Debian Codegraph @

tapset/linux/x86_64/sysc_mmap2.stp

raw
1 # In kernels < 2.6.33, mmap()/mmap2() was handled by arch-specific
2 # code. In kernels >= 2.6.33, the arch-specific code just calls
3 # generic sys_mmap_pgoff().
4 %( kernel_v < "2.6.33" %?
5 # sys32_mmap2(unsigned long addr, unsigned long len,
6 # unsigned long prot, unsigned long flags,
7 # unsigned long fd, unsigned long pgoff)
8 # The function is removed since 2.6.33
9
10 @define _SYSCALL_MMAP2_NAME
11 %(
12 name = "mmap2"
13 %)
14
15 @define _SYSCALL_MMAP2_ARGSTR
16 %(
17 argstr = sprintf("%p, %u, %s, %s, %d, %d", start, length,
18 prot_str, flags_str, fd, pgoffset)
19 %)
20
21 probe syscall.mmap2 = dw_syscall.mmap2 !, nd_syscall.mmap2 ? {}
22 probe syscall.mmap2.return = dw_syscall.mmap2.return !, nd_syscall.mmap2.return ? {}
23
24 # dw_mmap2 _____________________________________________________
25
26 probe dw_syscall.mmap2 = __syscall.mmap2 ?, __syscall.mmap_pgoff ?
27 {
28 @__syscall_compat_gate(@const("__NR_mmap2"), @const("__NR_ia32_mmap2"))
29 @_SYSCALL_MMAP2_NAME
30 start = $addr
31 length = $len
32 prot = $prot
33 prot_str = _mprotect_prot_str(prot)
34 flags = $flags
35 flags_str = _mmap_flags(flags)
36 fd = __int32($fd)
37 # Although the kernel gets an unsigned long fd, on the
38 # user-side it is a signed int. Fix this.
39 fd = __int32($fd)
40 @_SYSCALL_MMAP2_ARGSTR
41 }
42 probe __syscall.mmap2 = kernel.function("sys32_mmap2")
43 {
44 pgoffset = $pgoff
45 }
46 probe __syscall.mmap_pgoff = kernel.function("sys_mmap_pgoff")
47 {
48 pgoffset = $pgoff * %{ /* pure */ PAGE_SIZE %}
49 }
50
51 probe dw_syscall.mmap2.return = kernel.function("sys_mmap2").return ?,
52 kernel.function("sys_mmap_pgoff").return ?
53 {
54 @__syscall_compat_gate(@const("__NR_mmap2"), @const("__NR_ia32_mmap2"))
55 @_SYSCALL_MMAP2_NAME
56 @SYSC_RETVALSTR2($return)
57 }
58
59 # nd_mmap2 _____________________________________________________
60
61 probe nd_syscall.mmap2 = __nd_syscall.mmap2 ?, __nd_syscall.mmap_pgoff ?
62 {
63 @__syscall_compat_gate(@const("__NR_mmap2"), @const("__NR_ia32_mmap2"))
64 @_SYSCALL_MMAP2_NAME
65 start = ulong_arg(1)
66 length = ulong_arg(2)
67 prot = ulong_arg(3)
68 prot_str = _mprotect_prot_str(prot)
69 flags = ulong_arg(4)
70 flags_str = _mmap_flags(flags)
71 fd = int_arg(5)
72 @_SYSCALL_MMAP2_ARGSTR
73 }
74 probe __nd_syscall.mmap2 = kprobe.function("sys32_mmap2")
75 {
76 asmlinkage()
77 pgoffset = ulong_arg(6)
78 }
79 probe __nd_syscall.mmap_pgoff = kprobe.function("sys_mmap_pgoff")
80 {
81 asmlinkage()
82 # $pgoff is the number of pages. Convert this back into a
83 # number of bytes.
84 pgoffset = ulong_arg(6) * @const("PAGE_SIZE")
85 }
86 probe nd_syscall.mmap2.return = kprobe.function("sys32_mmap2").return ?,
87 kprobe.function("sys_mmap_pgoff").return ?
88 {
89 @__syscall_compat_gate(@const("__NR_mmap2"), @const("__NR_ia32_mmap2"))
90 @_SYSCALL_MMAP2_NAME
91 @SYSC_RETVALSTR2(returnval())
92 }
93 %)