Debian Codegraph @

tapset/linux/x86_64/sysc_execve.stp

raw
1 %( kernel_v < "3.7" %?
2 # execve _____________________________________________________
3 #
4 # In kernels < 3.7, sys_execve() was in arch-specific code (and had
5 # varying arguments). It was just a wrapper around generic
6 # do_execve(), but the wrapper could error out before calling
7 # do_execve(). So, we'll have to handle it in arch-specific tapset
8 # code to catch all calls.
9 #
10 # long sys_execve(char __user *name, char __user * __user *argv,
11 # char __user * __user *envp, struct pt_regs regs)
12
13 @define _SYSCALL_EXECVE_NAME
14 %(
15 name = "execve"
16 %)
17
18 @define _SYSCALL_EXECVE_ARGSTR
19 %(
20 argstr = sprintf("%s, %s, %s", filename, args, env_str)
21 %)
22
23 probe syscall.execve = dw_syscall.execve !, nd_syscall.execve {}
24 probe syscall.execve.return = dw_syscall.execve.return !,
25 nd_syscall.execve.return {}
26
27 # dw_execve _____________________________________________________
28
29 probe dw_syscall.execve = kernel.function("sys_execve").call
30 {
31 @_SYSCALL_EXECVE_NAME
32 filename = user_string_quoted($name)
33 args = __get_argv($argv, 0)
34 env_str = __get_argv($envp, 0)
35 @_SYSCALL_EXECVE_ARGSTR
36 }
37 probe dw_syscall.execve.return = kernel.function("sys_execve").return
38 {
39 @_SYSCALL_EXECVE_NAME
40 @SYSC_RETVALSTR($return)
41 }
42
43 # nd_execve _____________________________________________________
44
45 probe nd_syscall.execve = kprobe.function("sys_execve")
46 {
47 @_SYSCALL_EXECVE_NAME
48 filename = user_string_quoted(pointer_arg(1))
49 args = __get_argv(pointer_arg(2), 0)
50 env_str = __get_argv(pointer_arg(3), 0)
51 @_SYSCALL_EXECVE_ARGSTR
52 }
53 probe nd_syscall.execve.return = kprobe.function("sys_execve").return
54 {
55 @_SYSCALL_EXECVE_NAME
56 @SYSC_RETVALSTR(returnval())
57 }
58 %)