Debian Codegraph @

tapset/linux/sysc_sync_file_range.stp

raw
1 # sync_file_range ____________________________________________
2 #
3 # Why is there a 'sync_file_range' and a 'sync_file_range2'? As the
4 # man page says:
5 #
6 # Some architectures (e.g., PowerPC, ARM) need 64-bit arguments to be
7 # aligned in a suitable pair of registers. On such architectures, the
8 # call signature of sync_file_range()... would force a register to be
9 # be wasted as padding between the 'fd' and 'offset' arguments.
10 #
11 # SYSCALL_DEFINE4(sync_file_range, int, fd, loff_t, offset, loff_t, nbytes,
12 # unsigned int, flags)
13 # SYSCALL_DEFINE4(sync_file_range2, int, fd, unsigned int, flags,
14 # loff_t, offset, loff_t, nbytes)
15 #
16 # But, sync_file_range2() is just a wrapper around sync_file_range, so
17 # we can just probe that.
18
19 @define _SYSCALL_SYNC_FILE_RANGE_NAME
20 %(
21 name = "sync_file_range"
22 %)
23
24 @define _SYSCALL_SYNC_FILE_RANGE_ARGSTR
25 %(
26 argstr = sprintf("%d, %d, %d, %s", fd, offset, nbytes, flags_str)
27 %)
28
29 probe syscall.sync_file_range = dw_syscall.sync_file_range !,
30 nd_syscall.sync_file_range ? {}
31 probe syscall.sync_file_range.return = dw_syscall.sync_file_range.return !,
32 nd_syscall.sync_file_range.return ? {}
33
34 # dw_sync_file_range _____________________________________________________
35
36 probe dw_syscall.sync_file_range = kernel.function("sys_sync_file_range").call ?
37 {
38 @_SYSCALL_SYNC_FILE_RANGE_NAME
39 fd = __int32($fd)
40 offset = $offset
41 nbytes = $nbytes
42 flags = __uint32($flags)
43 flags_str = _sync_file_range_flags_str(flags)
44 @_SYSCALL_SYNC_FILE_RANGE_ARGSTR
45 }
46 probe dw_syscall.sync_file_range.return =
47 kernel.function("sys_sync_file_range").return ?
48 {
49 @_SYSCALL_SYNC_FILE_RANGE_NAME
50 @SYSC_RETVALSTR($return)
51 }
52
53 # nd_sync_file_range _____________________________________________________
54
55 probe nd_syscall.sync_file_range = nd1_syscall.sync_file_range!, nd2_syscall.sync_file_range!, tp_syscall.sync_file_range
56 { }
57
58 probe nd1_syscall.sync_file_range = kprobe.function("sys_sync_file_range") ?
59 {
60 asmlinkage()
61 @_SYSCALL_SYNC_FILE_RANGE_NAME
62 fd = int_arg(1)
63 %( CONFIG_64BIT == "y" %?
64 offset = longlong_arg(2)
65 nbytes = longlong_arg(3)
66 flags = uint_arg(4)
67 %:
68 %( arch == "arm" %?
69 # arm has some odd rules regarding long long arguments.
70 offset = longlong_arg(3)
71 nbytes = longlong_arg(5)
72 flags = uint_arg(7)
73 %:
74 offset = longlong_arg(2)
75 nbytes = longlong_arg(4)
76 flags = uint_arg(6)
77 %)
78 %)
79 flags_str = _sync_file_range_flags_str(flags)
80 @_SYSCALL_SYNC_FILE_RANGE_ARGSTR
81 }
82
83 /* kernel 4.17+ */
84 probe nd2_syscall.sync_file_range = __nd2_syscall.sync_file_range,
85 __nd2_syscall.compat_sync_file_range
86 {
87 @_SYSCALL_SYNC_FILE_RANGE_NAME
88 @_SYSCALL_SYNC_FILE_RANGE_ARGSTR
89 }
90 probe __nd2_syscall.sync_file_range =
91 kprobe.function(@arch_syscall_prefix "sys_sync_file_range") ?
92 {
93 __set_syscall_pt_regs(pointer_arg(1))
94 fd = int_arg(1)
95 offset = longlong_arg(2)
96 nbytes = longlong_arg(3)
97 flags = uint_arg(4)
98 flags_str = _sync_file_range_flags_str(flags)
99 },
100 {
101 %( @_IS_SREG_KERNEL %?
102 if (@probewrite(fd))
103 set_int_arg(1, fd)
104
105 if (@probewrite(offset))
106 set_longlong_arg(2, offset)
107
108 if (@probewrite(nbytes))
109 set_longlong_arg(3, nbytes)
110
111 if (@probewrite(flags))
112 set_uint_arg(4, flags)
113 %)
114 }
115 probe __nd2_syscall.compat_sync_file_range =
116 kprobe.function(@arch_syscall_prefix "compat_sys_x86_sync_file_range") ?
117 {
118 __set_syscall_pt_regs(pointer_arg(1))
119 fd = int_arg(1)
120 offset = (uint_arg(3) << 32) | uint_arg(2)
121 nbytes = (uint_arg(5) << 32) | uint_arg(4)
122 flags = uint_arg(6)
123 flags_str = _sync_file_range_flags_str(flags)
124 },
125 {
126 %( @_IS_SREG_KERNEL %?
127 if (@probewrite(fd))
128 set_int_arg(1, fd)
129
130 if (@probewrite(offset)) {
131 set_uint_arg(2, offset & 0xffffffff)
132 set_uint_arg(3, offset >> 32)
133 }
134
135 if (@probewrite(nbytes)) {
136 set_uint_arg(4, nbytes & 0xffffffff)
137 set_uint_arg(5, nbytes >> 32)
138 }
139
140 if (@probewrite(flags))
141 set_uint_arg(6, flags)
142 %)
143 }
144
145 /* kernel 3.5+, but undesirable because it affects all syscalls */
146 probe tp_syscall.sync_file_range = kernel.trace("sys_enter")
147 {
148 __set_syscall_pt_regs($regs)
149 @__syscall_compat_gate(@const("__NR_sync_file_range"),
150 @const("__NR_compat_sync_file_range"))
151 @_SYSCALL_SYNC_FILE_RANGE_NAME
152 fd = int_arg(1)
153 if (@__compat_task) {
154 offset = (uint_arg(3) << 32) | uint_arg(2)
155 nbytes = (uint_arg(5) << 32) | uint_arg(4)
156 flags = uint_arg(6)
157 }
158 else {
159 offset = longlong_arg(2)
160 nbytes = longlong_arg(3)
161 flags = uint_arg(4)
162 }
163 flags_str = _sync_file_range_flags_str(flags)
164 @_SYSCALL_SYNC_FILE_RANGE_ARGSTR
165 },
166 {
167 %( @_IS_SREG_KERNEL %?
168 if (@probewrite(fd))
169 set_int_arg(1, fd)
170
171 if (@__compat_task) {
172 if (@probewrite(offset)) {
173 set_uint_arg(2, offset & 0xffffffff)
174 set_uint_arg(3, offset >> 32)
175 }
176
177 if (@probewrite(nbytes)) {
178 set_uint_arg(4, nbytes & 0xffffffff)
179 set_uint_arg(5, nbytes >> 32)
180 }
181 if (@probewrite(flags))
182 set_uint_arg(6, flags)
183 } else {
184 if (@probewrite(offset))
185 set_longlong_arg(2, offset)
186
187 if (@probewrite(nbytes))
188 set_longlong_arg(3, nbytes)
189
190 if (@probewrite(flags))
191 set_uint_arg(4, flags)
192 }
193 %)
194 }
195
196 probe nd_syscall.sync_file_range.return = nd1_syscall.sync_file_range.return!, nd2_syscall.sync_file_range.return!, tp_syscall.sync_file_range.return
197 { }
198
199 probe nd1_syscall.sync_file_range.return =
200 kprobe.function("sys_sync_file_range").return ?
201 {
202 @_SYSCALL_SYNC_FILE_RANGE_NAME
203 @SYSC_RETVALSTR(returnval())
204 }
205
206 /* kernel 4.17+ */
207 probe nd2_syscall.sync_file_range.return =
208 kprobe.function(@arch_syscall_prefix "sys_sync_file_range").return ?,
209 kprobe.function(@arch_syscall_prefix "compat_sys_x86_sync_file_range").return ?
210 {
211 @_SYSCALL_SYNC_FILE_RANGE_NAME
212 @SYSC_RETVALSTR(returnval())
213 }
214
215 /* kernel 3.5+, but undesirable because it affects all syscalls */
216 probe tp_syscall.sync_file_range.return = kernel.trace("sys_exit")
217 {
218 __set_syscall_pt_regs($regs)
219 @__syscall_compat_gate(@const("__NR_sync_file_range"),
220 @const("__NR_compat_sync_file_range"))
221 @_SYSCALL_SYNC_FILE_RANGE_NAME
222 @SYSC_RETVALSTR($ret)
223 }