Debian Codegraph @

tapset/linux/ioscheduler.stp

raw
1 // IO scheduler tapset
2 // Copyright (C) 2005, 2006 IBM Corp.
3 // Copyright (C) 2010-2017 Red Hat Inc.
4 //
5 // This file is part of systemtap, and is free software. You can
6 // redistribute it and/or modify it under the terms of the GNU General
7 // Public License (GPL); either version 2, or (at your option) any
8 // later version.
9 // <tapsetdescription>
10 // This family of probe points is used to probe IO scheduler activities.
11 // </tapsetdescription>
12 %{
13 #include <linux/blkdev.h>
14 #if LINUX_VERSION_CODE < KERNEL_VERSION(4,18,0)
15 #include <linux/elevator.h>
16 #endif
17 %}
18
19 /**
20 * probe ioscheduler.elv_next_request - Fires when a request is retrieved from the request queue
21 * @name: Name of the probe point
22 * @elevator_name: The type of I/O elevator currently enabled
23 */
24 probe ioscheduler.elv_next_request = kernel.function("blk_peek_request") !,
25 kernel.function("elv_next_request") ?
26 {
27 name = "elv_next_request"
28 elevator_name = kernel_string(
29 @choose_defined($q->elevator->type->elevator_name,
30 @choose_defined($q->elevator->elevator_type->elevator_name,
31 $q->elevator->elevator_name)), "")
32 }
33
34 /**
35 * probe ioscheduler.elv_next_request.return - Fires when a request retrieval issues a return signal
36 * @name: Name of the probe point
37 * @rq: Address of the request
38 * @rq_flags: Request flags
39 * @disk_major: Disk major number of the request
40 * @disk_minor: Disk minor number of the request
41 */
42 probe ioscheduler.elv_next_request.return =
43 kernel.function("blk_peek_request").return !,
44 kernel.function("elv_next_request").return ?
45 {
46 name = "elv_next_request"
47 if ($return == 0) {
48 rq = 0
49 rq_flags = 0
50 disk_major = -1
51 disk_minor = -1
52 } else {
53 rq = $return
54 rq_flags = @choose_defined($return->cmd_flags, $return->flags)
55 if ($return->rq_disk == 0) {
56 disk_major = -1
57 disk_minor = -1
58 } else {
59 disk_major = $return->rq_disk->major
60 disk_minor = $return->rq_disk->first_minor
61 }
62 }
63 }
64
65 /**
66 * probe ioscheduler.elv_completed_request - Fires when a request is completed
67 * @name: Name of the probe point
68 * @elevator_name: The type of I/O elevator currently enabled
69 * @rq: Address of the request
70 * @rq_flags: Request flags
71 * @disk_major: Disk major number of the request
72 * @disk_minor: Disk minor number of the request
73 */
74 probe ioscheduler.elv_completed_request
75 = kernel.function("elv_completed_request") ?
76 {
77 name = "elv_completed_request"
78 elevator_name = kernel_string(
79 @choose_defined($q->elevator->type->elevator_name,
80 @choose_defined($q->elevator->elevator_type->elevator_name,
81 @choose_defined($q->elevator->elevator_name,
82 0))), "")
83 disk_major = -1
84 disk_minor = -1
85 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
86 // block: remove the ->rq_disk field in struct request
87 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
88 disk_major = $rq->rq_disk->major
89 disk_minor = $rq->rq_disk->first_minor
90 }
91
92 rq = $rq
93 rq_flags = ($rq == 0) ? 0
94 : @choose_defined($rq->cmd_flags, $rq->flags)
95 }
96
97 /**
98 * probe ioscheduler.elv_add_request.kp - kprobe based probe to indicate that a request was added to the request queue
99 * @name: Name of the probe point
100 * @elevator_name: The type of I/O elevator currently enabled
101 * @q: pointer to request queue
102 * @rq: Address of the request
103 * @rq_flags: Request flags
104 * @disk_major: Disk major number of the request
105 * @disk_minor: Disk minor number of the request
106 */
107 // when a request is added to the request queue
108 probe ioscheduler.elv_add_request.kp =
109 kernel.function("elv_insert") !,
110 kernel.function("__elv_add_request") ?
111 {
112 name = "elv_add_request"
113 elevator_name = kernel_string(
114 @choose_defined($q->elevator->type->elevator_name,
115 @choose_defined($q->elevator->elevator_type->elevator_name,
116 @choose_defined($q->elevator->elevator_name,
117 0))), "")
118 q = $q
119
120 disk_major = -1
121 disk_minor = -1
122 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
123 // block: remove the ->rq_disk field in struct request
124 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
125 disk_major = $rq->rq_disk->major
126 disk_minor = $rq->rq_disk->first_minor
127 }
128
129 rq = $rq
130 rq_flags = ($rq == 0) ? 0
131 : @choose_defined($rq->cmd_flags, $rq->flags)
132 }
133
134 /**
135 * probe ioscheduler.elv_add_request.tp - tracepoint based probe to indicate a request is added to the request queue.
136 * @name : Name of the probe point
137 * @elevator_name : The type of I/O elevator currently enabled.
138 * @q : Pointer to request queue.
139 * @rq : Address of request.
140 * @rq_flags : Request flags.
141 * @disk_major : Disk major no of request.
142 * @disk_minor : Disk minor number of request.
143 *
144 */
145 probe ioscheduler.elv_add_request.tp = kernel.trace("block_rq_insert") ?
146 {
147 name = "elv_add_request"
148 q = $rq->q
149 elevator_name = kernel_string(
150 @choose_defined($rq->q->elevator->type->elevator_name,
151 @choose_defined($rq->q->elevator->elevator_type->elevator_name,
152 @choose_defined($rq->q->elevator->elevator_name,
153 0))), "")
154 rq = $rq
155
156 disk_major = -1
157 disk_minor = -1
158 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
159 // block: remove the ->rq_disk field in struct request
160 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
161 disk_major = $rq->rq_disk->major
162 disk_minor = $rq->rq_disk->first_minor
163 }
164
165 rq_flags = ($rq == 0) ? 0
166 : @choose_defined($rq->cmd_flags, $rq->flags)
167 }
168
169 /**
170 * probe ioscheduler.elv_add_request - probe to indicate request is added to the request queue.
171 * @elevator_name : The type of I/O elevator currently enabled.
172 * @q : Pointer to request queue.
173 * @rq : Address of request.
174 * @rq_flags : Request flags.
175 * @disk_major : Disk major no of request.
176 * @disk_minor : Disk minor number of request.
177 *
178 */
179 probe ioscheduler.elv_add_request =
180 ioscheduler.elv_add_request.tp !, ioscheduler.elv_add_request.kp ?
181 {}
182
183 /**
184 * probe ioscheduler_trace.elv_completed_request - Fires when a request is
185 * completed.
186 * @name : Name of the probe point
187 * @elevator_name : The type of I/O elevator currently enabled.
188 * @rq : Address of request.
189 * @rq_flags : Request flags.
190 * @disk_major : Disk major no of request.
191 * @disk_minor : Disk minor number of request.
192 *
193 */
194 probe ioscheduler_trace.elv_completed_request
195 = kernel.trace("block_rq_complete") ?
196 {
197 name = "elv_completed_request"
198 q = $rq->q
199 elevator_name = kernel_string(
200 @choose_defined($rq->q->elevator->type->elevator_name,
201 @choose_defined($rq->q->elevator->elevator_type->elevator_name,
202 @choose_defined($rq->q->elevator->elevator_name,
203 0))), "")
204
205 rq = $rq
206
207 disk_major = -1
208 disk_minor = -1
209 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
210 // block: remove the ->rq_disk field in struct request
211 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
212 disk_major = $rq->rq_disk->major
213 disk_minor = $rq->rq_disk->first_minor
214 }
215
216 rq_flags = ($rq == 0) ? 0
217 : @choose_defined($rq->cmd_flags, $rq->flags)
218 }
219
220 /**
221 * probe ioscheduler_trace.elv_issue_request - Fires when a request is
222 * scheduled.
223 * @name : Name of the probe point
224 * @elevator_name : The type of I/O elevator currently enabled.
225 * @rq : Address of request.
226 * @rq_flags : Request flags.
227 * @disk_major : Disk major no of request.
228 * @disk_minor : Disk minor number of request.
229 *
230 */
231 probe ioscheduler_trace.elv_issue_request
232 = kernel.trace("block_rq_issue") ?
233 {
234 name = "elv_issue_request"
235 q = $rq->q
236 elevator_name = kernel_string(
237 @choose_defined($rq->q->elevator->type->elevator_name,
238 @choose_defined($rq->q->elevator->elevator_type->elevator_name,
239 @choose_defined($rq->q->elevator->elevator_name,
240 0))), "")
241 rq = $rq
242
243 disk_major = -1
244 disk_minor = -1
245 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
246 // block: remove the ->rq_disk field in struct request
247 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
248 disk_major = $rq->rq_disk->major
249 disk_minor = $rq->rq_disk->first_minor
250 }
251
252 rq_flags = ($rq == 0) ? 0
253 : @choose_defined($rq->cmd_flags, $rq->flags)
254 }
255
256 /**
257 * probe ioscheduler_trace.elv_requeue_request - Fires when a request is
258 * put back on the queue, when the hadware cannot accept more requests.
259 * @name : Name of the probe point
260 * @elevator_name : The type of I/O elevator currently enabled.
261 * @rq : Address of request.
262 * @rq_flags : Request flags.
263 * @disk_major : Disk major no of request.
264 * @disk_minor : Disk minor number of request.
265 *
266 */
267 probe ioscheduler_trace.elv_requeue_request
268 = kernel.trace("block_rq_requeue") ?
269 {
270 name = "elv_requeue_request"
271 q = $rq->q
272 elevator_name = kernel_string(
273 @choose_defined($rq->q->elevator->type->elevator_name,
274 @choose_defined($rq->q->elevator->elevator_type->elevator_name,
275 @choose_defined($rq->q->elevator->elevator_name,
276 0))), "")
277 rq = $rq
278
279 disk_major = -1
280 disk_minor = -1
281 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
282 // block: remove the ->rq_disk field in struct request
283 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
284 disk_major = $rq->rq_disk->major
285 disk_minor = $rq->rq_disk->first_minor
286 }
287
288 rq_flags = ($rq == 0) ? 0
289 : @choose_defined($rq->cmd_flags, $rq->flags)
290 }
291
292 /**
293 * probe ioscheduler_trace.elv_abort_request - Fires when a request is aborted.
294 * @name : Name of the probe point
295 * @elevator_name : The type of I/O elevator currently enabled.
296 * @rq : Address of request.
297 * @rq_flags : Request flags.
298 * @disk_major : Disk major no of request.
299 * @disk_minor : Disk minor number of request.
300 *
301 */
302 probe ioscheduler_trace.elv_abort_request
303 = kernel.trace("block_rq_abort") ?
304 {
305 name = "elv_abort_request"
306 q = $rq->q
307 elevator_name = kernel_string(
308 @choose_defined($rq->q->elevator->type->elevator_name,
309 @choose_defined($rq->q->elevator->elevator_type->elevator_name,
310 @choose_defined($rq->q->elevator->elevator_name,
311 0))), "")
312 rq = $rq
313
314 disk_major = -1
315 disk_minor = -1
316 // kernel f3fa33acca9f0058157214800f68b10d8e71ab7a
317 // block: remove the ->rq_disk field in struct request
318 if(@defined($rq->rq_disk) && ($rq->rq_disk != 0)) {
319 disk_major = $rq->rq_disk->major
320 disk_minor = $rq->rq_disk->first_minor
321 }
322
323 rq_flags = ($rq == 0) ? 0
324 : @choose_defined($rq->cmd_flags, $rq->flags)
325 }
326
327 /**
328 * probe ioscheduler_trace.plug - Fires when a request queue is plugged;
329 * ie, requests in the queue cannot be serviced by block driver.
330 * @name : Name of the probe point
331 * @rq_queue : request queue
332 *
333 */
334 probe ioscheduler_trace.plug = kernel.trace("block_plug") ?
335 {
336 name = "plug"
337 rq_queue = $q
338 }
339
340 /**
341 * probe ioscheduler_trace.unplug_io - Fires when a request queue is unplugged;
342 * Either, when number of pending requests in the queue exceeds threshold
343 * or, upon expiration of timer that was activated when queue was plugged.
344 * @name : Name of the probe point
345 * @rq_queue : request queue
346 *
347 */
348 probe ioscheduler_trace.unplug_io = kernel.trace("block_unplug_io") ?
349 {
350 name = "unplug_io"
351 rq_queue = $q
352 }
353
354 /**
355 * probe ioscheduler_trace.unplug_timer - Fires when unplug timer associated
356 * with a request queue expires.
357 * @name : Name of the probe point
358 * @rq_queue : request queue
359 *
360 */
361 probe ioscheduler_trace.unplug_timer = kernel.trace("block_unplug_timer") ?
362 {
363 name = "unplug_timer"
364 rq_queue = $q
365 }
366
367 function disk_major_from_request:long(var_q:long)
368 %{ /* pure */
369 #ifndef _ELEVATOR_H
370 STAP_ERROR ("unsupported (PR28634)");
371 #else
372 struct request_queue *q = (struct request_queue *)((uintptr_t)STAP_ARG_var_q);
373
374 /* We need to make sure there isn't a deref hazard here when
375 * reading 'q->queue_head'. However, kread() wants a pointer to
376 * a pointer, and we can't provide that for 'q->queue_head'
377 * since the list_head structure is directly embedded in the
378 * 'struct request_queue'. So, we validate all the members of
379 * the list_head structure instead. */
380 (void) kread(&(q->queue_head.next));
381 (void) kread(&(q->queue_head.prev));
382 if (list_empty(&(q->queue_head)))
383 STAP_RETVALUE = -1;
384 else {
385 struct request *rq = list_entry_rq(q->queue_head.next);
386 struct gendisk *rq_disk = kread(&(rq->rq_disk));
387 STAP_RETVALUE = kread(&(rq_disk->major));
388 }
389 CATCH_DEREF_FAULT();
390 #endif
391 %}
392
393 function disk_minor_from_request:long(var_q:long)
394 %{ /* pure */
395 #ifndef _ELEVATOR_H
396 STAP_ERROR ("unsupported (PR28634)");
397 #else
398 struct request_queue *q = (struct request_queue *)((uintptr_t)STAP_ARG_var_q);
399
400 /* We need to make sure there isn't a deref hazard here when
401 * reading 'q->queue_head'. However, kread() wants a pointer to
402 * a pointer, and we can't provide that for 'q->queue_head'
403 * since the list_head structure is directly embedded in the
404 * 'struct request_queue'. So, we validate all the members of
405 * the list_head structure instead. */
406 (void) kread(&(q->queue_head.next));
407 (void) kread(&(q->queue_head.prev));
408 if (list_empty(&(q->queue_head)))
409 STAP_RETVALUE = -1;
410 else {
411 struct request *rq = list_entry_rq(q->queue_head.next);
412 struct gendisk *rq_disk = kread(&(rq->rq_disk));
413 STAP_RETVALUE = kread(&(rq_disk->first_minor));
414 }
415 CATCH_DEREF_FAULT();
416 #endif
417 %}
418