Debian Codegraph @

tapset/linux/sysc_readlink.stp

raw
1 # readlink ___________________________________________________
2 #
3 # long sys_readlink(const char __user * path,
4 # char __user * buf,
5 # int bufsiz)
6 #
7
8 @define _SYSCALL_READLINK_NAME
9 %(
10 name = "readlink"
11 %)
12
13 @define _SYSCALL_READLINK_ARGSTR
14 %(
15 argstr = sprintf("%s, %p, %d", path, buf_uaddr, bufsiz)
16 %)
17
18 @define _SYSCALL_READLINK_REGARGS
19 %(
20 path = user_string_quoted(pointer_arg(1))
21 path_unquoted = user_string_nofault(pointer_arg(1))
22 buf_uaddr = pointer_arg(2)
23 bufsiz = int_arg(3)
24 %)
25
26 @define _SYSCALL_READLINK_REGARGS_STORE
27 %(
28 if (@probewrite(path_unquoted))
29 set_user_string_arg(pointer_arg(1), path_unquoted)
30
31 if (@probewrite(buf_uaddr))
32 set_pointer_arg(2, buf_uaddr)
33
34 if (@probewrite(bufsiz))
35 set_int_arg(3, bufsiz)
36 %)
37
38 probe syscall.readlink = dw_syscall.readlink !, nd_syscall.readlink ? {}
39 probe syscall.readlink.return = dw_syscall.readlink.return !,
40 nd_syscall.readlink.return ? {}
41
42 # dw_readlink _____________________________________________________
43
44 probe dw_syscall.readlink = kernel.function("sys_readlink").call
45 {
46 @_SYSCALL_READLINK_NAME
47 path = user_string_quoted($path)
48 buf_uaddr = $buf
49 bufsiz = __int32($bufsiz)
50 @_SYSCALL_READLINK_ARGSTR
51 }
52 probe dw_syscall.readlink.return = kernel.function("sys_readlink").return
53 {
54 @_SYSCALL_READLINK_NAME
55 @SYSC_RETVALSTR($return)
56 }
57
58 # nd_readlink _____________________________________________________
59
60 probe nd_syscall.readlink = nd1_syscall.readlink!, nd2_syscall.readlink!, tp_syscall.readlink
61 { }
62
63 probe nd1_syscall.readlink = kprobe.function("sys_readlink") ?
64 {
65 @_SYSCALL_READLINK_NAME
66 asmlinkage()
67 @_SYSCALL_READLINK_REGARGS
68 @_SYSCALL_READLINK_ARGSTR
69 }
70
71 /* kernel 4.17+ */
72 probe nd2_syscall.readlink = kprobe.function(@arch_syscall_prefix "sys_readlink") ?
73 {
74 __set_syscall_pt_regs(pointer_arg(1))
75 @_SYSCALL_READLINK_NAME
76 @_SYSCALL_READLINK_REGARGS
77 @_SYSCALL_READLINK_ARGSTR
78 },
79 {
80 %( @_IS_SREG_KERNEL %? @_SYSCALL_READLINK_REGARGS_STORE %)
81 }
82
83 /* kernel 3.5+, but undesirable because it affects all syscalls */
84 probe tp_syscall.readlink = kernel.trace("sys_enter")
85 {
86 __set_syscall_pt_regs($regs)
87 @__syscall_compat_gate(@const("__NR_readlink"), @const("__NR_compat_readlink"))
88 @_SYSCALL_READLINK_NAME
89 @_SYSCALL_READLINK_REGARGS
90 @_SYSCALL_READLINK_ARGSTR
91 },
92 {
93 %( @_IS_SREG_KERNEL %? @_SYSCALL_READLINK_REGARGS_STORE %)
94 }
95
96 probe nd_syscall.readlink.return = nd1_syscall.readlink.return!, nd2_syscall.readlink.return!, tp_syscall.readlink.return
97 { }
98
99 probe nd1_syscall.readlink.return = kprobe.function("sys_readlink").return ?
100 {
101 @_SYSCALL_READLINK_NAME
102 @SYSC_RETVALSTR(returnval())
103 }
104
105 /* kernel 4.17+ */
106 probe nd2_syscall.readlink.return = kprobe.function(@arch_syscall_prefix "sys_readlink").return ?
107 {
108 @_SYSCALL_READLINK_NAME
109 @SYSC_RETVALSTR(returnval())
110 }
111
112 /* kernel 3.5+, but undesirable because it affects all syscalls */
113 probe tp_syscall.readlink.return = kernel.trace("sys_exit")
114 {
115 __set_syscall_pt_regs($regs)
116 @__syscall_compat_gate(@const("__NR_readlink"), @const("__NR_compat_readlink"))
117 @_SYSCALL_READLINK_NAME
118 @SYSC_RETVALSTR($ret)
119 }