Debian Codegraph @

tapset/linux/sysc_write.stp

raw
1 # write ______________________________________________________
2 #
3 # ssize_t sys_write(unsigned int fd,
4 # const char __user * buf,
5 # size_t count)
6 #
7
8 @define _SYSCALL_WRITE_NAME
9 %(
10 name = "write"
11 %)
12
13 @define _SYSCALL_WRITE_ARGSTR
14 %(
15 argstr = sprintf("%d, %s, %u", fd, buf_str, count)
16 %)
17
18 @define _SYSCALL_WRITE_REGARGS
19 %(
20 fd = int_arg(1)
21 buf_uaddr = pointer_arg(2)
22 count = ulong_arg(3)
23 buf_str = user_buffer_quoted(buf_uaddr, count, syscall_string_trunc)
24 %)
25
26 @define _SYSCALL_WRITE_REGARGS_STORE
27 %(
28 if (@probewrite(fd))
29 set_int_arg(1, fd)
30
31 if (@probewrite(buf_uaddr))
32 set_pointer_arg(2, buf_uaddr)
33
34 if (@probewrite(count))
35 set_ulong_arg(3, count)
36 %)
37
38 probe syscall.write = dw_syscall.write !, nd_syscall.write ? {}
39 probe syscall.write.return = dw_syscall.write.return !, nd_syscall.write.return ? {}
40
41 # dw_write _____________________________________________________
42
43 probe dw_syscall.write =
44 %( arch == "s390" %?
45 __syscall.write, kernel.function("sys32_write").call ?,
46 kernel.function("compat_sys_s390_write").call ?
47 %:
48 __syscall.write
49 %)
50 {
51 @_SYSCALL_WRITE_NAME
52 fd = __int32($fd)
53 buf_uaddr = $buf
54 count = @__compat_ulong($count)
55 buf_str = user_buffer_quoted(buf_uaddr, count, syscall_string_trunc)
56 @_SYSCALL_WRITE_ARGSTR
57 }
58 probe __syscall.write = kernel.function("sys_write").call
59 {
60 %( arch == "s390" %?
61 @__syscall_gate(@const("__NR_write"))
62 %)
63 }
64 probe dw_syscall.write.return =
65 %( arch == "s390" %?
66 __syscall.write.return, kernel.function("sys32_write").return ?,
67 kernel.function("compat_sys_s390_write").return ?
68 %:
69 __syscall.write.return
70 %)
71 {
72 @_SYSCALL_WRITE_NAME
73 @SYSC_RETVALSTR($return)
74 }
75 probe __syscall.write.return = kernel.function("sys_write").return
76 {
77 %( arch == "s390" %?
78 @__syscall_gate(@const("__NR_write"))
79 %)
80 }
81
82 # nd_write _____________________________________________________
83
84 probe nd_syscall.write = nd1_syscall.write!, nd2_syscall.write!, tp_syscall.write
85 { }
86
87 probe nd1_syscall.write =
88 %( arch == "s390" %?
89 __nd1_syscall.write, kprobe.function("sys32_write") ?,
90 kprobe.function("compat_sys_s390_write") ?
91 %:
92 __nd1_syscall.write
93 %)
94 {
95 @_SYSCALL_WRITE_NAME
96 asmlinkage()
97 @_SYSCALL_WRITE_REGARGS
98 @_SYSCALL_WRITE_ARGSTR
99 }
100 probe __nd1_syscall.write = kprobe.function("sys_write")
101 {
102 %( arch == "s390" %?
103 @__syscall_gate(@const("__NR_write"))
104 %)
105 }
106
107 /* kernel 4.17+ */
108 probe nd2_syscall.write = kprobe.function(@arch_syscall_prefix "sys_write")
109 {
110 __set_syscall_pt_regs(pointer_arg(1))
111 @_SYSCALL_WRITE_NAME
112 @_SYSCALL_WRITE_REGARGS
113 @_SYSCALL_WRITE_ARGSTR
114 },
115 {
116 %( @_IS_SREG_KERNEL %? @_SYSCALL_WRITE_REGARGS_STORE %)
117 }
118
119 /* kernel 3.5+, but undesirable because it affects all syscalls */
120 probe tp_syscall.write = kernel.trace("sys_enter")
121 {
122 __set_syscall_pt_regs($regs)
123 @__syscall_compat_gate(@const("__NR_write"), @const("__NR_compat_write"))
124 @_SYSCALL_WRITE_NAME
125 @_SYSCALL_WRITE_REGARGS
126 @_SYSCALL_WRITE_ARGSTR
127 },
128 {
129 %( @_IS_SREG_KERNEL %? @_SYSCALL_WRITE_REGARGS_STORE %)
130 }
131
132 probe nd_syscall.write.return = nd1_syscall.write.return!, nd2_syscall.write.return!, tp_syscall.write.return
133 { }
134
135 probe nd1_syscall.write.return =
136 %( arch == "s390" %?
137 __nd1_syscall.write.return, kprobe.function("sys32_write").return ?,
138 kprobe.function("compat_sys_s390_write").return ?
139 %:
140 __nd1_syscall.write.return
141 %)
142 {
143 @_SYSCALL_WRITE_NAME
144 @SYSC_RETVALSTR(returnval())
145 }
146 probe __nd1_syscall.write.return = kprobe.function("sys_write").return
147 {
148 %( arch == "s390" %?
149 @__syscall_gate(@const("__NR_write"))
150 %)
151 }
152
153 /* kernel 4.17+ */
154 probe nd2_syscall.write.return = kprobe.function(@arch_syscall_prefix "sys_write").return
155 {
156 @_SYSCALL_WRITE_NAME
157 @SYSC_RETVALSTR(returnval())
158 }
159
160 /* kernel 3.5+, but undesirable because it affects all syscalls */
161 probe tp_syscall.write.return = kernel.trace("sys_exit")
162 {
163 __set_syscall_pt_regs($regs)
164 @__syscall_compat_gate(@const("__NR_write"), @const("__NR_compat_write"))
165 @_SYSCALL_WRITE_NAME
166 @SYSC_RETVALSTR($ret)
167 }