Debian Codegraph @

tapset/linux/sysc_getsockname.stp

raw
1 # getsockname ________________________________________________
2 # long sys_getsockname(int fd,
3 # struct sockaddr __user *usockaddr,
4 # int __user *usockaddr_len)
5
6 @define _SYSCALL_GETSOCKNAME_NAME
7 %(
8 name = "getsockname"
9 %)
10
11 @define _SYSCALL_GETSOCKNAME_ARGSTR
12 %(
13 argstr = sprintf("%d, %p, %p", s, name_uaddr, namelen_uaddr)
14 %)
15
16 @define _SYSCALL_GETSOCKNAME_REGARGS
17 %(
18 s = int_arg(1)
19 name_uaddr = pointer_arg(2)
20 namelen_uaddr = pointer_arg(3)
21 %)
22
23 @define _SYSCALL_GETSOCKNAME_REGARGS_STORE
24 %(
25 if (@probewrite(s))
26 set_int_arg(1, s)
27
28 if (@probewrite(name_uaddr))
29 set_pointer_arg(2, name_uaddr)
30
31 if (@probewrite(namelen_uaddr))
32 set_pointer_arg(3, namelen_uaddr)
33 %)
34
35 @define _SYSCALL_SOCKETCALL_GETSOCKNAME_REGARGS
36 %(
37 __argsl = &@ulong_cast(pointer_arg(2))
38 s = __int32(user_ulong(&@ulong_cast(__argsl)[0]))
39 name_uaddr = user_ulong(&@ulong_cast(__argsl)[1])
40 namelen_uaddr = user_ulong(&@ulong_cast(__argsl)[2])
41 %)
42
43 @define _SYSCALL_COMPAT_SOCKETCALL_GETSOCKNAME_REGARGS
44 %(
45 __argsi = &@uint_cast(pointer_arg(2))
46 s = user_int(&@uint_cast(__argsi)[0])
47 name_uaddr = user_uint32(&@uint_cast(__argsi)[1])
48 namelen_uaddr = user_uint32(&@uint_cast(__argsi)[2])
49 %)
50
51 probe syscall.getsockname = dw_syscall.getsockname !, nd_syscall.getsockname ? {}
52 probe syscall.getsockname.return = dw_syscall.getsockname.return !,
53 nd_syscall.getsockname.return ? {}
54
55 # dw_getsockname _____________________________________________________
56
57 probe dw_syscall.getsockname = __syscall.getsockname ?,
58 __syscall.socketcall.getsockname ?,
59 __syscall.compat_socketcall.getsockname ?
60 {
61 @_SYSCALL_GETSOCKNAME_NAME
62 @_SYSCALL_GETSOCKNAME_ARGSTR
63 }
64 probe __syscall.getsockname = kernel.function("sys_getsockname").call ?
65 {
66 @__syscall_gate(@const("__NR_getsockname"))
67 s = __int32($fd)
68 name_uaddr = $usockaddr
69 namelen_uaddr = $usockaddr_len
70 }
71 probe __syscall.socketcall.getsockname = kernel.function("sys_socketcall").call ?
72 {
73 if (__int32($call) != @const("SYS_GETSOCKNAME")) next;
74 s = __int32(user_ulong(&@ulong_cast($args)[0]))
75 name_uaddr = user_ulong(&@ulong_cast($args)[1])
76 namelen_uaddr = user_ulong(&@ulong_cast($args)[2])
77 }
78 probe __syscall.compat_socketcall.getsockname =
79 kernel.function("compat_sys_socketcall").call ?
80 {
81 if (__int32($call) != @const("SYS_GETSOCKNAME")) next;
82 s = user_int(&@uint_cast($args)[0])
83 name_uaddr = user_uint32(&@uint_cast($args)[1])
84 namelen_uaddr = user_uint32(&@uint_cast($args)[2])
85 }
86 probe dw_syscall.getsockname.return = __syscall.getsockname.return ?,
87 __syscall.socketcall.getsockname.return ?
88 {
89 @_SYSCALL_GETSOCKNAME_NAME
90 @SYSC_RETVALSTR($return)
91 }
92 probe __syscall.getsockname.return = kernel.function("sys_getsockname").return ?
93 {
94 @__syscall_gate(@const("__NR_getsockname"))
95 }
96 probe __syscall.socketcall.getsockname.return =
97 kernel.function("sys_socketcall").return ?,
98 kernel.function("compat_sys_socketcall").return ?
99 {
100 if (__int32(@entry($call)) != @const("SYS_GETSOCKNAME")) next;
101 }
102
103 # nd_getsockname _____________________________________________________
104
105 probe nd_syscall.getsockname = nd1_syscall.getsockname!, nd2_syscall.getsockname!, tp_syscall.getsockname
106 { }
107
108 probe nd1_syscall.getsockname = __nd1_syscall.getsockname ?,
109 __nd1_syscall.socketcall.getsockname ?,
110 __nd1_syscall.compat_socketcall.getsockname ?
111 {
112 @_SYSCALL_GETSOCKNAME_NAME
113 @_SYSCALL_GETSOCKNAME_ARGSTR
114 }
115 probe __nd1_syscall.getsockname = kprobe.function("sys_getsockname") ?
116 {
117 @__syscall_gate(@const("__NR_getsockname"))
118 asmlinkage()
119 @_SYSCALL_GETSOCKNAME_REGARGS
120 }
121 probe __nd1_syscall.socketcall.getsockname =
122 kprobe.function("sys_socketcall").call ?
123 {
124 asmlinkage()
125 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
126 @_SYSCALL_SOCKETCALL_GETSOCKNAME_REGARGS
127 }
128 probe __nd1_syscall.compat_socketcall.getsockname =
129 kprobe.function("compat_sys_socketcall").call ?
130 {
131 asmlinkage()
132 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
133 @_SYSCALL_COMPAT_SOCKETCALL_GETSOCKNAME_REGARGS
134 }
135
136 /* kernel 4.17+ */
137 probe nd2_syscall.getsockname = __nd2_syscall.getsockname ?,
138 __nd2_syscall.socketcall.getsockname ?,
139 __nd2_syscall.compat_socketcall.getsockname ?
140 {
141 @_SYSCALL_GETSOCKNAME_NAME
142 @_SYSCALL_GETSOCKNAME_ARGSTR
143 }
144 probe __nd2_syscall.getsockname = kprobe.function(@arch_syscall_prefix "sys_getsockname") ?
145 {
146 __set_syscall_pt_regs(pointer_arg(1))
147 @_SYSCALL_GETSOCKNAME_REGARGS
148 },
149 {
150 @_SYSCALL_GETSOCKNAME_REGARGS_STORE
151 }
152 probe __nd2_syscall.socketcall.getsockname =
153 kprobe.function(@arch_syscall_prefix "sys_socketcall").call ?
154 {
155 __set_syscall_pt_regs(pointer_arg(1))
156 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
157 @_SYSCALL_SOCKETCALL_GETSOCKNAME_REGARGS
158 }
159 probe __nd2_syscall.compat_socketcall.getsockname =
160 kprobe.function(@arch_syscall_prefix "compat_sys_socketcall").call ?
161 {
162 __set_syscall_pt_regs(pointer_arg(1))
163 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
164 @_SYSCALL_COMPAT_SOCKETCALL_GETSOCKNAME_REGARGS
165 }
166
167 /* kernel 3.5+, but undesirable because it affects all syscalls */
168 probe tp_syscall.getsockname = __tp_syscall.getsockname ?,
169 __tp_syscall.socketcall.getsockname ?
170 {
171 @_SYSCALL_GETSOCKNAME_NAME
172 @_SYSCALL_GETSOCKNAME_ARGSTR
173 }
174 probe __tp_syscall.getsockname = kernel.trace("sys_enter")
175 {
176 __set_syscall_pt_regs($regs)
177 @__syscall_gate(@const("__NR_getsockname"))
178 @_SYSCALL_GETSOCKNAME_REGARGS
179 },
180 {
181 @_SYSCALL_GETSOCKNAME_REGARGS_STORE
182 }
183 probe __tp_syscall.socketcall.getsockname = kernel.trace("sys_enter")
184 {
185 __set_syscall_pt_regs($regs)
186 @__syscall_compat_gate(@const("__NR_socketcall"), @const("__NR_compat_socketcall"))
187 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
188 if (@__compat_task) {
189 @_SYSCALL_COMPAT_SOCKETCALL_GETSOCKNAME_REGARGS
190 }
191 else {
192 @_SYSCALL_SOCKETCALL_GETSOCKNAME_REGARGS
193 }
194 }
195
196 probe nd_syscall.getsockname.return = nd1_syscall.getsockname.return!, nd2_syscall.getsockname.return!, tp_syscall.getsockname.return
197 { }
198
199 probe nd1_syscall.getsockname.return =
200 __nd1_syscall.getsockname.return ?,
201 __nd1_syscall.socketcall.getsockname.return ?
202 {
203 @_SYSCALL_GETSOCKNAME_NAME
204 @SYSC_RETVALSTR(returnval())
205 }
206 probe __nd1_syscall.getsockname.return =
207 kprobe.function("sys_getsockname").return ?
208 {
209 @__syscall_gate(@const("__NR_getsockname"))
210 }
211 probe __nd1_syscall.socketcall.getsockname.return =
212 kprobe.function("sys_socketcall").return ?,
213 kprobe.function("compat_sys_socketcall").return ?
214 {
215 if (@entry(__asmlinkage_int_arg(1)) != @const("SYS_GETSOCKNAME")) next;
216 }
217
218 /* kernel 4.17+ */
219 probe nd2_syscall.getsockname.return =
220 kprobe.function(@arch_syscall_prefix "sys_getsockname").return ?,
221 __nd2_syscall.socketcall.getsockname.return ?
222 {
223 @_SYSCALL_GETSOCKNAME_NAME
224 @SYSC_RETVALSTR(returnval())
225 }
226 probe __nd2_syscall.socketcall.getsockname.return =
227 kprobe.function(@arch_syscall_prefix "sys_socketcall").return ?,
228 kprobe.function(@arch_syscall_prefix "compat_sys_socketcall").return ?
229 {
230 __set_syscall_pt_regs(@entry(pointer_arg(1)))
231 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
232 }
233
234 /* kernel 3.5+, but undesirable because it affects all syscalls */
235 probe tp_syscall.getsockname.return = __tp_syscall.getsockname.return ?,
236 __tp_syscall.socketcall.getsockname.return ?
237 {
238 @_SYSCALL_GETSOCKNAME_NAME
239 @SYSC_RETVALSTR($ret)
240 }
241 probe __tp_syscall.getsockname.return = kernel.trace("sys_exit")
242 {
243 @__syscall_gate(@const("__NR_getsockname"))
244 }
245 probe __tp_syscall.socketcall.getsockname.return = kernel.trace("sys_exit")
246 {
247 __set_syscall_pt_regs($regs)
248 @__syscall_compat_gate(@const("__NR_socketcall"), @const("__NR_compat_socketcall"))
249 if (int_arg(1) != @const("SYS_GETSOCKNAME")) next;
250 }