Debian Codegraph @

tapset/linux/dev.stp

raw
1 // Device tapset
2 // Copyright (C) 2008, 2010 Red Hat Corp.
3 //
4 // This file is part of systemtap, and is free software. You can
5 // redistribute it and/or modify it under the terms of the GNU General
6 // Public License (GPL); either version 2, or (at your option) any
7 // later version.
8
9 %{
10 #include <linux/kdev_t.h>
11 %}
12
13 /**
14 * sfunction MAJOR - Extract major device number from a kernel device number (kdev_t)
15 *
16 * @dev: Kernel device number to query.
17 */
18 function MAJOR:long(dev:long)
19 %{ /* pure */
20 STAP_RETVALUE = MAJOR(STAP_ARG_dev);
21 %}
22
23
24 /**
25 * sfunction MINOR - Extract minor device number from a kernel device number (kdev_t)
26 *
27 * @dev: Kernel device number to query.
28 */
29 function MINOR:long(dev:long)
30 %{ /* pure */
31 STAP_RETVALUE = MINOR(STAP_ARG_dev);
32 %}
33
34
35 /**
36 * sfunction MKDEF - Creates a value that can be compared to a kernel device number (kdev_t)
37 *
38 * @major: Intended major device number.
39 * @minor: Intended minor device number.
40 */
41 function MKDEV:long(major:long, minor:long)
42 %{ /* pure */
43 STAP_RETVALUE = MKDEV(STAP_ARG_major,STAP_ARG_minor);
44 %}
45
46 /**
47 * sfunction usrdev2kerndev - Converts a user-space device number into the format used in the kernel
48 *
49 * @dev: Device number in user-space format.
50 */
51 function usrdev2kerndev:long(dev:long)
52 %{ /* pure */
53 STAP_RETVALUE = new_decode_dev(STAP_ARG_dev);
54 %}
55
56 function disk_name:string(hd:long, partno:long)
57 {
58 if (!partno)
59 return kernel_string(@cast(hd, "gendisk", "kernel")->disk_name)
60 disk_name = kernel_string(@cast(hd, "gendisk", "kernel")->disk_name)
61 if (isdigit(substr(disk_name, strlen(disk_name)-1, 1)))
62 return sprintf("%sp%d", disk_name, partno)
63 else
64 return sprintf("%s%d", disk_name, partno)
65 }
66
67 %{
68 #include <linux/blk_types.h>
69 #include <linux/blkdev.h>
70 %}
71
72 function bdev_partno(bdev:long)
73 %{ /* pure */ /* unprivileged */
74 #ifdef BD_PARTNO
75 STAP_RETURN(bdev_partno((const struct block_device *) STAP_ARG_bdev));
76 #else
77 STAP_RETURN(0);
78 #endif
79 %}
80
81 function bdevname:string(bdev:long)
82 {
83 bdev = & @cast(bdev, "block_device", "kernel")
84 if (bdev == 0)
85 return "N/A"
86
87 hd = bdev->bd_disk
88
89 if (@defined(&bdev->__bd_flags))
90 partno = bdev_partno(bdev)
91 else if (@defined(bdev->bd_partno))
92 partno = bdev->bd_partno
93 else if (bdev->bd_part)
94 partno = bdev->bd_part->partno
95 else
96 partno = MINOR(bdev->bd_dev) - hd->first_minor;
97 return disk_name(hd, partno)
98 }