Debian Codegraph @

tapset/linux/sysc_sched_setattr.stp

raw
1 # sched_setattr ______________________________________________
2 #
3 # SYSCALL_DEFINE3(sched_setattr, pid_t, pid, struct sched_attr __user *, uattr,
4 # unsigned int, flags)
5 #
6
7 @define _SYSCALL_SCHED_SETATTR_NAME
8 %(
9 name = "sched_setattr"
10 %)
11
12 @define _SYSCALL_SCHED_SETATTR_ARGSTR
13 %(
14 argstr = sprintf("%d, %s, %u", pid, sched_attr_str, flags)
15 %)
16
17 @define _SYSCALL_SCHED_SETATTR_REGARGS
18 %(
19 pid = int_arg(1)
20 sched_attr_uaddr = pointer_arg(2)
21 sched_attr_str = _struct_sched_attr_u(sched_attr_uaddr)
22 flags = uint_arg(3)
23 %)
24
25 @define _SYSCALL_SCHED_SETATTR_REGARGS_STORE
26 %(
27 if (@probewrite(pid))
28 set_int_arg(1, pid)
29
30 if (@probewrite(sched_attr_uaddr))
31 set_pointer_arg(2, sched_attr_uaddr)
32
33 if (@probewrite(flags))
34 set_uint_arg(3, flags)
35 %)
36
37 probe syscall.sched_setattr = dw_syscall.sched_setattr !, nd_syscall.sched_setattr ? {}
38 probe syscall.sched_setattr.return = dw_syscall.sched_setattr.return !,
39 nd_syscall.sched_setattr.return ? {}
40
41 # dw_sched_setattr _____________________________________________________
42
43 probe dw_syscall.sched_setattr = kernel.function("sys_sched_setattr") ?
44 {
45 @_SYSCALL_SCHED_SETATTR_NAME
46 pid = __int32($pid)
47 sched_attr_uaddr = $uattr
48 sched_attr_str = _struct_sched_attr_u(sched_attr_uaddr)
49 flags = __uint32($flags)
50 @_SYSCALL_SCHED_SETATTR_ARGSTR
51 }
52 probe dw_syscall.sched_setattr.return =
53 kernel.function("sys_sched_setattr").return ?
54 {
55 @_SYSCALL_SCHED_SETATTR_NAME
56 @SYSC_RETVALSTR($return)
57 }
58
59 # nd_sched_setattr _____________________________________________________
60
61 probe nd_syscall.sched_setattr = nd1_syscall.sched_setattr!, nd2_syscall.sched_setattr!, tp_syscall.sched_setattr
62 { }
63
64 probe nd1_syscall.sched_setattr = kprobe.function("sys_sched_setattr") ?
65 {
66 @_SYSCALL_SCHED_SETATTR_NAME
67 asmlinkage()
68 @_SYSCALL_SCHED_SETATTR_REGARGS
69 @_SYSCALL_SCHED_SETATTR_ARGSTR
70 }
71
72 /* kernel 4.17+ */
73 probe nd2_syscall.sched_setattr = kprobe.function(@arch_syscall_prefix "sys_sched_setattr") ?
74 {
75 __set_syscall_pt_regs(pointer_arg(1))
76 @_SYSCALL_SCHED_SETATTR_NAME
77 @_SYSCALL_SCHED_SETATTR_REGARGS
78 @_SYSCALL_SCHED_SETATTR_ARGSTR
79 },
80 {
81 %( @_IS_SREG_KERNEL %? @_SYSCALL_SCHED_SETATTR_REGARGS_STORE %)
82 }
83
84 /* kernel 3.5+, but undesirable because it affects all syscalls */
85 probe tp_syscall.sched_setattr = kernel.trace("sys_enter")
86 {
87 __set_syscall_pt_regs($regs)
88 @__syscall_compat_gate(@const("__NR_sched_setattr"), @const("__NR_compat_sched_setattr"))
89 @_SYSCALL_SCHED_SETATTR_NAME
90 @_SYSCALL_SCHED_SETATTR_REGARGS
91 @_SYSCALL_SCHED_SETATTR_ARGSTR
92 },
93 {
94 %( @_IS_SREG_KERNEL %? @_SYSCALL_SCHED_SETATTR_REGARGS_STORE %)
95 }
96
97 probe nd_syscall.sched_setattr.return = nd1_syscall.sched_setattr.return!, nd2_syscall.sched_setattr.return!, tp_syscall.sched_setattr.return
98 { }
99
100 probe nd1_syscall.sched_setattr.return =
101 kprobe.function("sys_sched_setattr").return ?
102 {
103 @_SYSCALL_SCHED_SETATTR_NAME
104 @SYSC_RETVALSTR(returnval())
105 }
106
107 /* kernel 4.17+ */
108 probe nd2_syscall.sched_setattr.return = kprobe.function(@arch_syscall_prefix "sys_sched_setattr").return ?
109 {
110 @_SYSCALL_SCHED_SETATTR_NAME
111 @SYSC_RETVALSTR(returnval())
112 }
113
114 /* kernel 3.5+, but undesirable because it affects all syscalls */
115 probe tp_syscall.sched_setattr.return = kernel.trace("sys_exit")
116 {
117 __set_syscall_pt_regs($regs)
118 @__syscall_compat_gate(@const("__NR_sched_setattr"), @const("__NR_compat_sched_setattr"))
119 @_SYSCALL_SCHED_SETATTR_NAME
120 @SYSC_RETVALSTR($ret)
121 }