Debian Codegraph @

tapset/linux/sysc_prlimit64.stp

raw
1 # prlimit64 ____________________________________________________
2 #
3 # SYSCALL_DEFINE4(prlimit64, pid_t, pid, unsigned int, resource,
4 # const struct rlimit64 __user *, new_rlim,
5 # struct rlimit64 __user *, old_rlim)
6
7 @define _SYSCALL_PRLIMIT64_NAME
8 %(
9 name = "prlimit64"
10 %)
11
12 @define _SYSCALL_PRLIMIT64_ARGSTR
13 %(
14 argstr = sprintf("%d, %s, %s, %p", pid, resource_str, new_rlim_str, old_rlim_uaddr)
15 %)
16
17 @define _SYSCALL_PRLIMIT64_REGARGS
18 %(
19 pid = int_arg(1)
20 resource = int_arg(2)
21 resource_str = _rlimit_resource_str(resource)
22 new_rlim_uaddr = pointer_arg(3)
23 new_rlim_str = _struct_rlimit_u(new_rlim_uaddr)
24 old_rlim_uaddr = pointer_arg(4)
25 %)
26
27 @define _SYSCALL_PRLIMIT64_REGARGS_STORE
28 %(
29 if (@probewrite(pid))
30 set_int_arg(1, pid)
31
32 if (@probewrite(resource))
33 set_int_arg(2, resource)
34
35 if (@probewrite(new_rlim_uaddr))
36 set_pointer_arg(3, new_rlim_uaddr)
37
38 if (@probewrite(old_rlim_uaddr))
39 set_pointer_arg(4, old_rlim_uaddr)
40 %)
41
42 probe syscall.prlimit64 = dw_syscall.prlimit64 !, nd_syscall.prlimit64 ? {}
43 probe syscall.prlimit64.return = dw_syscall.prlimit64.return !,
44 nd_syscall.prlimit64.return ? {}
45
46 # dw_prlimit64 _____________________________________________________
47
48 probe dw_syscall.prlimit64 = kernel.function("sys_prlimit64").call ?
49 {
50 @_SYSCALL_PRLIMIT64_NAME
51 pid = __int32($pid)
52 resource = __int32($resource)
53 resource_str = _rlimit_resource_str(resource)
54 new_rlim_uaddr = $new_rlim
55 new_rlim_str = _struct_rlimit_u(new_rlim_uaddr)
56 old_rlim_uaddr = $old_rlim
57 @_SYSCALL_PRLIMIT64_ARGSTR
58 }
59 probe dw_syscall.prlimit64.return = kernel.function("sys_prlimit64").return ?
60 {
61 @_SYSCALL_PRLIMIT64_NAME
62 @SYSC_RETVALSTR($return)
63 }
64
65 # nd_prlimit64 _____________________________________________________
66
67 probe nd_syscall.prlimit64 = nd1_syscall.prlimit64!, nd2_syscall.prlimit64!, tp_syscall.prlimit64
68 { }
69
70 probe nd1_syscall.prlimit64 = kprobe.function("sys_prlimit64") ?
71 {
72 @_SYSCALL_PRLIMIT64_NAME
73 asmlinkage()
74 @_SYSCALL_PRLIMIT64_REGARGS
75 @_SYSCALL_PRLIMIT64_ARGSTR
76 }
77
78 /* kernel 4.17+ */
79 probe nd2_syscall.prlimit64 = kprobe.function(@arch_syscall_prefix "sys_prlimit64") ?
80 {
81 __set_syscall_pt_regs(pointer_arg(1))
82 @_SYSCALL_PRLIMIT64_NAME
83 @_SYSCALL_PRLIMIT64_REGARGS
84 @_SYSCALL_PRLIMIT64_ARGSTR
85 },
86 {
87 %( @_IS_SREG_KERNEL %? @_SYSCALL_PRLIMIT64_REGARGS_STORE %)
88 }
89
90 /* kernel 3.5+, but undesirable because it affects all syscalls */
91 probe tp_syscall.prlimit64 = kernel.trace("sys_enter")
92 {
93 __set_syscall_pt_regs($regs)
94 @__syscall_compat_gate(@const("__NR_prlimit64"), @const("__NR_compat_prlimit64"))
95 @_SYSCALL_PRLIMIT64_NAME
96 @_SYSCALL_PRLIMIT64_REGARGS
97 @_SYSCALL_PRLIMIT64_ARGSTR
98 },
99 {
100 %( @_IS_SREG_KERNEL %? @_SYSCALL_PRLIMIT64_REGARGS_STORE %)
101 }
102
103 probe nd_syscall.prlimit64.return = nd1_syscall.prlimit64.return!, nd2_syscall.prlimit64.return!, tp_syscall.prlimit64.return
104 { }
105
106 probe nd1_syscall.prlimit64.return = kprobe.function("sys_prlimit64").return ?
107 {
108 @_SYSCALL_PRLIMIT64_NAME
109 @SYSC_RETVALSTR(returnval())
110 }
111
112 /* kernel 4.17+ */
113 probe nd2_syscall.prlimit64.return = kprobe.function(@arch_syscall_prefix "sys_prlimit64").return ?
114 {
115 @_SYSCALL_PRLIMIT64_NAME
116 @SYSC_RETVALSTR(returnval())
117 }
118
119 /* kernel 3.5+, but undesirable because it affects all syscalls */
120 probe tp_syscall.prlimit64.return = kernel.trace("sys_exit")
121 {
122 __set_syscall_pt_regs($regs)
123 @__syscall_compat_gate(@const("__NR_prlimit64"), @const("__NR_compat_prlimit64"))
124 @_SYSCALL_PRLIMIT64_NAME
125 @SYSC_RETVALSTR($ret)
126 }