Debian Codegraph @

tapset/linux/sysc_setregid.stp

raw
1 # setregid ___________________________________________________
2 # long sys_setregid(gid_t rgid, gid_t egid)
3 #
4
5 @define _SYSCALL_SETREGID_NAME
6 %(
7 name = "setregid"
8 %)
9
10 @define _SYSCALL_SETREGID_ARGSTR
11 %(
12 argstr = sprintf("%d, %d", rgid, egid)
13 %)
14
15 @define _SYSCALL_GATE
16 %(
17 %( arch == "x86_64" %?
18 // There are actually 3 x86_64 setregid syscalls numbers (which
19 // get mapped to 2 syscall functions:
20 // - __NR_setregid which gets mapped to sys_setregid()
21 // - __NR_ia32_setregid32 which also gets mapped to
22 // sys_setregid()
23 // - __NR_ia32_setregid which gets mapped to sys_setregid16()
24 // (which is a wrapper around sys_setregid())
25 // So, we need to avoid sys_setregid() calls that come from
26 // sys_setregid16().
27 @__syscall_compat_gate(@const("__NR_setregid"),
28 @const("__NR_ia32_setregid32"))
29 %:
30 %( arch == "i386" %?
31 // On i386, there are 2 setregid syscall numbers:
32 // - __NR_setregid which gets mapped to sys_setregid16
33 // - __NR_setregid32 which gets mapped to sys_setregid
34 // Since this gets called from a probe on sys_setregid, we'll
35 // make sure this is really __NR_setregid32.
36 @__syscall_nr_gate(@const("__NR_setregid32"))
37 %)
38 %)
39 %)
40
41 @define _SYSCALL_SETREGID_REGARGS
42 %(
43 rgid = __int32(uint_arg(1))
44 egid = __int32(uint_arg(2))
45 %)
46
47 @define _SYSCALL_SETREGID_REGARGS_STORE
48 %(
49 if (@probewrite(rgid))
50 set_uint_arg(1, __int32(rgid))
51
52 if (@probewrite(egid))
53 set_uint_arg(2, __int32(egid))
54 %)
55
56 @define _SYSCALL_SETREGID16_REGARGS
57 %(
58 rgid = __short(uint_arg(1))
59 egid = __short(uint_arg(2))
60 %)
61
62 @define _SYSCALL_SETREGID16_REGARGS_STORE
63 %(
64 if (@probewrite(rgid))
65 set_uint_arg(1, __short(rgid))
66
67 if (@probewrite(egid))
68 set_uint_arg(2, __short(egid))
69 %)
70
71 probe syscall.setregid = dw_syscall.setregid !, nd_syscall.setregid ? {}
72 probe syscall.setregid.return = dw_syscall.setregid.return !,
73 nd_syscall.setregid.return ? {}
74
75 # dw_setregid _____________________________________________________
76
77 probe dw_syscall.setregid = kernel.function("sys_setregid").call
78 {
79 @_SYSCALL_GATE
80 @_SYSCALL_SETREGID_NAME
81 rgid = __int32($rgid)
82 egid = __int32($egid)
83 @_SYSCALL_SETREGID_ARGSTR
84 }
85 probe dw_syscall.setregid.return = kernel.function("sys_setregid").return
86 {
87 @_SYSCALL_GATE
88 @_SYSCALL_SETREGID_NAME
89 @SYSC_RETVALSTR($return)
90 }
91
92 # nd_setregid _____________________________________________________
93
94 probe nd_syscall.setregid = nd1_syscall.setregid!, nd2_syscall.setregid!, tp_syscall.setregid
95 { }
96
97 probe nd1_syscall.setregid = kprobe.function("sys_setregid") ?
98 {
99 @_SYSCALL_GATE
100 @_SYSCALL_SETREGID_NAME
101 asmlinkage()
102 @_SYSCALL_SETREGID_REGARGS
103 @_SYSCALL_SETREGID_ARGSTR
104 }
105
106 /* kernel 4.17+ */
107 probe nd2_syscall.setregid = kprobe.function(@arch_syscall_prefix "sys_setregid") ?
108 {
109 __set_syscall_pt_regs(pointer_arg(1))
110 @_SYSCALL_SETREGID_NAME
111 @_SYSCALL_SETREGID_REGARGS
112 @_SYSCALL_SETREGID_ARGSTR
113 },
114 {
115 %( @_IS_SREG_KERNEL %? @_SYSCALL_SETREGID_REGARGS_STORE %)
116 }
117
118 /* kernel 3.5+, but undesirable because it affects all syscalls */
119 probe tp_syscall.setregid = kernel.trace("sys_enter")
120 {
121 __set_syscall_pt_regs($regs)
122 @__syscall_compat_gate(@const("__NR_setregid"), @const("__NR_compat_setregid32"))
123 @_SYSCALL_SETREGID_NAME
124 @_SYSCALL_SETREGID_REGARGS
125 @_SYSCALL_SETREGID_ARGSTR
126 },
127 {
128 %( @_IS_SREG_KERNEL %? @_SYSCALL_SETREGID_REGARGS_STORE %)
129 }
130
131 probe nd_syscall.setregid.return = nd1_syscall.setregid.return!, nd2_syscall.setregid.return!, tp_syscall.setregid.return
132 { }
133
134 probe nd1_syscall.setregid.return = kprobe.function("sys_setregid").return ?
135 {
136 @_SYSCALL_GATE
137 @_SYSCALL_SETREGID_NAME
138 @SYSC_RETVALSTR(returnval())
139 }
140
141 /* kernel 4.17+ */
142 probe nd2_syscall.setregid.return = kprobe.function(@arch_syscall_prefix "sys_setregid").return ?
143 {
144 @_SYSCALL_SETREGID_NAME
145 @SYSC_RETVALSTR(returnval())
146 }
147
148 /* kernel 3.5+, but undesirable because it affects all syscalls */
149 probe tp_syscall.setregid.return = kernel.trace("sys_exit")
150 {
151 __set_syscall_pt_regs($regs)
152 @__syscall_compat_gate(@const("__NR_setregid"), @const("__NR_compat_setregid32"))
153 @_SYSCALL_SETREGID_NAME
154 @SYSC_RETVALSTR($ret)
155 }
156
157 # setregid16 _________________________________________________
158 # long sys_setregid16(old_gid_t rgid, old_gid_t egid)
159 #
160
161 probe syscall.setregid16 = dw_syscall.setregid16 !, nd_syscall.setregid16 ? {}
162 probe syscall.setregid16.return = dw_syscall.setregid16.return !,
163 nd_syscall.setregid16.return ? {}
164
165 # dw_setregid16 _____________________________________________________
166
167 probe dw_syscall.setregid16 = kernel.function("sys_setregid16").call ?
168 {
169 @_SYSCALL_SETREGID_NAME
170 rgid = __short($rgid)
171 egid = __short($egid)
172 @_SYSCALL_SETREGID_ARGSTR
173 }
174 probe dw_syscall.setregid16.return = kernel.function("sys_setregid16").return ?
175 {
176 @_SYSCALL_SETREGID_NAME
177 @SYSC_RETVALSTR($return)
178 }
179
180 # nd_setregid16 _____________________________________________________
181
182 probe nd_syscall.setregid16 = nd1_syscall.setregid16!, nd2_syscall.setregid16!, tp_syscall.setregid16
183 { }
184
185 probe nd1_syscall.setregid16 = kprobe.function("sys_setregid16") ?
186 {
187 @_SYSCALL_SETREGID_NAME
188 asmlinkage()
189 @_SYSCALL_SETREGID16_REGARGS
190 @_SYSCALL_SETREGID_ARGSTR
191 }
192
193 /* kernel 4.17+ */
194 probe nd2_syscall.setregid16 = kprobe.function(@arch_syscall_prefix "sys_setregid16") ?
195 {
196 __set_syscall_pt_regs(pointer_arg(1))
197 @_SYSCALL_SETREGID_NAME
198 @_SYSCALL_SETREGID16_REGARGS
199 @_SYSCALL_SETREGID_ARGSTR
200 },
201 {
202 %( @_IS_SREG_KERNEL %? @_SYSCALL_SETREGID16_REGARGS_STORE %)
203 }
204
205 /* kernel 3.5+, but undesirable because it affects all syscalls */
206 probe tp_syscall.setregid16 = kernel.trace("sys_enter")
207 {
208 __set_syscall_pt_regs($regs)
209 @__compat_syscall_gate(@const("__NR_compat_setregid"))
210 @_SYSCALL_SETREGID_NAME
211 @_SYSCALL_SETREGID16_REGARGS
212 @_SYSCALL_SETREGID_ARGSTR
213 },
214 {
215 %( @_IS_SREG_KERNEL %? @_SYSCALL_SETREGID16_REGARGS_STORE %)
216 }
217
218 probe nd_syscall.setregid16.return = nd1_syscall.setregid16.return!, nd2_syscall.setregid16.return!, tp_syscall.setregid16.return
219 { }
220
221 probe nd1_syscall.setregid16.return = kprobe.function("sys_setregid16").return ?
222 {
223 @_SYSCALL_SETREGID_NAME
224 @SYSC_RETVALSTR(returnval())
225 }
226
227 /* kernel 4.17+ */
228 probe nd2_syscall.setregid16.return = kprobe.function(@arch_syscall_prefix "sys_setregid16").return ?
229 {
230 @_SYSCALL_SETREGID_NAME
231 @SYSC_RETVALSTR(returnval())
232 }
233
234 /* kernel 3.5+, but undesirable because it affects all syscalls */
235 probe tp_syscall.setregid16.return = kernel.trace("sys_exit")
236 {
237 __set_syscall_pt_regs($regs)
238 @__compat_syscall_gate(@const("__NR_compat_setregid"))
239 @_SYSCALL_SETREGID_NAME
240 @SYSC_RETVALSTR($ret)
241 }