Debian Codegraph @

tapset/linux/sysc_delete_module.stp

raw
1 # delete_module ______________________________________________
2 # long sys_delete_module(const char __user *name_user, unsigned int flags)
3
4 @define _SYSCALL_DELETE_MODULE_NAME
5 %(
6 name = "delete_module"
7 %)
8
9 @define _SYSCALL_DELETE_MODULE_ARGSTR
10 %(
11 argstr = sprintf("%s, %s", name_user, _module_flags_str(flags))
12 %)
13
14 @define _SYSCALL_DELETE_MODULE_REGARGS
15 %(
16 name_user = user_string_quoted(pointer_arg(1))
17 name_user_unquoted = user_string_nofault(pointer_arg(1))
18 flags = uint_arg(2)
19 flags_str = _module_flags_str(flags)
20 %)
21
22 @define _SYSCALL_DELETE_MODULE_REGARGS_STORE
23 %(
24 if (@probewrite(name_user_unquoted))
25 set_user_string_arg(pointer_arg(1), name_user_unquoted)
26
27 if (@probewrite(flags))
28 set_uint_arg(2, flags)
29 %)
30
31 probe syscall.delete_module = dw_syscall.delete_module !, nd_syscall.delete_module ? {}
32 probe syscall.delete_module.return = dw_syscall.delete_module.return !, nd_syscall.delete_module.return ? {}
33
34 # dw_delete_module _____________________________________________________
35
36 probe dw_syscall.delete_module = kernel.function("sys_delete_module").call ?
37 {
38 @_SYSCALL_DELETE_MODULE_NAME
39 name_user = user_string_quoted($name_user)
40 flags = __uint32($flags)
41 flags_str = _module_flags_str(__uint32($flags))
42 @_SYSCALL_DELETE_MODULE_ARGSTR
43 }
44 probe dw_syscall.delete_module.return =
45 kernel.function("sys_delete_module").return ?
46 {
47 @_SYSCALL_DELETE_MODULE_NAME
48 @SYSC_RETVALSTR($return)
49 }
50
51 # nd_delete_module _____________________________________________________
52
53 probe nd_syscall.delete_module = nd1_syscall.delete_module!, nd2_syscall.delete_module!, tp_syscall.delete_module
54 { }
55
56 probe nd1_syscall.delete_module = kprobe.function("sys_delete_module") ?
57 {
58 @_SYSCALL_DELETE_MODULE_NAME
59 asmlinkage()
60 @_SYSCALL_DELETE_MODULE_REGARGS
61 @_SYSCALL_DELETE_MODULE_ARGSTR
62 }
63
64 /* kernel 4.17+ */
65 probe nd2_syscall.delete_module = kprobe.function(@arch_syscall_prefix "sys_delete_module") ?
66 {
67 __set_syscall_pt_regs(pointer_arg(1))
68 @_SYSCALL_DELETE_MODULE_NAME
69 @_SYSCALL_DELETE_MODULE_REGARGS
70 @_SYSCALL_DELETE_MODULE_ARGSTR
71 },
72 {
73 %( @_IS_SREG_KERNEL %? @_SYSCALL_DELETE_MODULE_REGARGS_STORE %)
74 }
75
76 /* kernel 3.5+, but undesirable because it affects all syscalls */
77 probe tp_syscall.delete_module = kernel.trace("sys_enter")
78 {
79 __set_syscall_pt_regs($regs)
80 @__syscall_compat_gate(@const("__NR_delete_module"), @const("__NR_compat_delete_module"))
81 @_SYSCALL_DELETE_MODULE_NAME
82 @_SYSCALL_DELETE_MODULE_REGARGS
83 @_SYSCALL_DELETE_MODULE_ARGSTR
84 },
85 {
86 %( @_IS_SREG_KERNEL %? @_SYSCALL_DELETE_MODULE_REGARGS_STORE %)
87 }
88
89 probe nd_syscall.delete_module.return = nd1_syscall.delete_module.return!, nd2_syscall.delete_module.return!, tp_syscall.delete_module.return
90 { }
91
92 probe nd1_syscall.delete_module.return =
93 kprobe.function("sys_delete_module").return ?
94 {
95 @_SYSCALL_DELETE_MODULE_NAME
96 @SYSC_RETVALSTR(returnval())
97 }
98
99 /* kernel 4.17+ */
100 probe nd2_syscall.delete_module.return = kprobe.function(@arch_syscall_prefix "sys_delete_module").return ?
101 {
102 @_SYSCALL_DELETE_MODULE_NAME
103 @SYSC_RETVALSTR(returnval())
104 }
105
106 /* kernel 3.5+, but undesirable because it affects all syscalls */
107 probe tp_syscall.delete_module.return = kernel.trace("sys_exit")
108 {
109 __set_syscall_pt_regs($regs)
110 @__syscall_compat_gate(@const("__NR_delete_module"), @const("__NR_compat_delete_module"))
111 @_SYSCALL_DELETE_MODULE_NAME
112 @SYSC_RETVALSTR($ret)
113 }