Debian Codegraph @

tapset/linux/sysc_rt_sigpending.stp

raw
1 # rt_sigpending ______________________________________________
2 #
3 # long sys_rt_sigpending(sigset_t __user *set, size_t sigsetsize)
4 # COMPAT_SYSCALL_DEFINE2(rt_sigpending, compat_sigset_t __user *, uset,
5 # compat_size_t, sigsetsize)
6 # asmlinkage long sys32_rt_sigpending(compat_sigset_t __user *set,
7 # compat_size_t sigsetsize)
8 #
9
10 @define _SYSCALL_RT_SIGPENDING_NAME
11 %(
12 name = "rt_sigpending"
13 %)
14
15 @define _SYSCALL_RT_SIGPENDING_ARGSTR
16 %(
17 argstr = sprintf("%p, %u", set_uaddr, sigsetsize)
18 %)
19
20 @define _SYSCALL_RT_SIGPENDING_REGARGS
21 %(
22 set_uaddr = pointer_arg(1)
23 sigsetsize = ulong_arg(2)
24 %)
25
26 @define _SYSCALL_RT_SIGPENDING_REGARGS_STORE
27 %(
28 if (@probewrite(set_uaddr))
29 set_pointer_arg(1, set_uaddr)
30
31 if (@probewrite(sigsetsize))
32 set_ulong_arg(2, sigsetsize)
33 %)
34
35 probe syscall.rt_sigpending = dw_syscall.rt_sigpending !,
36 nd_syscall.rt_sigpending ? {}
37 probe syscall.rt_sigpending.return = dw_syscall.rt_sigpending.return !,
38 nd_syscall.rt_sigpending.return ? {}
39
40 # dw_rt_sigpending _____________________________________________________
41
42 probe dw_syscall.rt_sigpending = __syscall.rt_sigpending ?,
43 kernel.function("compat_sys_rt_sigpending").call !,
44 kernel.function("sys32_rt_sigpending").call ?
45 {
46 @_SYSCALL_RT_SIGPENDING_NAME
47 set_uaddr = @choose_defined($uset, $set)
48 sigsetsize = @__compat_ulong($sigsetsize)
49 @_SYSCALL_RT_SIGPENDING_ARGSTR
50 }
51 probe __syscall.rt_sigpending = kernel.function("sys_rt_sigpending").call ?
52 {
53 @__syscall_gate(@const("__NR_rt_sigpending"))
54 }
55 probe dw_syscall.rt_sigpending.return = __syscall.rt_sigpending.return ?,
56 kernel.function("compat_sys_rt_sigpending").return !,
57 kernel.function("sys32_rt_sigpending").return ?
58 {
59 @_SYSCALL_RT_SIGPENDING_NAME
60 @SYSC_RETVALSTR($return)
61 }
62 probe __syscall.rt_sigpending.return =
63 kernel.function("sys_rt_sigpending").return ?
64 {
65 @__syscall_gate(@const("__NR_rt_sigpending"))
66 }
67
68 # nd_rt_sigpending _____________________________________________________
69
70 probe nd_syscall.rt_sigpending = nd1_syscall.rt_sigpending!, nd2_syscall.rt_sigpending!, tp_syscall.rt_sigpending
71 { }
72
73 probe nd1_syscall.rt_sigpending = __nd1_syscall.rt_sigpending ?,
74 __nd1_syscall.compat_rt_sigpending ?
75 {
76 @_SYSCALL_RT_SIGPENDING_NAME
77 asmlinkage()
78 @_SYSCALL_RT_SIGPENDING_REGARGS
79 @_SYSCALL_RT_SIGPENDING_ARGSTR
80 }
81 probe __nd1_syscall.rt_sigpending = kprobe.function("sys_rt_sigpending") ?
82 {
83 @__syscall_gate(@const("__NR_rt_sigpending"))
84 }
85 probe __nd1_syscall.compat_rt_sigpending =
86 kprobe.function("compat_sys_rt_sigpending") !,
87 kprobe.function("sys32_rt_sigpending") ?
88 {
89 }
90
91 /* kernel 4.17+ */
92 probe nd2_syscall.rt_sigpending =
93 kprobe.function(@arch_syscall_prefix "sys_rt_sigpending") ?,
94 kprobe.function(@arch_syscall_prefix "compat_sys_rt_sigpending") ?
95 {
96 __set_syscall_pt_regs(pointer_arg(1))
97 @_SYSCALL_RT_SIGPENDING_NAME
98 @_SYSCALL_RT_SIGPENDING_REGARGS
99 @_SYSCALL_RT_SIGPENDING_ARGSTR
100 },
101 {
102 %( @_IS_SREG_KERNEL %? @_SYSCALL_RT_SIGPENDING_REGARGS_STORE %)
103 }
104
105 /* kernel 3.5+, but undesirable because it affects all syscalls */
106 probe tp_syscall.rt_sigpending = kernel.trace("sys_enter")
107 {
108 __set_syscall_pt_regs($regs)
109 @__syscall_compat_gate(@const("__NR_rt_sigpending"), @const("__NR_compat_rt_sigpending"))
110 @_SYSCALL_RT_SIGPENDING_NAME
111 @_SYSCALL_RT_SIGPENDING_REGARGS
112 @_SYSCALL_RT_SIGPENDING_ARGSTR
113 },
114 {
115 %( @_IS_SREG_KERNEL %? @_SYSCALL_RT_SIGPENDING_REGARGS_STORE %)
116 }
117
118 probe nd_syscall.rt_sigpending.return = nd1_syscall.rt_sigpending.return!, nd2_syscall.rt_sigpending.return!, tp_syscall.rt_sigpending.return
119 { }
120
121 probe nd1_syscall.rt_sigpending.return =
122 __nd1_syscall.rt_sigpending.return ?,
123 __nd1_syscall.compat_rt_sigpending.return ?
124 {
125 @_SYSCALL_RT_SIGPENDING_NAME
126 @SYSC_RETVALSTR(returnval())
127 }
128 probe __nd1_syscall.rt_sigpending.return =
129 kprobe.function("sys_rt_sigpending").return ?
130 {
131 @__syscall_gate(@const("__NR_rt_sigpending"))
132 }
133 probe __nd1_syscall.compat_rt_sigpending.return =
134 kprobe.function("compat_sys_rt_sigpending").return !,
135 kprobe.function("sys32_rt_sigpending").return ?
136 {
137 }
138
139 /* kernel 4.17+ */
140 probe nd2_syscall.rt_sigpending.return =
141 kprobe.function(@arch_syscall_prefix "sys_rt_sigpending").return ?,
142 kprobe.function(@arch_syscall_prefix "compat_sys_rt_sigpending").return ?
143 {
144 @_SYSCALL_RT_SIGPENDING_NAME
145 @SYSC_RETVALSTR(returnval())
146 }
147
148 /* kernel 3.5+, but undesirable because it affects all syscalls */
149 probe tp_syscall.rt_sigpending.return = kernel.trace("sys_exit")
150 {
151 __set_syscall_pt_regs($regs)
152 @__syscall_compat_gate(@const("__NR_rt_sigpending"), @const("__NR_compat_rt_sigpending"))
153 @_SYSCALL_RT_SIGPENDING_NAME
154 @SYSC_RETVALSTR($ret)
155 }