Debian Codegraph @

tapset/linux/sysc_sigsuspend.stp

raw
1 # sigsuspend _________________________________________________
2 # #ifdef CONFIG_OLD_SIGSUSPEND
3 # SYSCALL_DEFINE1(sigsuspend, old_sigset_t, mask)
4 # #endif
5 # #ifdef CONFIG_OLD_SIGSUSPEND3
6 # SYSCALL_DEFINE3(sigsuspend, int, unused1, int, unused2, old_sigset_t, mask)
7 # #endif
8 # asmlinkage long
9 # sys32_sigsuspend(int history0, int history1, old_sigset_t mask)
10 # long sys_sigsuspend(old_sigset_t mask)
11
12 @define _SYSCALL_SIGSUSPEND_NAME
13 %(
14 name = "sigsuspend"
15 %)
16
17 @define _SYSCALL_SIGSUSPEND_ARGSTR
18 %(
19 argstr = sprintf("%s", mask_str)
20 %)
21
22 @define _SYSCALL_GATE
23 %(
24 %( arch == "s390" && kernel_v >= "3.15" %?
25 # s390 switched from assembly compat wrappers to C-based
26 # wrappers in kernel 3.15.
27 @__syscall_gate_compat_simple
28 %)
29 %)
30
31 probe syscall.sigsuspend = dw_syscall.sigsuspend !, nd_syscall.sigsuspend ? {}
32 probe syscall.sigsuspend.return = dw_syscall.sigsuspend.return !,
33 nd_syscall.sigsuspend.return ? {}
34
35 # dw_sigsuspend _____________________________________________________
36
37 probe dw_syscall.sigsuspend = __syscall.sigsuspend ?,
38 kernel.function("sys32_sigsuspend").call ?,
39 kernel.function("compat_sys_sigsuspend").call ?
40 {
41 @_SYSCALL_SIGSUSPEND_NAME
42 %( arch == "mips" && CONFIG_TRAD_SIGNALS == "y" %?
43 mask = __ulong($uset)
44 %:
45 mask = __ulong($mask)
46 %)
47 mask_str = _stp_sigmask_str(mask)
48 @_SYSCALL_SIGSUSPEND_ARGSTR
49 }
50 probe __syscall.sigsuspend = kernel.function("sys_sigsuspend").call ?
51 {
52 @_SYSCALL_GATE
53 }
54 probe dw_syscall.sigsuspend.return = __syscall.sigsuspend.return ?,
55 kernel.function("sys32_sigsuspend").return ?,
56 kernel.function("compat_sys_sigsuspend").return ?
57 {
58 @_SYSCALL_SIGSUSPEND_NAME
59 @SYSC_RETVALSTR($return)
60 }
61 probe __syscall.sigsuspend.return = kernel.function("sys_sigsuspend").return ?
62 {
63 @_SYSCALL_GATE
64 }
65
66 # nd_sigsuspend _____________________________________________________
67
68 probe nd_syscall.sigsuspend = nd1_syscall.sigsuspend!, nd2_syscall.sigsuspend!, tp_syscall.sigsuspend
69 { }
70
71 probe nd1_syscall.sigsuspend = __nd1_syscall.sigsuspend ?,
72 __nd1_syscall.sys32_sigsuspend ?
73 {
74 @_SYSCALL_SIGSUSPEND_NAME
75 mask_str = _stp_sigmask_str(mask)
76 @_SYSCALL_SIGSUSPEND_ARGSTR
77 }
78 probe __nd1_syscall.sigsuspend = __nd1_syscall.sys_sigsuspend ?,
79 kprobe.function("compat_sys_sigsuspend") ?
80 {
81 asmlinkage()
82 %( CONFIG_OLD_SIGSUSPEND == "y" %?
83 mask = ulong_arg(1)
84 %:
85 # CONFIG_OLD_SIGSUSPEND3 has mask as the 3rd argument.
86 mask = ulong_arg(3)
87 %)
88 }
89 probe __nd1_syscall.sys_sigsuspend = kprobe.function("sys_sigsuspend") ?
90 {
91 asmlinkage()
92 @_SYSCALL_GATE
93 }
94 probe __nd1_syscall.sys32_sigsuspend = kprobe.function("sys32_sigsuspend") ?
95 {
96 asmlinkage()
97 mask = ulong_arg(3)
98 }
99
100 /* kernel 4.17+ */
101 probe nd2_syscall.sigsuspend =
102 kprobe.function(@arch_syscall_prefix "sys_sigsuspend") ?
103 {
104 __set_syscall_pt_regs(pointer_arg(1))
105 @_SYSCALL_SIGSUSPEND_NAME
106 mask = ulong_arg(3)
107 mask_str = _stp_sigmask_str(mask)
108 @_SYSCALL_SIGSUSPEND_ARGSTR
109 },
110 {
111 %( @_IS_SREG_KERNEL %?
112 if (@probewrite(mask))
113 set_ulong_arg(3, mask)
114 %)
115 }
116
117 /* kernel 3.5+, but undesirable because it affects all syscalls */
118 probe tp_syscall.sigsuspend = kernel.trace("sys_enter")
119 {
120 __set_syscall_pt_regs($regs)
121 @__syscall_compat_gate(@const("__NR_sigsuspend"), @const("__NR_compat_sigsuspend"))
122 @_SYSCALL_SIGSUSPEND_NAME
123 %( CONFIG_OLD_SIGSUSPEND == "y" %?
124 mask = ulong_arg(1)
125 %:
126 # CONFIG_OLD_SIGSUSPEND3 has mask as the 3rd argument.
127 mask = ulong_arg(3)
128 %)
129 mask_str = _stp_sigmask_str(mask)
130 @_SYSCALL_SIGSUSPEND_ARGSTR
131 },
132 {
133 %( @_IS_SREG_KERNEL %?
134 %( CONFIG_OLD_SIGSUSPEND == "y" %?
135 if (@probewrite(mask))
136 set_ulong_arg(1, mask)
137 %:
138 if (@probewrite(mask))
139 set_ulong_arg(3, mask)
140 %)
141 %)
142 }
143
144 probe nd_syscall.sigsuspend.return = nd1_syscall.sigsuspend.return!, nd2_syscall.sigsuspend.return!, tp_syscall.sigsuspend.return
145 { }
146
147 probe nd1_syscall.sigsuspend.return =
148 __nd1_syscall.sigsuspend.return ?,
149 kprobe.function("sys32_sigsuspend").return ?,
150 kprobe.function("compat_sys_sigsuspend").return ?
151 {
152 @_SYSCALL_SIGSUSPEND_NAME
153 @SYSC_RETVALSTR(returnval())
154 }
155 probe __nd1_syscall.sigsuspend.return =
156 kprobe.function("sys_sigsuspend").return ?
157 {
158 @_SYSCALL_GATE
159 }
160
161 /* kernel 4.17+ */
162 probe nd2_syscall.sigsuspend.return = kprobe.function(@arch_syscall_prefix "sys_sigsuspend").return ?
163 {
164 @_SYSCALL_SIGSUSPEND_NAME
165 @SYSC_RETVALSTR(returnval())
166 }
167
168 /* kernel 3.5+, but undesirable because it affects all syscalls */
169 probe tp_syscall.sigsuspend.return = kernel.trace("sys_exit")
170 {
171 __set_syscall_pt_regs($regs)
172 @__syscall_compat_gate(@const("__NR_sigsuspend"), @const("__NR_compat_sigsuspend"))
173 @_SYSCALL_SIGSUSPEND_NAME
174 @SYSC_RETVALSTR($ret)
175 }