Debian Codegraph @

tapset/linux/powerpc/sysc_sysctl32.stp

raw
1 # compat_sys_sysctl ________________________________________
2 #
3 # long compat_sys_sysctl(struct __sysctl_args32 __user *args)
4 #
5 # To match the ia64/s390/x86_64 versions (and to match the syscall variant of
6 # this probe), the 'syscall.compat_sysctl' probe name is deprecated and
7 # 'syscall.sysctl32' should be used instead. To use the old name without
8 # changing your script, use the '--compatible 2.8' stap option.
9 #
10
11 @define _SYSCALL_SYSCTL32_NAME
12 %(
13 name = "sysctl"
14 %)
15
16 @define _SYSCALL_SYSCTL32_ARGSTR
17 %(
18 argstr = sprintf("%p", args)
19 %)
20
21 probe
22 %( systemtap_v <= "2.8"
23 %? syscall.compat_sysctl %: syscall.sysctl32
24 %) = dw_syscall.sysctl32 !, nd_syscall.sysctl32 ? {}
25 probe
26 %( systemtap_v <= "2.8"
27 %? syscall.compat_sysctl.return %: syscall.sysctl32.return
28 %) = dw_syscall.sysctl32.return !, nd_syscall.sysctl32.return ? {}
29
30 # Note that these probes used to hook up to the ppc64 specific
31 # compat_sys_sysctl() kernel function. However, that was just a
32 # wrapper around sys_sysctl(). To avoid syscall nesting, we'll just
33 # ignore compat_sys_sysctl().
34
35 # dw_compat_sys_sysctl ________________________________________
36
37 probe
38 %( systemtap_v <= "2.8"
39 %? dw_syscall.compat_sysctl %: dw_syscall.sysctl32
40 %)
41 = %( systemtap_v <= "3.1"
42 %? kernel.function("compat_sys_sysctl").call ? %: never %)
43 {
44 @_SYSCALL_SYSCTL32_NAME
45 args = %( systemtap_v <= "3.1" %? $args %: 0 %)
46 @_SYSCALL_SYSCTL32_ARGSTR
47 }
48 probe
49 %( systemtap_v <= "2.8"
50 %? dw_syscall.compat_sysctl.return %: dw_syscall.sysctl32.return
51 %)
52 = %( systemtap_v <= "3.1"
53 %? kernel.function("compat_sys_sysctl").return ? %: never %)
54 {
55 @_SYSCALL_SYSCTL32_NAME
56 retstr = %( systemtap_v <= "3.1" %? return_str(1, $return) %: "0" %)
57 }
58
59 # nd_compat_sys_sysctl ________________________________________
60
61 probe
62 %( systemtap_v <= "2.8"
63 %? nd_syscall.compat_sysctl %: nd_syscall.sysctl32
64 %)
65 = %( systemtap_v <= "3.1" %? kprobe.function("compat_sys_sysctl") ?
66 %: never %)
67 {
68 @_SYSCALL_SYSCTL32_NAME
69 asmlinkage()
70 args = %( systemtap_v <= "3.1" %? pointer_arg(1) %: 0 %)
71 @_SYSCALL_SYSCTL32_ARGSTR
72 }
73 probe
74 %( systemtap_v <= "2.8"
75 %? nd_syscall.compat_sysctl.return %: nd_syscall.sysctl32.return
76 %)
77 = %( systemtap_v <= "3.1"
78 %? kprobe.function("compat_sys_sysctl").return ? %: never %)
79 {
80 @_SYSCALL_SYSCTL32_NAME
81 retstr = %( systemtap_v <= "3.1" %? returnstr(1) %: "0" %)
82 }