Debian Codegraph @

tapset/linux/powerpc/sysc_mmap2.stp

raw
1 # In kernels < 2.6.33, mmap()/mmap2() was handled by arch-specific
2 # code. In kernels >= 2.6.33, the arch-specific code just calls
3 # generic sys_mmap_pgoff().
4 %( kernel_v < "2.6.33" %?
5 # mmap2
6 # long sys_mmap2(unsigned long addr, size_t len,
7 # unsigned long prot, unsigned long flags,
8 # unsigned long fd, unsigned long pgoff)
9 # long compat_sys_mmap2(unsigned long addr, size_t len,
10 # unsigned long prot, unsigned long flags,
11 # unsigned long fd, unsigned long pgoff)
12 #
13
14 @define _SYSCALL_MMAP2_NAME
15 %(
16 name = "mmap2"
17 %)
18
19 @define _SYSCALL_MMAP2_ARGSTR
20 %(
21 argstr = sprintf("%p, %u, %s, %s, %d, %d", start,
22 length, prot_str, flags_str, fd, pgoffset)
23 %)
24
25 probe syscall.mmap2 = dw_syscall.mmap2 !, nd_syscall.mmap2 ? {}
26 probe syscall.mmap2.return = dw_syscall.mmap2.return !, nd_syscall.mmap2.return ? {}
27
28 # dw_mmap2 _____________________________________________________
29
30 probe dw_syscall.mmap2 = kernel.function("sys_mmap2") ?,
31 kernel.function("compat_sys_mmap2") ?
32 {
33 @_SYSCALL_MMAP2_NAME
34 start = $addr
35 length = $len
36 prot = $prot
37 prot_str = _mprotect_prot_str(prot)
38 flags = $flags
39 flags_str = _mmap_flags(flags)
40 # Although the kernel gets an unsigned long fd, on the
41 # user-side it is a signed int. Fix this.
42 fd = __int32($fd)
43 pgoffset = $pgoff
44 @_SYSCALL_MMAP2_ARGSTR
45 }
46 probe dw_syscall.mmap2.return = kernel.function("sys_mmap2").return ?,
47 kernel.function("compat_sys_mmap2").return ?
48 {
49 @_SYSCALL_MMAP2_NAME
50 @SYSC_RETVALSTR2($return)
51 }
52
53 # nd_mmap2 _____________________________________________________
54
55 probe nd_syscall.mmap2 = kprobe.function("sys_mmap2") ?,
56 kprobe.function("compat_sys_mmap2") ?
57 {
58 @_SYSCALL_MMAP2_NAME
59 asmlinkage()
60 start = ulong_arg(1)
61 length = ulong_arg(2)
62 prot = ulong_arg(3)
63 prot_str = _mprotect_prot_str(prot)
64 flags = ulong_arg(4)
65 flags_str = _mmap_flags(flags)
66 # Although the kernel gets an unsigned long fd, on the
67 # user-side it is a signed int. Fix this.
68 fd = int_arg(5)
69 pgoffset = ulong_arg(6)
70 @_SYSCALL_MMAP2_ARGSTR
71 }
72 probe nd_syscall.mmap2.return = kprobe.function("sys_mmap2").return ?,
73 kprobe.function("compat_sys_mmap2").return ?
74 {
75 @_SYSCALL_MMAP2_NAME
76 @SYSC_RETVALSTR2(returnval())
77 }
78 %)