Debian Codegraph @

tapset/linux/i386/sysc_mmap2.stp

raw
1 # In kernels < 2.6.33, mmap()/mmap2() was handled by arch-specific
2 # code. In kernels >= 2.6.33, the arch-specific code just calls
3 # generic sys_mmap_pgoff().
4 %( kernel_v < "2.6.33" %?
5 # mmap2 ____________________________________________
6 # sys_mmap2(unsigned long addr, unsigned long len,
7 # unsigned long prot, unsigned long flags,
8 # unsigned long fd, unsigned long pgoff)
9 #
10
11 @define _SYSCALL_MMAP2_NAME
12 %(
13 name = "mmap2"
14 %)
15
16 @define _SYSCALL_MMAP2_ARGSTR
17 %(
18 argstr = sprintf("%p, %u, %s, %s, %d, %d", start, length, prot_str,
19 flags_str, fd, pgoffset)
20 %)
21
22 probe syscall.mmap2 = dw_syscall.mmap2 !, nd_syscall.mmap2 ? {}
23 probe syscall.mmap2.return = dw_syscall.mmap2.return !, nd_syscall.mmap2.return ? {}
24
25 # dw_mmap2 _____________________________________________________
26
27 probe dw_syscall.mmap2 = __syscall.mmap2 ?, __syscall.mmap_pgoff ?
28 {
29 @_SYSCALL_MMAP2_NAME
30 start = $addr
31 length = $len
32 prot = $prot
33 prot_str = _mprotect_prot_str(prot)
34 flags = $flags
35 flags_str = _mmap_flags(flags)
36 # Although the kernel gets an unsigned long fd, on the
37 # user-side it is a signed int. Fix this.
38 fd = __int32($fd)
39 @_SYSCALL_MMAP2_ARGSTR
40 }
41 probe __syscall.mmap2 = kernel.function("sys_mmap2")
42 {
43 pgoffset = $pgoff
44 }
45 probe __syscall.mmap_pgoff = kernel.function("sys_mmap_pgoff")
46 {
47 pgoffset = $pgoff * @const("PAGE_SIZE")
48 }
49 probe dw_syscall.mmap2.return = kernel.function("sys_mmap2").return ?,
50 kernel.function("sys_mmap_pgoff").return ?
51 {
52 @_SYSCALL_MMAP2_NAME
53 @SYSC_RETVALSTR2($return)
54 }
55
56 # nd_mmap2 _____________________________________________________
57
58 probe nd_syscall.mmap2 = __nd_syscall.mmap2 ?, __nd_syscall.mmap_pgoff ?
59 {
60 @_SYSCALL_MMAP2_NAME
61 asmlinkage()
62 start = ulong_arg(1)
63 length = ulong_arg(2)
64 prot = ulong_arg(3)
65 prot_str = _mprotect_prot_str(prot)
66 flags = ulong_arg(4)
67 flags_str = _mmap_flags(flags)
68 # Although the kernel gets an unsigned long fd, on the
69 # user-side it is a signed int. Fix this.
70 fd = int_arg(5)
71 @_SYSCALL_MMAP2_ARGSTR
72 }
73 probe __nd_syscall.mmap2 = kprobe.function("sys_mmap2")
74 {
75 asmlinkage()
76 pgoffset = ulong_arg(6)
77 }
78 probe __nd_syscall.mmap_pgoff = kprobe.function("sys_mmap_pgoff")
79 {
80 asmlinkage()
81 pgoffset = ulong_arg(6) * @const("PAGE_SIZE")
82 }
83 probe nd_syscall.mmap2.return = kprobe.function("sys_mmap2").return ?,
84 kprobe.function("sys_mmap_pgoff").return ?
85 {
86 @_SYSCALL_MMAP2_NAME
87 @SYSC_RETVALSTR2(returnval())
88 }
89 %)