Debian Codegraph @

tapset/linux/i386/sysc_execve.stp

raw
1 %( kernel_v < "3.7" %?
2 # execve _____________________________________________________
3 #
4 # In kernels < 3.7, sys_execve() was in arch-specific code (and had
5 # varying arguments). It was just a wrapper around generic
6 # do_execve(), but the wrapper could error out before calling
7 # do_execve(). So, we'll have to handle it in arch-specific tapset
8 # code to catch all calls.
9 #
10 # asmlinkage int sys_execve(struct pt_regs regs)
11
12 @define _SYSCALL_EXECVE_NAME
13 %(
14 name = "execve"
15 %)
16
17 @define _SYSCALL_EXECVE_ARGSTR
18 %(
19 argstr = sprintf("%s, %s, %s", filename, args, env_str)
20 %)
21
22 probe syscall.execve = dw_syscall.execve !, nd_syscall.execve {}
23 probe syscall.execve.return = dw_syscall.execve.return !, nd_syscall.execve.return {}
24
25 # dw_execve _____________________________________________________
26
27 probe dw_syscall.execve = kernel.function("sys_execve").call
28 {
29 @_SYSCALL_EXECVE_NAME
30 filename = user_string_quoted(@choose_defined($regs->bx, $regs->ebx))
31 args = __get_argv(@choose_defined($regs->cx, $regs->ecx), 0)
32 env_str = __get_argv(@choose_defined($regs->dx, $regs->edx), 0)
33 @_SYSCALL_EXECVE_ARGSTR
34 }
35 probe dw_syscall.execve.return = kernel.function("sys_execve").return
36 {
37 @_SYSCALL_EXECVE_NAME
38 @SYSC_RETVALSTR($return)
39 }
40
41 # nd_execve _____________________________________________________
42
43 probe nd_syscall.execve = kprobe.function("sys_execve")
44 {
45 @_SYSCALL_EXECVE_NAME
46 %( kernel_v < "2.6.30" %?
47 asmlinkage()
48 # Notice here that a pointer to a pt_regs struct isn't passed,
49 # a pt_regs struct itself is passed.
50 filename = user_string_quoted(pointer_arg(1))
51 args = __get_argv(pointer_arg(2), 0)
52 env_str = __get_argv(pointer_arg(3), 0)
53 %:
54 __regs = &@cast(ulong_arg(1), "pt_regs", "kernel<asm/ptrace.h>")
55 filename = user_string_quoted(__regs->bx)
56 args = __get_argv(__regs->cx, 0)
57 env_str = __get_argv(__regs->dx, 0)
58 %)
59 @_SYSCALL_EXECVE_ARGSTR
60 }
61 probe nd_syscall.execve.return = kprobe.function("sys_execve").return
62 {
63 @_SYSCALL_EXECVE_NAME
64 @SYSC_RETVALSTR(returnval())
65 }
66 %)