Debian Codegraph @

tapset/linux/s390/sysc_mmap.stp

raw
1 # In kernels < 2.6.33, mmap()/mmap2() was handled by arch-specific
2 # code. In kernels >= 2.6.33, the arch-specific code just calls
3 # generic sys_mmap_pgoff().
4 %( kernel_v < "2.6.33" %?
5 # mmap _________________________________________________
6 # long old_mmap(struct mmap_arg_struct __user *arg)
7 # long old32_mmap(struct mmap_arg_struct_emu31 __user *arg)
8 #
9
10 @define _SYSCALL_MMAP_NAME
11 %(
12 name = "mmap"
13 %)
14
15 @define _SYSCALL_MMAP_ARGSTR
16 %(
17 argstr = sprintf("%p, %u, %s, %s, %d, %d", start, len,
18 prot_str, flags_str, fd, offset)
19 %)
20
21 probe syscall.mmap = dw_syscall.mmap !, nd_syscall.mmap ? {}
22 probe syscall.mmap.return = dw_syscall.mmap.return !, nd_syscall.mmap.return ? {}
23
24 # dw_mmap _____________________________________________________
25
26 probe dw_syscall.mmap = __syscall.mmap ?, __syscall.mmap32 ?
27 {
28 @_SYSCALL_MMAP_NAME
29 prot_str = _mprotect_prot_str(prot)
30 flags_str = _mmap_flags(flags)
31 @_SYSCALL_MMAP_ARGSTR
32 }
33 probe __syscall.mmap = kernel.function("old_mmap") ?,
34 kernel.function("SyS_s390_old_mmap") ?
35 {
36 start = user_long(&@cast($arg, "mmap_arg_struct")->addr)
37 len = user_ulong(&@cast($arg, "mmap_arg_struct")->len)
38 prot = user_long(&@cast($arg, "mmap_arg_struct")->prot)
39 flags = user_long(&@cast($arg, "mmap_arg_struct")->flags)
40 fd = user_long(&@cast($arg, "mmap_arg_struct")->fd)
41 offset = user_long(&@cast($arg, "mmap_arg_struct")->offset)
42 }
43 probe __syscall.mmap32 = kernel.function("old32_mmap")
44 {
45 start = user_int(&@cast($arg, "mmap_arg_struct_emu31")->addr)
46 len = user_uint32(&@cast($arg, "mmap_arg_struct_emu31")->len)
47 prot = user_int(&@cast($arg, "mmap_arg_struct_emu31")->prot)
48 flags = user_int(&@cast($arg, "mmap_arg_struct_emu31")->flags)
49 fd = user_int(&@cast($arg, "mmap_arg_struct_emu31")->fd)
50 offset = user_int(&@cast($arg, "mmap_arg_struct_emu31")->offset)
51 }
52
53 probe dw_syscall.mmap.return = kernel.function("old_mmap").return ?,
54 kernel.function("old32_mmap").return ?,
55 kernel.function("SyS_s390_old_mmap").return ?
56 {
57 @_SYSCALL_MMAP_NAME
58 @SYSC_RETVALSTR2($return)
59 }
60
61 # nd_mmap _____________________________________________________
62
63 probe nd_syscall.mmap = __nd_syscall.mmap ?, __nd_syscall.mmap32 ?
64 {
65 @_SYSCALL_MMAP_NAME
66 prot_str = _mprotect_prot_str(prot)
67 flags_str = _mmap_flags(flags)
68 @_SYSCALL_MMAP_ARGSTR
69 }
70 probe __nd_syscall.mmap = kprobe.function("old_mmap") ?,
71 kprobe.function("SyS_s390_old_mmap") ?
72 {
73 asmlinkage()
74 __args = &@ulong_cast(pointer_arg(1))
75 start = user_ulong(&(__args)[0])
76 len = user_ulong(&(__args)[1])
77 prot = user_ulong(&(__args)[2])
78 flags = user_ulong(&(__args)[3])
79 fd = user_long(&(__args)[4])
80 offset = user_ulong(&(__args)[5])
81 }
82 probe __nd_syscall.mmap32 = kprobe.function("old32_mmap")
83 {
84 asmlinkage()
85 __args = &@uint_cast(pointer_arg(1))
86 start = user_uint32(&(__args)[0])
87 len = user_uint32(&(__args)[1])
88 prot = user_uint32(&(__args)[2])
89 flags = user_uint32(&(__args)[3])
90 fd = user_int(&(__args)[4])
91 offset = user_uint32(&(__args)[5])
92 }
93 probe nd_syscall.mmap.return = kprobe.function("old_mmap").return ?,
94 kprobe.function("old32_mmap").return ?,
95 kprobe.function("SyS_s390_old_mmap").return ?
96 {
97 @_SYSCALL_MMAP_NAME
98 @SYSC_RETVALSTR2(returnval())
99 }
100 %)