Debian Codegraph @

tapset/linux/ia64/sysc_mmap.stp

raw
1 # In kernels < 2.6.33, mmap()/mmap2() was handled by arch-specific
2 # code. In kernels >= 2.6.33, the arch-specific code just calls
3 # generic sys_mmap_pgoff().
4 %( kernel_v < "2.6.33" %?
5 # mmap
6 # sys_mmap (unsigned long addr, unsigned long len, int prot, int flags, int fd, long off)
7 #
8
9 @define _SYSCALL_MMAP_NAME
10 %(
11 name = "mmap"
12 %)
13
14 @define _SYSCALL_MMAP_ARGSTR
15 %(
16 argstr = sprintf("%p, %u, %s, %s, %d, %d", start, len, prot_str,
17 flags_str, fd, offset)
18 %)
19
20 probe syscall.mmap = dw_syscall.mmap !, nd_syscall.mmap ? {}
21 probe syscall.mmap.return = dw_syscall.mmap.return !, nd_syscall.mmap.return ? {}
22
23 # dw_mmap _____________________________________________________
24
25 probe dw_syscall.mmap = kernel.function("sys_mmap") ?
26 {
27 @_SYSCALL_MMAP_NAME
28 start = $addr
29 len = $len
30 prot = $prot
31 prot_str = _mprotect_prot_str(prot)
32 flags = $flags
33 flags_str = _mmap_flags(flags)
34 # Although the kernel gets an unsigned long fd, on the
35 # user-side it is a signed int. Fix this.
36 fd = __int32($fd)
37 offset = $off
38 @_SYSCALL_MMAP_ARGSTR
39 }
40
41 probe dw_syscall.mmap.return = kernel.function("sys_mmap").return ?
42 {
43 @_SYSCALL_MMAP_NAME
44 @SYSC_RETVALSTR2($return)
45 }
46
47 # nd_mmap _____________________________________________________
48
49 probe nd_syscall.mmap = kprobe.function("sys_mmap") ?
50 {
51 @_SYSCALL_MMAP_NAME
52 asmlinkage()
53 start = ulong_arg(1)
54 len = ulong_arg(2)
55 prot = int_arg(3)
56 prot_str = _mprotect_prot_str(prot)
57 flags = int_arg(4)
58 flags_str = _mmap_flags(flags)
59 fd = int_arg(5)
60 offset = long_arg(6)
61 @_SYSCALL_MMAP_ARGSTR
62 }
63
64 probe nd_syscall.mmap.return = kprobe.function("sys_mmap").return ?
65 {
66 @_SYSCALL_MMAP_NAME
67 @SYSC_RETVALSTR2(returnval())
68 }
69 %)