Debian Codegraph @

packages/seacas/applications/blot/setup.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE SETUP (MSHDEF, ZMMESH)
9 C=======================================================================
10
11 C --*** SETUP *** (MESH) Setup for plot set
12 C -- Written by Amy Gilkey - revised 05/26/88
13 C -- D. P. Flanagan, 07/27/82
14 C --
15 C --SETUP sets graphics parameters common to the plot sequence. It
16 C --computes the display area and window for each view. It also computes
17 C --and sets the axis lengths and limits (with "nice" tick intervals).
18 C --The only information that is returned about the axis is the
19 C --starting locations and the label size factor (through COMMON).
20 C --
21 C --Parameters:
22 C -- MSHDEF - IN - the display modes for all views (none/defined)
23 C -- (as in /MSHOPT/)
24 C -- ZMMESH - IN - the zoomed mesh coordinates
25 C --
26 C --Common Variables:
27 C -- Uses XISSYM, YISSYM, XAXSYM, YAXSYM, LFTSYM, BOTSYM of /VIEWS/
28 C -- Uses ZMMESH of /MSHLIM/
29 C -- Uses DVIEW0 of /LAYOUT/
30 C -- Sets DVIEW, WVIEW of /LAYOUT/
31 C -- Uses DTW, VWSCL of /DEVDAT/
32
33 PARAMETER (KLFT=1, KRGT=2, KBOT=3, KTOP=4, KNEA=5, KFAR=6)
34
35 include 'views.blk'
36 include 'layout.blk'
37 include 'layoud.blk'
38 include 'devdat.blk'
39
40 CHARACTER*(*) MSHDEF(4)
41 REAL ZMMESH(KTOP)
42
43 INTEGER NDEFVW, IXVW
44 LOGICAL RGTVW, TOPVW
45 LOGICAL XISDIV, YISDIV
46
47 RGTVW(I) = (I .EQ. 2) .OR. (I .EQ. 4)
48 TOPVW(I) = (I .EQ. 1) .OR. (I .EQ. 2)
49
50 XISDIV = (MSHDEF(1) .NE. 'NONE')
51 YISDIV = (MSHDEF(4) .NE. 'NONE')
52
53 C --WXRNG and WYRNG are the window limits for a single view
54 WXRNG = ZMMESH(KRGT) - ZMMESH(KLFT)
55 WYRNG = ZMMESH(KTOP) - ZMMESH(KBOT)
56
57 C --Set view device boundaries
58
59 IF (XISDIV .EQV. YISDIV) THEN
60 RAT = WXRNG / WYRNG
61 ELSE IF (XISDIV) THEN
62 RAT = (2 * WXRNG) / WYRNG
63 ELSE IF (YISDIV) THEN
64 RAT = WXRNG / (2 * WYRNG)
65 END IF
66
67 C --DXRNG2 and DYRNG2 are the device limits for all defined views / 2
68 DXRNG2 = 0.5 * (DVIEW0(KRGT) - DVIEW0(KLFT))
69 DYRNG2 = 0.5 * (DVIEW0(KTOP) - DVIEW0(KBOT))
70 IF (RAT .LT. 0.99) THEN
71 DXRNG2 = DXRNG2 * RAT
72 ELSE IF (RAT .GT. 1.01) THEN
73 DYRNG2 = DYRNG2 / RAT
74 END IF
75
76 DXMID = 0.5 * (DVIEW0(KRGT) + DVIEW0(KLFT))
77 DYMID = 0.5 * (DVIEW0(KTOP) + DVIEW0(KBOT))
78 DO 100 IVW = 1, NDEFVW (.TRUE.)
79 IVIEW = IXVW (.TRUE., IVW)
80 IF (XISDIV) THEN
81 IF (RGTVW(IVIEW)) THEN
82 DVIEW(KLFT,IVIEW) = DXMID
83 DVIEW(KRGT,IVIEW) = DXMID + DXRNG2
84 ELSE
85 DVIEW(KLFT,IVIEW) = DXMID - DXRNG2
86 DVIEW(KRGT,IVIEW) = DXMID
87 END IF
88 ELSE
89 DVIEW(KLFT,IVIEW) = DXMID - DXRNG2
90 DVIEW(KRGT,IVIEW) = DXMID + DXRNG2
91 END IF
92 IF (YISDIV) THEN
93 IF (TOPVW(IVIEW)) THEN
94 DVIEW(KBOT,IVIEW) = DYMID
95 DVIEW(KTOP,IVIEW) = DYMID + DYRNG2
96 ELSE
97 DVIEW(KBOT,IVIEW) = DYMID - DYRNG2
98 DVIEW(KTOP,IVIEW) = DYMID
99 END IF
100 ELSE
101 DVIEW(KBOT,IVIEW) = DYMID - DYRNG2
102 DVIEW(KTOP,IVIEW) = DYMID + DYRNG2
103 END IF
104 100 CONTINUE
105
106 C --Set window limits
107
108 IF (XISSYM) THEN
109 IF (LFTSYM) THEN
110 WLFT = XAXSYM
111 WRGT = XAXSYM + WXRNG
112 ELSE
113 WLFT = XAXSYM
114 WRGT = XAXSYM - WXRNG
115 END IF
116 ELSE
117 WLFT = ZMMESH(KLFT)
118 WRGT = ZMMESH(KRGT)
119 END IF
120 IF (YISSYM) THEN
121 IF (BOTSYM) THEN
122 WBOT = YAXSYM
123 WTOP = YAXSYM + WYRNG
124 ELSE
125 WBOT = YAXSYM
126 WTOP = YAXSYM - WYRNG
127 END IF
128 ELSE
129 WBOT = ZMMESH(KBOT)
130 WTOP = ZMMESH(KTOP)
131 END IF
132
133 C --Set view window boundaries
134
135 DO 110 IVW = 1, NDEFVW (.TRUE.)
136 IVIEW = IXVW (.TRUE., IVW)
137 IF (XISSYM .AND. (.NOT. RGTVW(IVIEW))) THEN
138 WVIEW(KLFT,IVIEW) = WRGT
139 WVIEW(KRGT,IVIEW) = WLFT
140 ELSE
141 WVIEW(KLFT,IVIEW) = WLFT
142 WVIEW(KRGT,IVIEW) = WRGT
143 END IF
144 IF (YISSYM .AND. (.NOT. TOPVW(IVIEW))) THEN
145 WVIEW(KBOT,IVIEW) = WTOP
146 WVIEW(KTOP,IVIEW) = WBOT
147 ELSE
148 WVIEW(KBOT,IVIEW) = WBOT
149 WVIEW(KTOP,IVIEW) = WTOP
150 END IF
151 110 CONTINUE
152
153 C --Set window to device units ratio
154
155 DTW = MIN (ABS (WRGT - WLFT), ABS (WTOP - WBOT))
156 & / (DVIEW0(KRGT) - DVIEW0(KLFT))
157
158 IF (XISDIV .OR. YISDIV) THEN
159 VWSCL = 0.5
160 ELSE
161 VWSCL = 1.0
162 END IF
163
164 RETURN
165 END