Debian Codegraph @

packages/seacas/applications/blot/adjlim.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE ADJLIM (MSHDEF,
9 & XISSYM, YISSYM, LFTSYM, BOTSYM, XAXSYM, YAXSYM,
10 & SQUARE, RDMESH, ZMMESH)
11 C=======================================================================
12
13 C --*** ADJLIM *** (MESH) Adjust zoom mesh limits
14 C -- Written by Amy Gilkey - revised 05/26/88
15 C --
16 C --ADJLIM adjusts the zoom window to make a (square) window centered on
17 C --the user-requested limits. If there are symmetric views, the center
18 C --is the symmetry axis. The zoom mesh limits may be adjusted to take
19 C --account of the fact that one axis may be twice as long as the other
20 C --axis in 2-view plots.
21 C --
22 C --On a 2-view plot, a check is made to see if the "short" limits
23 C --can be made half as long. This occurs if the user-specified window
24 C --can be fit within the given "short" window.
25 C --
26 C --Parameters:
27 C -- MSHDEF - IN - the display modes for all views (none/defined)
28 C -- (as in /MSHOPT/)
29 C -- XISSYM - IN - true iff X views are symmetric vs copies
30 C -- (false if X not divided)
31 C -- YISSYM - IN - true iff Y views are symmetric vs copies
32 C -- (false if Y not divided)
33 C -- LFTSYM - IN - true iff symmetry line to left of main view
34 C -- BOTSYM - IN - true iff symmetry line to bottom of main view
35 C -- XAXSYM - IN - the vertical symmetry axis
36 C -- YAXSYM - IN - the horizontal symmetry axis
37 C -- SQUARE - IN - true iff window limits must be square
38 C -- RDMESH - IN - the user-requested window limits
39 C -- (left, right, bottom, top)
40 C -- ZMMESH - OUT - the window limits (may be RDMESH)
41 C -- (left, right, bottom, top)
42
43 PARAMETER (KLFT=1, KRGT=2, KBOT=3, KTOP=4)
44
45 CHARACTER*(*) MSHDEF(4)
46 LOGICAL XISSYM, YISSYM, LFTSYM, BOTSYM
47 LOGICAL SQUARE
48 REAL RDMESH(KTOP), ZMMESH(KTOP)
49
50 IF (XISSYM) THEN
51 IF (LFTSYM) THEN
52 XRNG = RDMESH(KRGT) - XAXSYM
53 ELSE
54 XRNG = XAXSYM - RDMESH(KLFT)
55 END IF
56 ELSE
57 XRNG = RDMESH(KRGT) - RDMESH(KLFT)
58 END IF
59 IF (YISSYM) THEN
60 IF (BOTSYM) THEN
61 YRNG = RDMESH(KTOP) - YAXSYM
62 ELSE
63 YRNG = YAXSYM - RDMESH(KBOT)
64 END IF
65 ELSE
66 YRNG = RDMESH(KTOP) - RDMESH(KBOT)
67 END IF
68
69 IF (SQUARE) THEN
70 RNG = MAX (XRNG, YRNG)
71 IF ((MSHDEF(1) .NE. 'NONE') .AND. (MSHDEF(3) .EQ. 'NONE')) THEN
72 IF (XRNG .LE. 0.51*RNG) RNG = 0.5*RNG
73 END IF
74 ELSE
75 RNG = XRNG
76 END IF
77 IF (XISSYM) THEN
78 IF (LFTSYM) THEN
79 ZMMESH(KLFT) = XAXSYM
80 ZMMESH(KRGT) = ZMMESH(KLFT) + RNG
81 ELSE
82 ZMMESH(KRGT) = XAXSYM
83 ZMMESH(KLFT) = ZMMESH(KRGT) - RNG
84 END IF
85 ELSE
86 ZMMESH(KLFT) = 0.5 * (RDMESH(KRGT) + RDMESH(KLFT) - RNG)
87 ZMMESH(KRGT) = ZMMESH(KLFT) + RNG
88 END IF
89
90 IF (SQUARE) THEN
91 RNG = MAX (XRNG, YRNG)
92 IF ((MSHDEF(4) .NE. 'NONE') .AND. (MSHDEF(3) .EQ. 'NONE')) THEN
93 IF (YRNG .LE. 0.51*RNG) RNG = 0.5*RNG
94 END IF
95 ELSE
96 RNG = YRNG
97 END IF
98 IF (YISSYM) THEN
99 IF (BOTSYM) THEN
100 ZMMESH(KBOT) = YAXSYM
101 ZMMESH(KTOP) = ZMMESH(KBOT) + RNG
102 ELSE
103 ZMMESH(KTOP) = YAXSYM
104 ZMMESH(KBOT) = ZMMESH(KTOP) - RNG
105 END IF
106 ELSE
107 ZMMESH(KBOT) = 0.5 * (RDMESH(KTOP) + RDMESH(KBOT) - RNG)
108 ZMMESH(KTOP) = ZMMESH(KBOT) + RNG
109 END IF
110
111 RETURN
112 END