Debian Codegraph @

packages/seacas/applications/blot/mrknod.F

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE MRKNOD (F, HIDENP, XN, YN, ZN, IN2ELB,
9 & NMIN, NMAX, FMIN, FMAX, BLKCOL, *)
10 C=======================================================================
11
12 C --*** MRKNOD *** (DETOUR) Mark minimum/maximum nodal values
13 C -- Written by Amy Gilkey - revised 03/09/88
14 C --
15 C --MRKNOD marks the nodes which have the minimum or maximum values
16 C --with symbols.
17 C --
18 C --Parameters:
19 C -- F - IN - the nodal variable values
20 C -- HIDENP(i) - IN - true iff node i is hidden (3D only)
21 C -- XN, YN, ZN - IN - the nodal coordinates
22 C -- IN2ELB - IN - the element block for each node;
23 C -- <0 if not in any selected element block
24 C -- =0 if in more than one selected element block
25 C -- NMIN, NMAX - IN - the number of variables values matching the
26 C -- minimum and the maximum
27 C -- FMIN, FMAX - IN - the minimum and maximum function values
28 C -- BLKCOL - IN/OUT - the user selected colors of the element blocks.
29 C -- BLKCOL(0) = 1 if the user defined material
30 C -- colors should be used in mesh plots.
31 C -- = -1 if program selected colors should
32 C -- be used.
33 C -- BLKCOL(i) = the user selected color of element
34 C -- block i:
35 C -- -2 - no color selected by user.
36 C -- -1 - black
37 C -- 0 - white
38 C -- 1 - red
39 C -- 2 - green
40 C -- 3 - yellow
41 C -- 4 - blue
42 C -- 5 - cyan
43 C -- 6 - magenta
44 C -- * - return statement if the cancel function is active
45 C --
46 C --Common Variables:
47 C -- Uses IS3DIM, NUMNPF of /D3NUMS/
48 C -- Uses MAXMIN, MAXMAX of /CNTR/
49
50 include 'dbnums.blk'
51 include 'd3nums.blk'
52 include 'cntr.blk'
53
54 REAL F(NUMNPF)
55 LOGICAL HIDENP(NUMNPF)
56 REAL XN(NUMNPF), YN(NUMNPF), ZN(NUMNPF)
57 INTEGER IN2ELB(NUMNPF)
58 INTEGER BLKCOL(0:NELBLK)
59
60 LOGICAL GRABRT
61 LOGICAL MRKMIN, MRKMAX
62
63 CALL UGRCOL (0, BLKCOL)
64
65 MRKMIN = (MAXMIN .GE. NMIN)
66 MRKMAX = (MAXMAX .GE. NMAX)
67
68 IF ((FMIN .NE. FMAX) .AND. (MRKMIN .OR. MRKMAX)) THEN
69
70 C --Mark minimum and maximum values with centered symbols
71
72 DO 100 INP = 1, NUMNPF
73 IF (IS3DIM) THEN
74 IF (HIDENP(INP)) GOTO 100
75 END IF
76
77 IF (IN2ELB(INP) .GE. 0) THEN
78 IF (FMIN .EQ. F(INP)) THEN
79 IF (MRKMIN) THEN
80 IF (GRABRT ()) RETURN 1
81 #if NeedsDoubleEscape
82 CALL MPD2SY (1, XN(INP), YN(INP), '\\CCI')
83 CALL MPD2SY (1, XN(INP), YN(INP), '\\CCS')
84 #else
85 CALL MPD2SY (1, XN(INP), YN(INP), '\CCI')
86 CALL MPD2SY (1, XN(INP), YN(INP), '\CCS')
87 #endif
88 END IF
89 ELSE IF (FMAX .EQ. F(INP)) THEN
90 IF (MRKMAX) THEN
91 IF (GRABRT ()) RETURN 1
92 #if NeedsDoubleEscape
93 CALL MPD2SY (1, XN(INP), YN(INP), '\\CX')
94 CALL MPD2SY (1, XN(INP), YN(INP), '\\CCS')
95 #else
96 CALL MPD2SY (1, XN(INP), YN(INP), '\CX')
97 CALL MPD2SY (1, XN(INP), YN(INP), '\CCS')
98 #endif
99 END IF
100 END IF
101 END IF
102 100 CONTINUE
103
104 CALL PLTFLU
105 END IF
106
107 RETURN
108 END