Debian Codegraph @

packages/seacas/applications/blot/comand.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE COMAND (A, CURPRO,
9 & QAREC, INFREC, NAMECO, NAMELB, NAMES, TIMES, WHOTIM, IPTIMS,
10 & MAPEL, MAPND, IDELB, NEWELB, IELBST, IE2ELB,
11 & LENE, NLNKE, LINKE, XN, YN, ZN, XE, YE, ZE,
12 & ISEVOK,
13 & ISSNPS, IDNPS, NNNPS, ISSESS, IDESS, NEESS, NNESS,
14 & NCSTEP, LISNP, NLISEL, LISEL, LISNPS, LISESS,
15 & LISHV, LISGV, LISNV, LISEV, LIDSP, BLKCOL,
16 & NENUM, NEUTRL, NEWPRO, SHDCOL, ISHDCL,
17 $ EBNAME, NSNAME, SSNAME, NAMLEN, *)
18 C=======================================================================
19
20 C --*** COMAND *** (BLOT) Input and process commands
21 C -- Modified by John Glick - 11/21/88
22 C -- Written by Amy Gilkey - revised 05/20/88
23 C -- Dennis Flanagan, 11/18/82
24 C --
25 C --COMAND inputs and executes command lines. It returns when a plot
26 C --set is defined and the plots are requested.
27 C --
28 C --The command line uses the 1520 free-field reader.
29 C --
30 C --Parameters:
31 C -- A - IN - the dynamic memory base array
32 C -- CURPRO - IN - the current program name
33 C -- QAREC - IN - the QA records
34 C -- INFREC - IN - the information records
35 C -- NAMECO - IN - the coordinate names
36 C -- NAMELB - IN - the element block names
37 C -- NAMES - IN - the variable names
38 C -- TIMES - IN - the database times
39 C -- WHOTIM - IN - true iff whole (versus history) time step
40 C -- IPTIMS - IN/OUT - the selected time steps
41 C -- IDELB - IN - the element block ID array
42 C -- NEWELB - IN/OUT - the new element blocks flag
43 C -- 0 = no new element blocks (set elsewhere)
44 C -- 1 = new selected element blocks
45 C -- 2 = new displayed element blocks (implies new selected blocks)
46 C -- IELBST - IN/OUT - the element block status:
47 C -- -1 = OFF, 0 = ON, but not selected, 1 = selected
48 C -- IE2ELB - IN - the element block for each element
49 C -- LENE - IN - the cumulative element counts by element block
50 C -- NLNKE - IN - the number of nodes per element
51 C -- LINKE - IN - the element connectivity
52 C -- XN, YN, ZN - IN - the nodal mesh coordinates
53 C -- XE, YE, ZE - IN - the element centroid mesh coordinates
54 C -- ISEVOK - IN - the element block variable truth table;
55 C -- variable i of block j exists iff ISEVOK(j,i)
56 C -- ISSNPS - IN/OUT - the indices of the selected node sets (SETS)
57 C -- IDNPS - IN - the node set ID for each set
58 C -- NNNPS - IN - the number of nodes for each set
59 C -- ISSESS - IN/OUT - the indices of the selected side sets (SETS)
60 C -- IDESS - IN - the side set ID for each set
61 C -- NEESS - IN - the number of elements for each set
62 C -- NNESS - IN - the number of nodes for each set
63 C -- NCSTEP - IN/OUT - the current step number for display
64 C -- LISNP - IN/OUT - the indices of the selected nodes
65 C -- NLISEL - IN/OUT - the indices of the selected element blocks
66 C -- LISEL - IN/OUT - the indices of the selected elements (by block)
67 C -- LISNPS - IN/OUT - the indices of the selected node sets
68 C -- LISESS - IN/OUT - the indices of the selected side sets
69 C -- LISHV - IN/OUT - the indices of the selected history variables
70 C -- LISGV - IN/OUT - the indices of the selected global variables
71 C -- LISNV - IN/OUT - the indices of the selected nodal variables
72 C -- LISEV - IN/OUT - the indices of the selected element variables
73 C -- LIDSP - IN/OUT - the indices of the variables selected for
74 C -- display on the plot legend.
75 C -- BLKCOL - IN/OUT - the user selected colors of the element blocks.
76 C -- BLKCOL(0) = 1 if the user defined material
77 C -- colors should be used in mesh plots.
78 C -- = -1 if program selected colors should
79 C -- be used.
80 C -- BLKCOL(i) = the user selected color of element
81 C -- block i:
82 C -- -2 - no color selected by user.
83 C -- -1 - black
84 C -- 0 - white
85 C -- 1 - red
86 C -- 2 - green
87 C -- 3 - yellow
88 C -- 4 - blue
89 C -- 5 - cyan
90 C -- 6 - magenta
91 C -- NENUM - IN/OUT - the selected node/element numbers
92 C -- NEUTRL - OUT - The type of neutral file to write.
93 C -- NEWPRO - IN/OUT - the program indicator:
94 C -- 'N' = new program, initialize for program
95 C -- 'R' = new program, initialize for program with reset
96 C -- 'P' = old program, initialize for plot set
97 C --
98 C --Common Variables:
99 C -- Uses NVARHI, NVARGL, NVARNP, NVAREL of /DBNUMS/
100 C -- Uses NPTIMS of /TIMES/
101 C -- Uses NALVAR of /MSHOPT/
102
103 PARAMETER (MAXFLD = 80)
104 include 'params.blk'
105 include 'neutral.blk'
106 include 'dbnums.blk'
107 include 'times.blk'
108 include 'mshopt.blk'
109 include 'dbase.blk'
110 common /debugc/ cdebug
111 common /debugn/ idebug
112 character*8 cdebug
113
114 DIMENSION A(*)
115 CHARACTER*(*) CURPRO
116 CHARACTER*(MXSTLN) QAREC(4,*)
117 CHARACTER*(MXLNLN) INFREC(*)
118 CHARACTER*(MXSTLN) NAMECO(*)
119 CHARACTER*(MXSTLN) NAMELB(*)
120 CHARACTER*(NAMLEN) NAMES(*)
121 CHARACTER*(NAMLEN) EBNAME(*), NSNAME(*), SSNAME(*)
122 REAL TIMES(*)
123 LOGICAL WHOTIM(*)
124 INTEGER IPTIMS(*)
125 INTEGER MAPEL(*)
126 INTEGER MAPND(*)
127 INTEGER IDELB(*)
128 INTEGER NEWELB
129 INTEGER IELBST(*)
130 INTEGER IE2ELB(*)
131 INTEGER LENE(0:NELBLK), LINKE(*)
132 INTEGER NLNKE(*)
133 REAL XN(*), YN(*), ZN(*)
134 REAL XE(*), YE(*), ZE(*)
135 LOGICAL ISEVOK(*)
136 INTEGER ISSNPS(*)
137 INTEGER IDNPS(*), NNNPS(*)
138 INTEGER ISSESS(*)
139 INTEGER IDESS(*), NEESS(*), NNESS(*)
140 INTEGER LISNP(0:*)
141 INTEGER NLISEL(0:*)
142 INTEGER LISEL(0:*)
143 INTEGER LISNPS(0:*), LISESS(0:*)
144 INTEGER LISHV(0:*), LISGV(0:*), LISNV(0:*), LISEV(0:*)
145 INTEGER LIDSP(0:*)
146 INTEGER BLKCOL(0:NELBLK)
147 INTEGER NENUM(*)
148 INTEGER IDUMA(1)
149 REAL SHDCOL(7, NELBLK)
150 INTEGER ISHDCL(3, NELBLK)
151 CHARACTER NEWPRO
152 INTEGER IOSTAT
153 SAVE IOSTAT
154
155 LOGICAL MATSTR
156 LOGICAL OKABRT
157
158 INTEGER INTYP(MAXFLD+1)
159 CHARACTER*(MXNAME) CFIELD(MAXFLD)
160 INTEGER IFIELD(MAXFLD)
161 REAL RFIELD(MAXFLD)
162 C --INTYP, CFIELD, IFIELD, RFIELD - the free-field reader types,
163 C -- character fields, integer fields, and real fields
164
165 CHARACTER*(MXNAME) VERB, INVERB
166 CHARACTER*1024 INLINE(5)
167 CHARACTER*10 PROMPT
168 CHARACTER*(MXNAME) WORD
169 LOGICAL HELP
170 LOGICAL ISON
171 LOGICAL OK
172 INTEGER NEWMOD(4)
173
174 LOGICAL FIRST
175 SAVE FIRST
176 C --FIRST - true iff first time through routine
177
178 LOGICAL SAVLOG
179 SAVE SAVLOG
180 C --SAVLOG - true iff the log file is to be saved
181
182 CHARACTER*(MXSTLN) SAVPRO, MEMPRO
183 SAVE SAVPRO, MEMPRO
184 C --SAVPRO - the current program to be restored if mesh plot
185 C --MEMPRO - the current program used to reserve memory
186
187 LOGICAL MSHTYP, XYTYPE
188 SAVE MSHTYP, XYTYPE
189 C --MSHTYP - true iff mesh plot program
190 C --XYTYPE - true iff XY plot program
191
192 LOGICAL MESHOK
193 SAVE MESHOK
194 C --MESHOK - true iff a mesh is defined
195
196 CHARACTER*(MXSTLN) CMDTBL(18)
197 SAVE CMDTBL
198 C --CMDTBL - the command table
199
200 DATA FIRST / .TRUE. /
201
202 C --Command table follows. The table is ended by a blank entry.
203 C --Remember to change the dimensioned size when changing the table.
204 DATA (CMDTBL(I),I=1,10) /
205 1 'DETOUR ',
206 * 'PATHLINE ',
207 * 'SETS ',
208 * 'TPLOT ',
209 * 'SPLOT ',
210 2 'RANGE ',
211 * 'SELECT ',
212 * 'LIST ',
213 * 'PRINT ',
214 3 'SHOW '/
215 DATA (CMDTBL(I),I=11,18) /
216 * 'HELP ',
217 * 'SAVELOG ',
218 * 'LOG ',
219 4 'RESET ',
220 * 'EXIT ',
221 * 'END ',
222 * 'QUIT ',
223 5 ' ' /
224
225 IF (FIRST) THEN
226 CURPRO = 'BLOT'
227 NEWPRO = '*'
228 MSHTYP = .FALSE.
229 XYTYPE = .FALSE.
230
231 CALL MSCHK (.FALSE., MESHOK)
232
233 C --Open the log file
234 NLOG = 99
235 CALL OPNLOG (NLOG)
236 SAVLOG = .FALSE.
237 c savlog = (nlog .gt. 0)
238 if (cdebug .ne. ' ') savlog = (nlog .gt. 0)
239
240 FIRST = .FALSE.
241 END IF
242
243 NEUTRL = NONE
244 C --Select primary device (ready for any plot)
245 CALL GRSPAR ('DEVICE', 0, IDUM, WORD)
246
247 C --Set up to initialize for new plot set or new program
248
249 IF (NEWPRO .EQ. '*') THEN
250 INVERB = ' '
251 ELSE IF (NEWPRO .EQ. 'N') THEN
252 INVERB = 'initprog'
253 ELSE IF (NEWPRO .EQ. 'R') THEN
254 INVERB = 'initres'
255 ELSE
256 C --Restore saved program if mesh plot
257 IF (CURPRO .EQ. 'MESH') THEN
258 CURPRO = SAVPRO
259 INVERB = 'postmesh'
260 ELSE
261 INVERB = 'postplot'
262 END IF
263 END IF
264
265 C --Reserve memory needed in this routine
266
267 MEMPRO = CURPRO
268 IF (MEMPRO .EQ. 'PATHLINE') THEN
269 CALL MDRSRV ('LNSCR', KLNSCR, MAX (NUMNP, NUMEL))
270 CALL MDSTAT (NERR, MEM)
271 IF (NERR .GT. 0) GOTO 160
272 ELSE IF (MEMPRO .EQ. 'TPLOT') THEN
273 NTPSCR = MAX (NUMNP, NUMEL)
274 CALL MDRSRV ('TPSCR', KTPSCR, 2 * NTPSCR)
275 CALL MDSTAT (NERR, MEM)
276 IF (NERR .GT. 0) GOTO 160
277 END IF
278
279 C --Initialize for new plot set or new program
280
281 NEWPRO = ' '
282 IF (INVERB .NE. ' ') THEN
283 IFLD = 1
284 INTYP(1) = -999
285 INLINE(1) = ' '
286 C --Initialize the interrupt flag
287 ISON = OKABRT (.TRUE.)
288 GOTO 110
289 END IF
290
291 C --Get next command line and extract verb
292
293 100 CONTINUE
294 WRITE (*, *)
295 PROMPT = CURPRO
296 LPROM = LENSTR (PROMPT) + 2
297 PROMPT(LPROM-1:LPROM) = '> '
298 CALL GETINS ('parse', MAXFLD, NUMFLD, INTYP, CFIELD,
299 & IFIELD, RFIELD, ' ', IOSTAT, PROMPT, LPROM, *170)
300 IF (IOSTAT .NE. 0) THEN
301 CALL PRTERR ('CMDWARN', 'Error reading command')
302 GOTO 170
303 END IF
304 IF (NUMFLD .EQ. 0) GOTO 100
305 IF (NUMFLD .GT. MAXFLD)
306 & CALL PRTERR ('CMDWARN', 'Too many fields input')
307 INTYP(MIN(NUMFLD,MAXFLD)+1) = -999
308
309 C --Initialize the interrupt flag
310 ISON = OKABRT (.TRUE.)
311
312 CALL INISTR (5, CHAR(0), INLINE)
313 INLINE(1) = ' '
314 IFLD = 1
315 CALL FFCHAR (IFLD, INTYP, CFIELD, ' ', VERB)
316 IF (VERB .EQ. ' ') GOTO 150
317
318 C --Get the command verb
319
320 C --Save the command verb - it may be restored later
321 INVERB = VERB
322
323 WORD = VERB
324 CALL ABRSTR (VERB, WORD, CMDTBL)
325 IF (VERB .EQ. ' ') VERB = WORD
326
327 IF ((VERB(3:) .NE. ' ') .AND. (WORD(3:) .EQ. ' ')) THEN
328 CALL PRTERR ('CMDERR',
329 & 'Enter at least 3 letters for BLOT-level commands')
330 GOTO 150
331 END IF
332
333 C --These commands are valid at any level, including BLOT
334
335 C --Commands to switch programs
336
337 IF (VERB .EQ. 'SETS') THEN
338 CALL PRTERR ('CMDERR',
339 & 'This function has been moved into DETOUR')
340 GOTO 150
341
342 ELSE IF ((VERB .EQ. 'DETOUR') .OR. (VERB .EQ. 'PATHLINE')
343 & .OR. (VERB .EQ. 'TPLOT') .OR. (VERB .EQ. 'SPLOT')) THEN
344 C Commented out code that forces the user to type the whole
345 C program name on the command line to transfer to another program
346 c IF ((CURPRO .NE. 'BLOT') .AND. (CURPRO .NE. VERB)
347 c & .AND. (INVERB .NE. VERB)) THEN
348 c CALL PRTERR ('CMDERR',
349 c & 'Program name cannot be abbreviated')
350 c GOTO 150
351 c END IF
352 CALL FFADDC (VERB, INLINE(1))
353
354 IF (CURPRO .NE. VERB) THEN
355 IF (VERB .EQ. 'DETOUR') THEN
356 CALL DTCHK (.TRUE., OK)
357 ELSE IF (VERB .EQ. 'PATHLINE') THEN
358 CALL LNCHK (.TRUE., OK)
359 ELSE IF (VERB .EQ. 'TPLOT') THEN
360 CALL TPCHK (.TRUE., OK)
361 ELSE IF (VERB .EQ. 'SPLOT') THEN
362 CALL SPCHK (.TRUE., OK)
363 END IF
364 IF (.NOT. OK) GOTO 150
365
366 MSHTYP = (VERB .EQ. 'DETOUR') .OR. (VERB .EQ. 'PATHLINE')
367 XYTYPE = (VERB .EQ. 'TPLOT') .OR. (VERB .EQ. 'SPLOT')
368
369 CURPRO = VERB(1:8)
370 VERB = ' '
371
372 CALL FFCHAR (IFLD, INTYP, CFIELD, ' ', WORD)
373 IF (MATSTR (WORD, 'RESET', 1)) THEN
374 CALL FFADDC ('RESET', INLINE(1))
375 NEWPRO = 'R'
376 ELSE
377 NEWPRO = 'N'
378 END IF
379
380 ELSE
381 VERB = ' '
382 END IF
383
384 C --Commands to exit
385
386 ELSE IF ((VERB .EQ. 'EXIT') .OR. (VERB .EQ. 'END')
387 & .OR. (VERB .EQ. 'QUIT')) THEN
388 CALL FFADDC (VERB, INLINE(1))
389 VERB = ' '
390
391 CALL SCNEOF
392 NEWPRO = 'E'
393
394 C --Informational commands
395
396 ELSE IF ((VERB .EQ. 'LOG') .or. (verb .eq. 'SAVELOG')) THEN
397 if (verb .eq. 'SAVELOG') then
398 call prterr ('CMDSPEC', 'Please use the LOG command')
399 verb = 'LOG'
400 end if
401 IF (NLOG .LE. 0) THEN
402 CALL PRTERR ('CMDERR', 'Log file cannot be opened')
403 GOTO 150
404 END IF
405 VERB = ' '
406 SAVLOG = .TRUE.
407 IF (SAVLOG) THEN
408 WRITE (*, 10000) 'Log file will be saved'
409 ELSE
410 WRITE (*, 10000) 'Log file will NOT be saved'
411 END IF
412
413 ELSE IF (VERB .EQ. 'SELECT') THEN
414 CALL FFADDC (VERB, INLINE(1))
415 CALL FFCHAR (IFLD, INTYP, CFIELD, ' ', WORD)
416
417 CALL DBSEL (A, A, INLINE,
418 & WORD, IFLD, INTYP, CFIELD, IFIELD, RFIELD,
419 & NAMES, TIMES, WHOTIM, NPTIMS, IPTIMS,
420 & IDELB, LENE, IDNPS, IDESS,
421 & NCSTEP, LISNP, NLISEL, LISEL, LISNPS, LISESS,
422 & LISHV, LISGV, LISNV, LISEV, MAPEL, MAPND)
423 VERB = ' '
424 CALL MDSTAT (NERR, MEM)
425 IF (NERR .GT. 0) GOTO 160
426
427 ELSE IF ((VERB .EQ. 'LIST') .OR. (VERB .EQ. 'PRINT')) THEN
428 CALL DBLIST (A, INLINE,
429 & VERB, IFLD, INTYP, CFIELD, IFIELD, RFIELD,
430 & NAMECO, NAMELB, NAMES, QAREC, INFREC,
431 & TIMES, WHOTIM, NPTIMS, IPTIMS, XN, YN, ZN,
432 & IDELB, LENE, NLNKE, LINKE, ISEVOK,
433 & IDNPS, NNNPS, IDESS, NEESS, NNESS,
434 & NCSTEP, LISNP, NLISEL, LISEL, LISNPS, LISESS,
435 & LISHV, LISGV, LISNV, LISEV, EBNAME, NSNAME, SSNAME, NAMLEN,
436 * MAPEL, MAPND)
437 VERB = ' '
438 CALL MDSTAT (NERR, MEM)
439 IF (NERR .GT. 0) GOTO 160
440
441 ELSE IF (VERB .EQ. 'RANGE') THEN
442 CALL FFADDC (VERB, INLINE(1))
443 VERB = ' '
444
445 CALL FFCHAR (IFLD, INTYP, CFIELD, ' ', WORD)
446 CALL FFADDC (WORD, INLINE(1))
447 IVAR = LOCSTR (WORD, NVARHI+NVARGL+NVARNP+NVAREL, NAMES)
448 IF (IVAR .LE. 0) THEN
449 CALL PRTERR ('CMDERR', 'Expected variable name')
450 GOTO 150
451 END IF
452
453 IF (MSHTYP) THEN
454 CALL SCALER (A, A, 2, NAMES(IVAR), IVAR,
455 & .TRUE., IELBST, NALVAR, DUMMIN, DUMMAX, MAPEL, MAPND)
456 ELSE
457 CALL SCALER (A, A, 2, NAMES(IVAR), IVAR,
458 & .FALSE., IDUMA, 0, DUMMIN, DUMMAX, MAPEL, MAPND)
459 END IF
460 CALL MDSTAT (NERR, MEM)
461 IF (NERR .GT. 0) GOTO 160
462
463 ELSE IF ((VERB .EQ. 'SHOW') .AND. (CURPRO .NE. 'BLOT')) THEN
464 CALL LOWSTR (INVERB, VERB)
465
466 ELSE IF (VERB .EQ. 'HELP') THEN
467 ISON = HELP ('BLOT', 'COMMANDS', CFIELD(IFLD))
468 IF (.NOT. ISON) THEN
469 CALL SHOCMD ('BLOT Commands', CMDTBL)
470 CALL LOWSTR (INVERB, VERB)
471 ELSE
472 VERB = ' '
473 END IF
474
475 C --Reset command
476
477 ELSE IF (VERB .EQ. 'RESET') THEN
478 CALL FFADDC (VERB, INLINE(1))
479 CALL LOWSTR (INVERB, VERB)
480
481 else if (verb .eq. 'DEBUG') then
482 call ffaddc (verb, inline(1))
483 verb = ' '
484 call ffchar (ifld, intyp, cfield, ' ', cdebug)
485 call ffaddc (cdebug, inline(1))
486 call ffintg (ifld, intyp, ifield,
487 & 'debug constant', 0, idebug, *150)
488 call ffaddi (idebug, inline(1))
489
490 ELSE IF (CURPRO .EQ. 'BLOT') THEN
491 VERB = ' '
492 CALL PRTERR ('CMDERR', 'Expected a subprogram name')
493 GOTO 150
494 END IF
495
496 IF (VERB .EQ. ' ') GOTO 120
497
498 110 CONTINUE
499
500 C --Restore the command verb
501 VERB = INVERB
502
503 C --Perform general command
504
505 IF (MSHTYP .OR. XYTYPE) THEN
506 IIFLD = IFLD
507 CALL PLCOMD (A, CURPRO, XYTYPE, MESHOK, INLINE,
508 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
509 & TIMES, WHOTIM, IPTIMS)
510 CALL MDSTAT (NERR, MEM)
511 IF (NERR .GT. 0) GOTO 160
512 IF (VERB .EQ. ' ') GOTO 120
513 END IF
514
515 IF (MSHTYP) THEN
516
517 C --Perform MESH command
518
519 IIFLD = IFLD
520 CALL MSCOMD (A, CURPRO, MSHTYP, INLINE,
521 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
522 & NAMECO, NAMES, IDELB, NEWELB, IELBST, NEWMOD,
523 & IDNPS, ISSNPS, IDESS, ISSESS, BLKCOL, SHDCOL, ISHDCL)
524 CALL MDSTAT (NERR, MEM)
525 IF (NERR .GT. 0) GOTO 160
526 IF (VERB .EQ. ' ') GOTO 120
527
528 C --Perform DETOUR command
529
530 IF (CURPRO .EQ. 'DETOUR') THEN
531 IIFLD = IFLD
532 CALL DTCOMD (A, INLINE,
533 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
534 & NEWMOD, NAMES, IELBST,
535 & ISSNPS, ISSESS, LIDSP, MAPEL, MAPND, NAMLEN)
536 CALL MDSTAT (NERR, MEM)
537 IF (NERR .GT. 0) GOTO 160
538 IF (VERB .EQ. ' ') GOTO 120
539 END IF
540
541 C --Perform PATHLINE command
542
543 IF (CURPRO .EQ. 'PATHLINE') THEN
544 IIFLD = IFLD
545 CALL LNCOMD (A, INLINE,
546 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
547 & NAMES, ISEVOK, IE2ELB, A(KLNSCR))
548 CALL MDSTAT (NERR, MEM)
549 IF (NERR .GT. 0) GOTO 160
550 IF (VERB .EQ. ' ') GOTO 120
551 END IF
552
553 ELSE IF (XYTYPE) THEN
554
555 C --Perform TPLOT command
556
557 IF (CURPRO .EQ. 'TPLOT') THEN
558 IIFLD = IFLD
559 CALL TPCOMD (A, INLINE,
560 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD, MAXFLD,
561 & NAMES, ISEVOK, IE2ELB, A(KTPSCR), NTPSCR, MAPEL, MAPND)
562 CALL MDSTAT (NERR, MEM)
563 IF (NERR .GT. 0) GOTO 160
564 IF (VERB .EQ. ' ') GOTO 120
565 END IF
566
567 C --Perform SPLOT command
568
569 IF (CURPRO .EQ. 'SPLOT') THEN
570 IIFLD = IFLD
571 CALL SPCOMD (A, INLINE,
572 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
573 & NAMES, LENE, NLNKE, LINKE, XN, YN, ZN, XE, YE, ZE,
574 & ISEVOK, IE2ELB, NENUM, LIDSP, MAPEL, MAPND, NAMLEN)
575 CALL MDSTAT (NERR, MEM)
576 IF (NERR .GT. 0) GOTO 160
577 IF (VERB .EQ. ' ') GOTO 120
578 END IF
579
580 C --Perform XY command
581
582 IIFLD = IFLD
583 CALL XYCOMD (A, CURPRO, INLINE,
584 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
585 & MESHOK)
586 CALL MDSTAT (NERR, MEM)
587 IF (NERR .GT. 0) GOTO 160
588 IF (VERB .EQ. ' ') GOTO 120
589
590 C --Perform MESH command
591
592 IF (MESHOK) THEN
593 IIFLD = IFLD
594 CALL MSCOMD (A, CURPRO, MSHTYP, INLINE,
595 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
596 & NAMECO, NAMES, IDELB, NEWELB, IELBST, NEWMOD,
597 & IDNPS, ISSNPS, IDESS, ISSESS, BLKCOL, SHDCOL, ISHDCL)
598 CALL MDSTAT (NERR, MEM)
599 IF (NERR .GT. 0) GOTO 160
600 IF (VERB .EQ. ' ') GOTO 120
601 END IF
602 END IF
603
604 C --Make second pass through PLCOMD on reset to set options that may be
605 C --controlled by xxCOMD after PLCOMD is called the first time
606
607 IF (MSHTYP .OR. XYTYPE) THEN
608 IF ((VERB .EQ. 'initprog') .OR. (VERB .EQ. 'initres')
609 & .OR. (VERB .EQ. 'reset')) THEN
610 VERB = 'postinit'
611 IIFLD = 0
612 CALL PLCOMD (A, CURPRO, XYTYPE, MESHOK, INLINE,
613 & VERB, IIFLD, INTYP, CFIELD, IFIELD, RFIELD,
614 & TIMES, WHOTIM, IPTIMS)
615 CALL MDSTAT (NERR, MEM)
616 IF (NERR .GT. 0) GOTO 160
617 IF (VERB .EQ. ' ') GOTO 120
618 END IF
619 END IF
620
621 C --Check command verb
622
623 IF (VERB .EQ. 'show') THEN
624 CALL PRTERR ('CMDERR', 'Invalid SHOW option')
625 VERB = ' '
626
627 ELSE IF ((VERB .EQ. 'plot') .OR. (VERB .EQ. 'hardcopy') .OR.
628 * (VERB .EQ. 'neutral') .OR. (VERB .EQ. 'grafaid') .OR.
629 * (VERB .EQ. 'csv') .OR. (VERB .EQ. 'xmgr') .OR.
630 * (VERB .EQ. 'raw') .OR. (VERB .EQ. 'mesh')) THEN
631
632 C --Set neutral file flag
633 IF (VERB .EQ. 'neutral') neutrl = XMGR
634 IF (VERB .EQ. 'xmgr') neutrl = XMGR
635 IF (VERB .EQ. 'grafaid') neutrl = GRAF
636 IF (VERB .EQ. 'csv') neutrl = CSV
637 IF (VERB .EQ. 'raw') neutrl = RAW
638
639 C --Switch to hardcopy device
640 IF (VERB .EQ. 'hardcopy') THEN
641 CALL GRGPARD ('DEVICE', 2, ISON, WORD)
642 IF (.NOT. ISON) VERB = 'plot'
643 END IF
644 IF (VERB .EQ. 'hardcopy')
645 & CALL GRSPAR ('DEVICE', 2, IDUM, WORD)
646
647 C --If mesh display, save current program to be restored
648 IF (VERB .EQ. 'mesh') THEN
649 SAVPRO = CURPRO
650 CURPRO = 'MESH'
651 END IF
652
653 NEWPRO = 'P'
654 VERB = ' '
655
656 ELSE IF ((VERB(1:1) .GE. 'a') .AND. (VERB(1:1) .LE. 'z')) THEN
657 VERB = ' '
658 END IF
659
660 IF (VERB .EQ. ' ') GOTO 120
661 CALL PRTERR ('CMDERR',
662 & '"' // VERB(:LENSTR(VERB)) // '" is an invalid command')
663 VERB = ' '
664 GOTO 150
665
666 120 CONTINUE
667 IF ((NLOG .GT. 0) .AND. (INLINE(1) .NE. ' ')) THEN
668 DO 130 I = 1, 5
669 IF (INLINE(I) .EQ. CHAR(0)) GOTO 140
670 WRITE (NLOG, '(A)') INLINE(I)(:LENSTR(INLINE(I)))
671 130 CONTINUE
672 140 CONTINUE
673 END IF
674
675 150 CONTINUE
676 IF (NEWPRO .EQ. ' ') GOTO 100
677
678 C --Release memory needed in this routine
679
680 IF (MEMPRO .EQ. 'PATHLINE') THEN
681 CALL MDDEL ('LNSCR')
682 ELSE IF (MEMPRO .EQ. 'TPLOT') THEN
683 CALL MDDEL ('TPSCR')
684 END IF
685
686 IF (NEWPRO .EQ. 'E') GOTO 170
687
688 C --Return to plot or change programs
689
690 160 CONTINUE
691 RETURN
692
693 C --Exit program
694
695 170 CONTINUE
696
697 C --Close the log file (delete if not saved)
698
699 IF (NLOG .GT. 0) THEN
700 IF (SAVLOG) THEN
701 CLOSE (NLOG, IOSTAT=IDUM)
702 ELSE
703 CLOSE (NLOG, STATUS='DELETE', IOSTAT=IDUM)
704 END IF
705 END IF
706
707 RETURN 1
708 10000 FORMAT (1X, 5A)
709 END