Debian Codegraph @

packages/seacas/applications/blot/hidmid.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE HIDMID (NLNKF, LINKF1, XN, YN, ZN, LINSET,
9 & IPSET, TVHMAX, ICROSS, XP, YP, ZP, NPART)
10 C=======================================================================
11
12 C --*** HIDMID *** (MESH) Hide nodes beneath a face
13 C -- Written by Amy Gilkey - revised 02/24/88
14 C --
15 C --HIDMID marks a node as hidden if it is beneath a face.
16 C --
17 C --Parameters:
18 C -- NLNKF - IN - the number of nodes per face
19 C -- LINKF1 - IN - the connectivity for the face
20 C -- XN, YN, ZN - IN - the nodal coordinates
21 C -- LINSET - IN - the sorted line set
22 C -- IPSET - IN/OUT - the indices of the partial line set
23 C -- NPART - IN/OUT - the number of lines in the partial line set
24 C --
25 C --Common Variables:
26
27 include 'debug.blk'
28 include 'dbnums.blk'
29 include 'd3nums.blk'
30
31 INTEGER LINKF1(NLNKF)
32 REAL XN(*), YN(*), ZN(*)
33 INTEGER LINSET(LLNSET,*)
34 INTEGER IPSET(*)
35 REAL TVHMAX(*)
36 INTEGER ICROSS(*)
37 REAL XP(*), YP(*), ZP(*)
38
39 REAL X(4), Y(4), Z(4)
40 REAL XNORM(4), YNORM(4), ZNORM(4)
41 LOGICAL FIRSIN, FIRSTZ, FIRST(4)
42
43 C --Calculate enclosing X-Y-Z box for face
44
45 DO 100 ILINK = 1, NLNKF
46 X(ILINK) = XN(LINKF1(ILINK))
47 Y(ILINK) = YN(LINKF1(ILINK))
48 Z(ILINK) = ZN(LINKF1(ILINK))
49 100 CONTINUE
50
51 XMIN = MIN (X(1), X(2), X(3), X(4))
52 XMAX = MAX (X(1), X(2), X(3), X(4))
53 YMIN = MIN (Y(1), Y(2), Y(3), Y(4))
54 YMAX = MAX (Y(1), Y(2), Y(3), Y(4))
55 ZMIN = MIN (Z(1), Z(2), Z(3), Z(4))
56 ZMAX = MAX (Z(1), Z(2), Z(3), Z(4))
57
58 FIRSIN = .TRUE.
59 FIRSTZ = .TRUE.
60
61 C --Check for nodes behind the face, mark as hidden
62
63 IP = 1
64 110 CONTINUE
65 IF (IP .LE. NPART) THEN
66
67 C --Check if outside of box enclosing face
68
69 IF (XMAX .LT. XP(IP)) GOTO 120
70 IF (XMIN .GT. XP(IP)) GOTO 120
71 IF (YMAX .LT. YP(IP)) GOTO 120
72 IF (YMIN .GT. YP(IP)) GOTO 120
73 IF (ZMAX .LT. ZP(IP)) GOTO 120
74
75 IV = LINSET(1,IPSET(IP))
76 IH = LINSET(2,IPSET(IP))
77 IF (((IV .EQ. LINKF1(1)) .OR. (IV .EQ. LINKF1(2)) .OR.
78 & (IV .EQ. LINKF1(3)) .OR. (IV .EQ. LINKF1(4))) .AND.
79 & ((IH .EQ. LINKF1(1)) .OR. (IH .EQ. LINKF1(2)) .OR.
80 & (IH .EQ. LINKF1(3)) .OR. (IH .EQ. LINKF1(4)))) GOTO 120
81
82 IF (FIRSIN) THEN
83 FIRSIN = .FALSE.
84
85 C --Pre-compute factors for "within" test
86
87 X2X1 = X(2) - X(1)
88 Y2Y1 = Y(2) - Y(1)
89 XY21 = X(1)*Y(2) - X(2)*Y(1)
90 X3X2 = X(3) - X(2)
91 Y3Y2 = Y(3) - Y(2)
92 XY32 = X(2)*Y(3) - X(3)*Y(2)
93 X4X3 = X(4) - X(3)
94 Y4Y3 = Y(4) - Y(3)
95 XY43 = X(3)*Y(4) - X(4)*Y(3)
96 X1X4 = X(1) - X(4)
97 Y1Y4 = Y(1) - Y(4)
98 XY14 = X(4)*Y(1) - X(1)*Y(4)
99 END IF
100
101 C --Check if all 4 triangles formed by 2 nodes of the face
102 C --and the node have a positive area
103
104 X0 = XP(IP)
105 Y0 = YP(IP)
106
107 A12 = X2X1*Y0 - X0*Y2Y1 + XY21
108 IF (A12 .LT. 0.0) GOTO 120
109 A23 = X3X2*Y0 - X0*Y3Y2 + XY32
110 IF (A23 .LT. 0.0) GOTO 120
111 A34 = X4X3*Y0 - X0*Y4Y3 + XY43
112 IF (A34 .LT. 0.0) GOTO 120
113 A41 = X1X4*Y0 - X0*Y1Y4 + XY14
114 IF (A41 .LT. 0.0) GOTO 120
115
116 C --Check if the node's Z is behind the face's Z at that point
117
118 IF (FIRSTZ) THEN
119 FIRSTZ = .FALSE.
120 FIRST(1) = .TRUE.
121 FIRST(2) = .TRUE.
122 FIRST(3) = .TRUE.
123 FIRST(4) = .TRUE.
124
125 C --Calculate epsilon based on length of "standard" side
126
127 A = A12 + A23 + A34 + A41
128 EPS = A * SQRT (A) * .001
129
130 C --Calculate center of face
131
132 XCEN = 0.25 * (X(1) + X(2) + X(3) + X(4))
133 YCEN = 0.25 * (Y(1) + Y(2) + Y(3) + Y(4))
134 ZCEN = 0.25 * (Z(1) + Z(2) + Z(3) + Z(4))
135 END IF
136
137 C --Check if the node's Z is behind the face's minimum Z
138
139 IF ((ZMIN - ZP(IP)) .LT. EPS) THEN
140
141 C --Calculate normal for center of face with two nodes
142 C --that have the smallest area with the given node
143
144 AMIN = MIN (A12, A23, A34, A41)
145
146 IF (AMIN .EQ. A12) THEN
147 ISIDE = 1
148 ELSE IF (AMIN .EQ. A23) THEN
149 ISIDE = 2
150 ELSE IF (AMIN .EQ. A34) THEN
151 ISIDE = 3
152 ELSE IF (AMIN .EQ. A41) THEN
153 ISIDE = 4
154 END IF
155 IF (FIRST(ISIDE)) THEN
156 FIRST(ISIDE) = .FALSE.
157 IF (ISIDE .LT. 4) THEN
158 N2 = ISIDE + 1
159 ELSE
160 N2 = 1
161 END IF
162 AX = X(ISIDE) - XCEN
163 AY = Y(ISIDE) - YCEN
164 AZ = Z(ISIDE) - ZCEN
165 BX = X(N2) - XCEN
166 BY = Y(N2) - YCEN
167 BZ = Z(N2) - ZCEN
168 XNORM(ISIDE) = 0.5 * (AY*BZ - BY*AZ)
169 YNORM(ISIDE) = 0.5 * (AZ*BX - BZ*AX)
170 ZNORM(ISIDE) = 0.5 * (AX*BY - BX*AY)
171 END IF
172
173 C --Check if the node's Z is behind the face's Z at that point
174 IF ((XNORM(ISIDE)*(X0-XCEN) + YNORM(ISIDE)*(Y0-YCEN)
175 & + ZNORM(ISIDE)*(ZP(IP)-ZCEN)) .GE. -EPS) GOTO 120
176 END IF
177
178 C --Hide the entire line (as is), and move the line to hidden section
179 I = IPSET(IP)
180 IPSET(IP) = IPSET(NPART)
181 IPSET(NPART) = I
182 T = TVHMAX(IP)
183 TVHMAX(IP) = TVHMAX(NPART)
184 TVHMAX(NPART) = T
185 I = ICROSS(IP)
186 ICROSS(IP) = ICROSS(NPART)
187 ICROSS(NPART) = I
188 XP(IP) = XP(NPART)
189 YP(IP) = YP(NPART)
190 ZP(IP) = ZP(NPART)
191 NPART = NPART - 1
192 IP = IP - 1
193
194 120 CONTINUE
195 IP = IP + 1
196 GOTO 110
197 END IF
198
199 RETURN
200 END