Debian Codegraph @

packages/seacas/applications/blot/ckcros.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 LOGICAL FUNCTION CKCROS (IMID, IH, NLNKF, LINKF1, XN, YN, ZN)
9 C=======================================================================
10
11 C --*** CKCROS *** (MESH) Hide partial lines by face
12 C -- Written by Amy Gilkey - revised 10/02/86
13 C --
14 C --CKCROS deletes partial lines that have a visible node along the edge
15 C --of a quarilateral and the hidden node is within the area defined
16 C --by the vectors from the corner to the two adjacent nodes. Such
17 C --a face totally hides the partial line.
18 C --
19 C --Parameters:
20 C -- IMID - IN - the node in the face that is closest to the
21 C -- visible node
22 C -- IH - IN - the hidden nodes
23 C -- NLNKF - IN - the number of nodes per face
24 C -- LINKF1 - IN - the connectivity for the face containing the edge
25 C -- XN,YN,ZN - IN - the nodal coordinates
26
27 include 'debug.blk'
28 C common /debugc/ cdebug
29 C common /debugn/ idebug
30 C character*8 cdebug
31
32 INTEGER LINKF1(NLNKF)
33 REAL XN(*), YN(*), ZN(*)
34
35 CKCROS = .FALSE.
36
37 C --Find left and right node for face
38
39 DO 100 ILINK = 1, 4
40 IF (LINKF1(ILINK) .EQ. IMID) IXMID = ILINK
41 100 CONTINUE
42 IF (IXMID .LT. 4) THEN
43 ILFT = LINKF1(IXMID+1)
44 ELSE
45 ILFT = LINKF1(1)
46 END IF
47 IF (IXMID .GT. 1) THEN
48 IRGT = LINKF1(IXMID-1)
49 ELSE
50 IRGT = LINKF1(4)
51 END IF
52 IF ((ILFT .EQ. IH) .OR. (IRGT .EQ. IH)) GOTO 110
53 XMID = XN(IMID)
54 YMID = YN(IMID)
55 XLFT = XN(ILFT)
56 YLFT = YN(ILFT)
57 XRGT = XN(IRGT)
58 YRGT = YN(IRGT)
59 IF ((XLFT-XMID)*YRGT + (XRGT-XLFT)*YMID
60 & + (XMID-XRGT)*YLFT .LT. 0.0) THEN
61 I = IRGT
62 IRGT = ILFT
63 ILFT = I
64 XLFT = XN(ILFT)
65 YLFT = YN(ILFT)
66 XRGT = XN(IRGT)
67 YRGT = YN(IRGT)
68 END IF
69
70 C --Check 2 triangles formed by 2 adjacent nodes of the face
71 C --and the node have a positive area
72
73 X0 = XN(IH)
74 Y0 = YN(IH)
75 ALFT = (XLFT-XMID)*Y0 + (X0-XLFT)*YMID + (XMID-X0)*YLFT
76 IF (ALFT .LT. 0.0) GOTO 110
77 ARGT = (XMID-XRGT)*Y0 + (X0-XMID)*YRGT + (XRGT-X0)*YMID
78 IF (ARGT .LT. 0.0) GOTO 110
79
80 C --Check if the node's Z is behind the face's Z at that point
81
82 ZMIN = MIN
83 & (ZN(LINKF1(1)), ZN(LINKF1(2)), ZN(LINKF1(3)), ZN(LINKF1(4)))
84
85 IF (ZMIN .LE. ZN(IH)) THEN
86
87 C --Calculate normal at visible node with diagonal node and
88 C --left or right node
89
90 IF (IXMID .GT. 2) THEN
91 IDIA = LINKF1(IXMID-2)
92 ELSE
93 IDIA = LINKF1(IXMID+2)
94 END IF
95
96 ZMID = ZN(IMID)
97
98 AMIN = MIN (ALFT, ARGT)
99
100 IF (AMIN .EQ. ALFT) THEN
101 ISIDA = ILFT
102 ISIDB = IDIA
103 ELSE IF (AMIN .EQ. ARGT) THEN
104 ISIDA = IDIA
105 ISIDB = IRGT
106 END IF
107 AX = XN(ISIDA) - XMID
108 AY = YN(ISIDA) - YMID
109 AZ = ZN(ISIDA) - ZMID
110 BX = XN(ISIDB) - XMID
111 BY = YN(ISIDB) - YMID
112 BZ = ZN(ISIDB) - ZMID
113 XNORM = 0.5 * (AY*BZ - BY*AZ)
114 YNORM = 0.5 * (AZ*BX - BZ*AX)
115 ZNORM = 0.5 * (AX*BY - BX*AY)
116
117 IF ((XNORM*(X0-XMID) + YNORM*(Y0-YMID)
118 & + ZNORM*(ZN(IH)-ZMID)) .GE. 0.0) GOTO 110
119 END IF
120
121 C --Mark totally hidden lines
122
123 CKCROS = .TRUE.
124
125 110 CONTINUE
126 RETURN
127 END