Debian Codegraph @

packages/seacas/applications/blot/nzaway.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 INTEGER FUNCTION NZAWAY (NLNKF, LINKF1, XN, YN, ZN, HIDENP)
9 C=======================================================================
10
11 C --*** NZAWAY *** (MESH) Determine if warped face is hidden
12 C -- Written by Amy Gilkey - revised 05/02/88
13 C --
14 C --NZAWAY determines how many nodes of a possible warped face
15 C --on a 3D surface are hidden. A node is hidden if and only if the
16 C --outward normal formed by the node and the two adjacent nodes points
17 C --"into" the plotting surface. The nodes are marked as visible if
18 C --they point away from the plotting surface.
19 C --
20 C --Parameters:
21 C -- NLNKF - IN - the number of nodes per face
22 C -- LINKF1 - IN - the connectivity for the face
23 C -- XN, YN, ZN - IN - the nodal coordinates; the Z-coordinate is
24 C -- pointing towards the viewer (out of the plotting plane)
25 C -- HIDENP - IN/OUT - node status (as in HIDDEN)
26
27 PARAMETER (KNVIS=0, KNFOVR=10, KNHID=100)
28
29 common /debugc/ cdebug
30 common /debugn/ idebug
31 character*8 cdebug
32
33 INTEGER LINKF1(NLNKF)
34 REAL XN(*), YN(*), ZN(*)
35 INTEGER HIDENP(*)
36
37 NZAWAY = 0
38 IMID = LINKF1(3)
39 IRGT = LINKF1(4)
40 AX = XN(IRGT) - XN(IMID)
41 AY = YN(IRGT) - YN(IMID)
42 IF ((AX .NE. 0.0) .OR. (AY .NE. 0.0)) THEN
43 ISAME = 0
44 ELSE
45 IMID = LINKF1(2)
46 IRGT = LINKF1(3)
47 BX = XN(IRGT) - XN(IMID)
48 BY = YN(IRGT) - YN(IMID)
49 IMID = LINKF1(3)
50 IRGT = LINKF1(4)
51 ISAME = IMID
52 END IF
53
54 DO 100 ILINK = 1, 4
55 IMID = IRGT
56 IRGT = LINKF1(ILINK)
57
58 C --Form X and Y components of corner of face
59
60 IF (ISAME .EQ. 0) THEN
61 BX = -AX
62 BY = -AY
63 END IF
64 AX = XN(IRGT) - XN(IMID)
65 AY = YN(IRGT) - YN(IMID)
66
67 C --Form Z component of normal vector to corner, and make node
68 C --visible if normal points forward
69
70 IF ((AX .NE. 0.0) .OR. (AY .NE. 0.0)) THEN
71 IF (AX*BY .LE. BX*AY) THEN
72 NZAWAY = NZAWAY + 1
73 IF (ISAME .NE. 0) NZAWAY = NZAWAY + 1
74 ELSE
75 IXRGT = ILINK
76 HIDENP(IMID) = KNVIS
77 IF (ISAME .NE. 0) HIDENP(ISAME) = KNVIS
78 END IF
79 ISAME = 0
80 ELSE
81 ISAME = IMID
82 END IF
83 100 CONTINUE
84
85 IF (NZAWAY .EQ. 1) THEN
86
87 C --If single node visible, make two adjoining nodes visible
88
89 IF (IXRGT .GT. 2) THEN
90 IXLFT = IXRGT - 2
91 ELSE
92 IXLFT = IXRGT + 2
93 END IF
94 HIDENP(LINKF1(IXLFT)) = KNVIS
95 HIDENP(LINKF1(IXRGT)) = KNVIS
96 END IF
97
98 if ((nzaway .ne. 4) .and. (nzaway .ne. 0)) then
99 if ((cdebug .eq. 'HIDDEN') .and. (idebug .ge. 2))
100 & write (*, '(1x,a,i5,2x,4i5)') 'warped', nzaway, linkf1
101 end if
102
103 RETURN
104 END