Debian Codegraph @

packages/seacas/applications/blot/cmdtim.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE CMDTIM (INLINE,
9 & VERB, IFLD, INTYP, CFIELD, IFIELD, RFIELD,
10 & NSTEPS, TIMES, WHOTIM, WHONLY, TMIN, TMAX, DELT, NINTV,
11 & NPTIMS, IPTIMS)
12 C=======================================================================
13
14 C --*** CMDTIM *** (TIMSEL) Process time step parameter command
15 C -- Written by Amy Gilkey - revised 05/18/88
16 C --
17 C --CMDTIM processes a time step parameter command. The commands are:
18 C -- TMIN - sets the minimum selected time TMIN
19 C -- TMAX - sets the maximum selected time TMAX
20 C -- DELTIME - sets the selected time interval DELT
21 C -- ZINTV - sets the number of selected times NINTV
22 C -- with interval starting at TMIN
23 C -- NINTV - sets the number of selected times NINTV
24 C -- with interval starting at TMIN + offset
25 C -- ALLTIMES - sets DELT = 0 for all times
26 C -- TIMES - selects time steps by time
27 C -- STEPS - selects time steps by number
28 C --
29 C --Parameters:
30 C -- INLINE - IN/OUT - the parsed input lines for the log file
31 C -- VERB - IN/OUT - the time step parameter command verb; set for SHOW
32 C -- IFLD - IN/OUT - the field number
33 C -- INTYP - IN - the input types from the free field reader
34 C -- CFIELD - IN - the character fields
35 C -- IFIELD - IN - the integer fields
36 C -- RFIELD - IN - the real fields
37 C -- NSTEPS - IN - the number of time steps
38 C -- TIMES - IN - the database times
39 C -- WHOTIM - IN - true iff TIMES(i) is whole (versus history) time step
40 C -- WHONLY - IN - true iff only whole times may be selected
41 C -- TMIN - IN/OUT - the minimum selected time
42 C -- TMAX - IN/OUT - the maximum selected time
43 C -- DELT - IN/OUT - the interval between selected times
44 C -- (<0 = selected times)
45 C -- NINTV - IN/OUT - the number of times between tmin and tmax to select
46 C -- (negative for zero interval)
47 C -- NPTIMS - IN/OUT - the number of selected times
48 C -- IPTIMS - IN/OUT - the selected time step numbers
49
50 C --Routines Called:
51 C -- LOCREA - (ETCLIB) Find closest value
52 C -- MINMAX - (ETCLIB) Find minimum and maximum value
53 C -- MINMXL - (ETCLIB) Find minimum and maximum value of selected values
54 C -- NUMEQL - (ETCLIB) Count the number of equal values
55
56 CHARACTER*(*) INLINE(*)
57 CHARACTER*(*) VERB
58 INTEGER INTYP(*)
59 CHARACTER*(*) CFIELD(*)
60 INTEGER IFIELD(*)
61 REAL RFIELD(*)
62 REAL TIMES(*)
63 LOGICAL WHOTIM(*)
64 LOGICAL WHONLY
65 INTEGER IPTIMS(*)
66
67 LOGICAL FFEXST, FFMATC
68 LOGICAL ISTIME
69 CHARACTER*5 STR5
70
71 IF (.NOT. WHONLY) THEN
72 NSTEPX = NSTEPS
73 ELSE
74 NSTEPX = NUMEQL (.TRUE., NSTEPS, WHOTIM)
75 END IF
76
77 IF ((VERB .EQ. 'TMIN') .OR. (VERB .EQ. 'TMAX')) THEN
78 CALL FFADDC (VERB, INLINE(1))
79 IF (.NOT. WHONLY) THEN
80 CALL MINMAX (NSTEPS, TIMES, TIMMIN, TIMMAX)
81 ELSE
82 CALL MINMXL (NSTEPS, WHOTIM, TIMES, TIMMIN, TIMMAX)
83 END IF
84 IF (VERB .EQ. 'TMIN') THEN
85 CALL FFREAL (IFLD, INTYP, RFIELD,
86 & 'minimum time', TIMMIN, X, *120)
87 TMIN = X
88 CALL FFADDR (TMIN, INLINE(1))
89 ELSE
90 CALL FFREAL (IFLD, INTYP, RFIELD,
91 & 'maximum time', TIMMAX, X, *120)
92 TMAX = X
93 CALL FFADDR (TMAX, INLINE(1))
94 END IF
95 IF (TMIN .GT. TMAX) CALL PRTERR ('CMDWARN',
96 & 'Minimum time is greater than maximum time')
97 IF (DELT .LT. 0) THEN
98 NINTV = 0
99 DELT = 0.0
100 END IF
101
102 ELSE IF ((VERB .EQ. 'NINTV') .OR. (VERB .EQ. 'ZINTV')) THEN
103 CALL FFADDC (VERB, INLINE(1))
104 IF (VERB .EQ. 'NINTV') THEN
105 NT = MIN (10, NSTEPX-1)
106 ELSE
107 NT = MIN (10, NSTEPX)
108 END IF
109 CALL FFINTG (IFLD, INTYP, IFIELD,
110 & 'number of times', NT, N, *120)
111 NINTV = N
112 CALL FFADDI (NINTV, INLINE(1))
113 IF (VERB .EQ. 'NINTV') THEN
114 NINTV = N
115 ELSE
116 NINTV = -N
117 END IF
118 DELT = 999.0
119
120 ELSE IF (VERB .EQ. 'DELTIME') THEN
121 CALL FFADDC (VERB, INLINE(1))
122 NT = - MIN (10, NSTEPX)
123 IF (NT .LT. -1) THEN
124 DDELT = (TMAX - TMIN) / (-NT-1)
125 IF (DDELT .LE. 0.) DDELT = 1.0
126 ELSE
127 DDELT = 0.0
128 END IF
129 CALL FFREAL (IFLD, INTYP, RFIELD,
130 & 'delta time', DDELT, X, *120)
131 DELT = X
132 CALL FFADDR (DELT, INLINE(1))
133 NINTV = 0
134
135 ELSE IF (VERB .EQ. 'ALLTIMES') THEN
136 CALL FFADDC (VERB, INLINE(1))
137 DELT = 0.0
138 NINTV = 0
139
140 ELSE IF ((VERB .EQ. 'TIMES') .OR. (VERB .EQ. 'STEPS')) THEN
141 CALL FFADDC (VERB, INLINE(1))
142 ISTIME = (VERB .EQ. 'TIMES')
143 VERB = 'DELTIME'
144 IF (DELT .GE. 0.0) THEN
145 NINTV = NPTIMS
146 DELT = -1.0
147 END IF
148
149 C --Reset is assumed, unless ADD is first parameter
150 IF (.NOT. FFMATC (IFLD, INTYP, CFIELD, 'ADD', 1)) NINTV = 0
151
152 100 CONTINUE
153 IF (FFEXST (IFLD, INTYP)) THEN
154 IF (ISTIME) THEN
155 CALL FFREAL (IFLD, INTYP, RFIELD,
156 & 'time, ignored', 0.0, T, *110)
157 CALL FFADDR (T, INLINE(1))
158 IF (.NOT. WHONLY) THEN
159 ISTEP = LOCREA (T, NSTEPS, TIMES)
160 ELSE
161 ISTEP = LOCRL (T, NSTEPS, WHOTIM, TIMES)
162 END IF
163
164 ELSE
165 CALL FFINTG (IFLD, INTYP, IFIELD,
166 & 'step, ignored', 0, ISTEP, *110)
167 IF ((ISTEP .LE. 0) .OR. (ISTEP .GT. NSTEPS)) THEN
168 CALL INTSTR (1, 0, ISTEP, STR5, LSTR)
169 CALL PRTERR ('CMDERR', 'Step ' // STR5(:LSTR)
170 & // ' does not exist, ignored')
171 GOTO 110
172 ELSE IF (WHONLY) THEN
173 IF (.NOT. WHOTIM(ISTEP)) THEN
174 CALL INTSTR (1, 0, ISTEP, STR5, LSTR)
175 CALL PRTERR ('CMDERR', 'Step ' // STR5(:LSTR)
176 & // ' is a history time step, ignored')
177 GOTO 110
178 END IF
179 END IF
180 CALL FFADDI (ISTEP, INLINE(1))
181 END IF
182
183 IF (LOCINT (ISTEP, NINTV, IPTIMS) .LE. 0) THEN
184 NINTV = NINTV + 1
185 IPTIMS(NINTV) = ISTEP
186 END IF
187 110 CONTINUE
188 GOTO 100
189 END IF
190 END IF
191
192 NPTIMS = -999
193 CALL CALTIM (WHONLY, TMIN, TMAX, DELT, NINTV,
194 & NSTEPS, TIMES, WHOTIM, NPTIMS, IPTIMS)
195
196 120 CONTINUE
197 RETURN
198 END