Debian Codegraph @

packages/seacas/applications/blot/hidnod.f

raw
1 C Copyright(C) 1999-2020 National Technology & Engineering Solutions
2 C of Sandia, LLC (NTESS). Under the terms of Contract DE-NA0003525 with
3 C NTESS, the U.S. Government retains certain rights in this software.
4 C
5 C See packages/seacas/LICENSE for details
6
7 C=======================================================================
8 SUBROUTINE HIDNOD (NLNKF, LINKF1, XN, YN, ZN,
9 & COLMIN, ROWMIN, CRDELT, CREPS, NUMCOL, NUMROW,
10 & IXNCRS, IXNCRE, NPCR,
11 & HIDENP, nhid)
12 C=======================================================================
13
14 C --*** HIDNOD *** (MESH) Hide nodes beneath a face
15 C -- Written by Amy Gilkey - revised 10/22/87
16 C --
17 C --HIDNOD marks a node as hidden if it is beneath a face.
18 C --
19 C --Parameters:
20 C -- NLNKF - IN - the number of nodes per face
21 C -- LINKF1 - IN - the connectivity for the face
22 C -- XN, YN, ZN - IN - the nodal coordinates
23 C -- COLMIN, ROWMIN - IN - the minimum row and column value and 1 / interval
24 C -- CRDELT - the row and column interval reciprical (1 / interval)
25 C -- NUMCOL, NUMROW - IN - the number of rows and columns
26 C -- IXNCRS, IXNCRE - OUT - the starting and ending NPCR index
27 C -- for each column and row
28 C -- NPCR - OUT - the nodes indexed by IXNCRS, IXNCRE
29 C -- HIDENP - IN/OUT - node status (as in HIDDEN)
30 C --
31 C --Common Variables:
32
33 PARAMETER (KNVIS=0, KNFOVR=10, KNHID=100)
34
35 common /debugc/ cdebug
36 common /debugn/ idebug
37 character*8 cdebug
38
39 include 'dbnums.blk'
40 include 'd3nums.blk'
41
42 INTEGER LINKF1(NLNKF)
43 REAL XN(*), YN(*), ZN(*)
44 INTEGER IXNCRS(0:NUMCOL,0:NUMROW), IXNCRE(0:NUMCOL,0:NUMROW)
45 INTEGER NPCR(*)
46 INTEGER HIDENP(*)
47
48 REAL X(4), Y(4), Z(4)
49 REAL XNORM(4), YNORM(4), ZNORM(4)
50 LOGICAL FIRSTZ, FIRST(4)
51
52 C --Skip face if all nodes hidden
53
54 IF ((HIDENP(LINKF1(1)) .GT. KNVIS) .AND.
55 & (HIDENP(LINKF1(2)) .GT. KNVIS) .AND.
56 & (HIDENP(LINKF1(3)) .GT. KNVIS) .AND.
57 & (HIDENP(LINKF1(4)) .GT. KNVIS)) RETURN
58
59 C --Calculate enclosing X-Y-Z box for face
60
61 DO 100 ILINK = 1, 4
62 X(ILINK) = XN(LINKF1(ILINK))
63 Y(ILINK) = YN(LINKF1(ILINK))
64 Z(ILINK) = ZN(LINKF1(ILINK))
65 100 CONTINUE
66
67 XMIN = MIN (X(1), X(2), X(3), X(4))
68 XMAX = MAX (X(1), X(2), X(3), X(4))
69 YMIN = MIN (Y(1), Y(2), Y(3), Y(4))
70 YMAX = MAX (Y(1), Y(2), Y(3), Y(4))
71 ZMIN = MIN (Z(1), Z(2), Z(3), Z(4))
72 ZMAX = MAX (Z(1), Z(2), Z(3), Z(4))
73
74 C --Find the minimum and maximum row and column for this face
75
76 MINCOL = INT ((XMIN - CREPS - COLMIN) * CRDELT)
77 MAXCOL = INT ((XMAX + CREPS - COLMIN) * CRDELT)
78 MINROW = INT ((YMIN - CREPS - ROWMIN) * CRDELT)
79 MAXROW = INT ((YMAX + CREPS - ROWMIN) * CRDELT)
80
81 C --Pre-compute factors for "within" test
82
83 X2X1 = X(2) - X(1)
84 Y2Y1 = Y(2) - Y(1)
85 XY21 = X(1)*Y(2) - X(2)*Y(1)
86 X3X2 = X(3) - X(2)
87 Y3Y2 = Y(3) - Y(2)
88 XY32 = X(2)*Y(3) - X(3)*Y(2)
89 X4X3 = X(4) - X(3)
90 Y4Y3 = Y(4) - Y(3)
91 XY43 = X(3)*Y(4) - X(4)*Y(3)
92 X1X4 = X(1) - X(4)
93 Y1Y4 = Y(1) - Y(4)
94 XY14 = X(4)*Y(1) - X(1)*Y(4)
95
96 FIRSTZ = .TRUE.
97
98 C --Check for nodes behind the face, mark as hidden
99
100 DO 140 ICOL = MINCOL, MAXCOL
101 DO 130 IROW = MINROW, MAXROW
102 IXN = IXNCRS(ICOL,IROW)
103 110 CONTINUE
104 IF (IXN .LE. IXNCRE(ICOL,IROW)) THEN
105 INP = NPCR(IXN)
106
107 C --Check if outside of box enclosing face
108
109 IF (XMAX .LT. XN(INP)) GOTO 120
110 IF (XMIN .GT. XN(INP)) GOTO 120
111 IF (YMAX .LT. YN(INP)) GOTO 120
112 IF (YMIN .GT. YN(INP)) GOTO 120
113 IF (ZMAX .LT. ZN(INP)) GOTO 120
114
115 C --Check if node is part of the face
116
117 IF ((INP .EQ. LINKF1(1)) .OR. (INP .EQ. LINKF1(2)) .OR.
118 & (INP .EQ. LINKF1(3)) .OR. (INP .EQ. LINKF1(4)))
119 & GOTO 120
120
121 C --Check if all 4 triangles formed by 2 nodes of the face
122 C --and the node have a positive area
123
124 X0 = XN(INP)
125 Y0 = YN(INP)
126 A12 = X2X1*Y0 - X0*Y2Y1 + XY21
127 IF (A12 .LT. 0.0) GOTO 120
128 A23 = X3X2*Y0 - X0*Y3Y2 + XY32
129 IF (A23 .LT. 0.0) GOTO 120
130 A34 = X4X3*Y0 - X0*Y4Y3 + XY43
131 IF (A34 .LT. 0.0) GOTO 120
132 A41 = X1X4*Y0 - X0*Y1Y4 + XY14
133 IF (A41 .LT. 0.0) GOTO 120
134
135 IF (FIRSTZ) THEN
136 FIRSTZ = .FALSE.
137 FIRST(1) = .TRUE.
138 FIRST(2) = .TRUE.
139 FIRST(3) = .TRUE.
140 FIRST(4) = .TRUE.
141
142 C --Calculate epsilon based on length of "standard" side
143
144 A = A12 + A23 + A34 + A41
145 EPS = A * SQRT (A) * .001
146
147 C --Calculate center of face
148
149 XCEN = 0.25 * (X(1) + X(2) + X(3) + X(4))
150 YCEN = 0.25 * (Y(1) + Y(2) + Y(3) + Y(4))
151 ZCEN = 0.25 * (Z(1) + Z(2) + Z(3) + Z(4))
152 END IF
153
154 C --Check if the node's Z is behind the face's minimum Z
155
156 IF ((ZMIN - ZN(INP)) .LT. EPS) THEN
157
158 C --Calculate normal for center of face with two nodes
159 C --that have the smallest area with the given node
160
161 AMIN = MIN (A12, A23, A34, A41)
162
163 IF (AMIN .EQ. A12) THEN
164 ISIDE = 1
165 ELSE IF (AMIN .EQ. A23) THEN
166 ISIDE = 2
167 ELSE IF (AMIN .EQ. A34) THEN
168 ISIDE = 3
169 ELSE IF (AMIN .EQ. A41) THEN
170 ISIDE = 4
171 END IF
172 IF (FIRST(ISIDE)) THEN
173 FIRST(ISIDE) = .FALSE.
174 IF (ISIDE .LT. 4) THEN
175 N2 = ISIDE + 1
176 ELSE
177 N2 = 1
178 END IF
179 AX = X(ISIDE) - XCEN
180 AY = Y(ISIDE) - YCEN
181 AZ = Z(ISIDE) - ZCEN
182 BX = X(N2) - XCEN
183 BY = Y(N2) - YCEN
184 BZ = Z(N2) - ZCEN
185 XNORM(ISIDE) = 0.5 * (AY*BZ - BY*AZ)
186 YNORM(ISIDE) = 0.5 * (AZ*BX - BZ*AX)
187 ZNORM(ISIDE) = 0.5 * (AX*BY - BX*AY)
188 END IF
189
190 C --Check if the node's Z is behind the face's Z at that point
191
192 Z0C = XNORM(ISIDE)*(X0-XCEN) + YNORM(ISIDE)*(Y0-YCEN)
193 & + ZNORM(ISIDE)*(ZN(INP)-ZCEN)
194
195 IF (Z0C .GT. EPS) GOTO 120
196 IF (Z0C .GE. -EPS) THEN
197 C --Mark as slide line
198 HIDENP(INP) = -1
199 GOTO 120
200 END IF
201 END IF
202
203 C --Mark the node as hidden and delete from visible set
204 HIDENP(INP) = KNFOVR
205 I = IXNCRE(ICOL,IROW)
206 NPCR(IXN) = NPCR(I)
207 IXNCRE(ICOL,IROW) = I-1
208 IXN = IXN - 1
209 nhid = nhid + 1
210
211 120 CONTINUE
212 IXN = IXN + 1
213 GOTO 110
214 END IF
215 130 CONTINUE
216 140 CONTINUE
217
218 RETURN
219 END