Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/uncll.mf

raw
1 %%
2 %% This is file `uncll.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% uncial.dtx (with options: `min')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19 cmchar "Uncial letter a";
20 beginchar("a", 2u#+hstretch*(x_height#+jut#), x_height#, 0);
21 adjust_fit(0,0);
22 pcshiftx := u;
23 sqyside:=h; sqxside:=hstretch*sqyside;
24 y100 = h/2; x100 = pcshiftx+y100; % square center
25 pickup quill;
26 lft x1=pcshiftx+sqxside/3; rt x2=lft x1+2/3sqxside;
27 y1=h; y2=0;
28 z3=3/4[z2,z1];
29 z5=3/16[z2,z1];
30 y4=1/10[y5,y3];
31 lft x4=pcshiftx;
32 %%ductus:=true;
33 if ductus:
34 pickup stylus;
35 fi
36 draw_istem(1,2,srad); % the stem
37 draw z3{-pdir}..z4{down}..{pdir}z5;
38 ductus:=false;
39 proofpcbb(100, y100, y100);
40 penlabels(1,2,3,4,5,100);
41 endchar; % end "a"
42
43 cmchar "Uncial letter b";
44 beginchar("b", 2u#+hstretch*(x_height#+jut#), x_height#, 0);
45 adjust_fit(0,0);
46 pcshiftx := u+jut/2;
47 sqyside:=h; sqxside:=hstretch*sqyside;
48 y100 = h/2; x100 = pcshiftx+y100; % square center
49 pair uncial; uncial=(qhor,0.5qvert);
50 pickup quill;
51 lft x1=lft x2=pcshiftx;
52 top y1=h; y2=h/4;
53 x3=pcshiftx+sqxside/2; bot y3=0;
54 rt x4=pcshiftx+sqxside; y4=0.3h;
55 lft x5=x1; bot y5=h/2;
56 z5'=z5 + thick*uncial;
57 x6=x4-thick; y6=0.85h;
58 x7=x1; y7=0.9h;
59 %%ductus:=true;
60 if ductus:
61 pickup stylus;
62 fi
63 draw_tlserif(1,2,srad); % the stem
64 draw z2{down}..z3{right}..z4{up}..{-uncial}z5'--z5; % bottom bowl
65 draw z5--z5'{uncial}..z6{up}..{-pdir}z7; % top bowl
66 ductus:=false;
67 proofpcbb(100, y100, y100);
68 penlabels(1,2,3,4,5,5',6,7,8,100);
69 endchar; % end "b"
70
71 cmchar "Uncial letter c";
72 beginchar("c", u#+hstretch*(x_height#), x_height#, 0);
73 adjust_fit(0,0);
74 pcshiftx := u/2;
75 sqyside:=h; sqxside:=hstretch*sqyside;
76 y100 = h/2; x100 = pcshiftx+y100; % square center
77 pickup quill;
78 lft x1=pcshiftx; rt x3=pcshiftx+sqxside; y1=y3=h/2;
79 x2=x4=w/2; top y2=h; bot y4=0;
80 x5=x6=x3;
81 y5=0.2h;
82 y6=0.75h;
83 %%ductus:=true;
84 if ductus:
85 pickup stylus;
86 fi
87 draw z5{-pdir}..{left}z4..z1..z2..z6;
88 ductus:=false;
89 proofpcbb(100, y100, y100);
90 penlabels(1,2,3,4,5,6,100);
91 endchar; % end "c"
92
93 cmchar "Uncial letter d";
94 beginchar("d", 2u#+hstretch*(x_height#), 5/4x_height#, 0);
95 adjust_fit(0,0);
96 pcshiftx := u;
97 sqyside:=4/5h; sqxside:=hstretch*sqyside;
98 y100 = side/2; x100 = pcshiftx+y100; % square center
99 pickup quill;
100 lft x1=pcshiftx; rt x3=pcshiftx+sqxside; y1=y3=sqyside/2;
101 x2=x4=w/2; top y2=sqyside; bot y4=0;
102 x5=x6=x3;
103 y5=0.2h;
104 y6=0.75h;
105 rt x0=pcshiftx+0.5sqxside; top y0=sqyside;
106 lft x7=pcshiftx+0.5sqxside;
107 bot y7=sqyside;
108 lft x8=pcshiftx; y8=y7+thick;
109 %%ductus:=true;
110 if ductus:
111 pickup stylus;
112 fi
113 draw z0{-pdir}..z1{down}..z4{right}..z3{up}..z7..z8;
114 ductus:=false;
115 proofpcbb(100, y100, y100);
116 penlabels(0,1,2,3,4,5,6,7,8,100);
117 endchar; % end "d"
118
119 cmchar "Uncial letter e";
120 beginchar("e", 2u#+hstretch*(x_height#), x_height#, 0);
121 adjust_fit(0,0);
122 pcshiftx := u;
123 sqyside:=h; sqxside:=hstretch*sqyside;
124 y100 = h/2; x100 = pcshiftx+y100; % square center
125 pickup quill;
126 lft x1=pcshiftx; rt x3=pcshiftx+sqxside; y1=y3=h/2;
127 x2=x4=w/2; top y2=h; bot y4=0;
128 x5=x6=x3;
129 y5=0.2h;
130 y6=0.75h;
131 x7=x1; y7=y1;
132 %%x8=x7+side+0.5thick; y8=y7;
133 x8=w-pcshiftx; y8=y7;
134 x10=x7; y10=y7+3thin;
135 numeric alpha; alpha:=0.5; % dishing
136 x9=0.5[x8,x10]; y9=(0.5alpha)[y8,y10];
137 %%ductus:=true;
138 if ductus:
139 pickup stylus;
140 fi
141 draw z5{-pdir}..{left}z4..z1..z2..z6; % the bowl
142 pickup stylus;
143 filldraw z7--z8..z9..z10--cycle; % the bar
144 ductus:=false;
145 proofpcbb(100, y100, y100);
146 penlabels(1,2,3,4,5,6,7,8,9,10,100);
147 endchar; % end "e"
148
149 cmchar "Uncial letter f";
150 beginchar("f", 2u#+hstretch*(jut#+x_height#), x_height#, 2/3x_height#);
151 adjust_fit(0,0);
152 pcshiftx := u+jut;
153 sqyside:=h; sqxside:=hstretch*sqyside;
154 y100 = h/2; x100 = pcshiftx+y100; % square center
155 pickup quill;
156 lft x1=lft x2=pcshiftx;
157 top y1=h; bot y2=-d/2;
158 x3=x4=x1; y3=h-thick; y4=0;
159 numeric rise, fall, fjut;
160 rise:=thick; fall:=0; fjut:=2/3sqxside;
161 %%ductus:=true;
162 draw_jstem(1,2,srad,d/2,d/2);
163 draw_flick(3,rise,fall,fjut);
164 draw_flick(4,rise,fall,fjut);
165 ductus:=false;
166 proofpcbb(100, y100, y100);
167 penlabels(1,2,3,4,100);
168 endchar; % end "f"
169
170 cmchar "Uncial letter g";
171 beginchar("g", u#+hstretch*(x_height#), x_height#, 0);
172 adjust_fit(0,0);
173 pcshiftx := u/2;
174 sqyside:=h; sqxside:=hstretch*sqyside;
175 y100 = h/2; x100 = pcshiftx+y100; % square center
176 pickup quill;
177 lft x1=pcshiftx; rt x3=pcshiftx+sqxside; y1=y3=h/2;
178 x2=x4=w/2; top y2=h; bot y4=0;
179 x5=x6=x3;
180 y5=0.2h;
181 y6=0.75h;
182 lft x7=x5-thick; bot y7=y5-3thick;
183 %%ductus:=true;
184 if ductus:
185 pickup stylus;
186 fi
187 draw z5{-pdir}..{left}z4..z1..z2..z6; % the bowl
188 draw z5{down}..{-pdir}z7; % the stem
189 ductus:=false;
190 proofpcbb(100, y100, y100);
191 penlabels(1,2,3,4,5,6,7,100);
192 endchar; % end "g"
193
194 cmchar "Uncial letter h";
195 beginchar("h", 2u#+hstretch*(jut#+thick#+x_height#), asc_height#, 0);
196 adjust_fit(0,0);
197 pcshiftx := u+jut;
198 sqyside:=h/2; % asc_height is 2x_height !!!
199 sqxside:=hstretch*sqyside;
200 y100 = sqyside/2; x100 = pcshiftx+y100; % square center
201 pickup quill;
202 lft x1=lft x2=pcshiftx;
203 top y1=h; bot y2=0;
204 x99=w/2; y99=sqyside/2;
205 y3=y5=y99;
206 lft x3= pcshiftx;
207 %%rt x5=x99+w-pcshiftx;
208 x5 = x99 + (x99-x3);
209 x4=x6=x99; top y4=sqyside; bot y6 =0;
210 path pcirc; pcirc=z6..z5..z4..z3..cycle;
211 x1'=x2'=x1+0.5thick; y1'=h; y2'=0;
212 z7' = (z1'--z2') intersectionpoint (subpath(2,3) of pcirc);
213 x7=x1; y7=y7';
214 z99'=z99 - 500ppdir;
215 z8' = (z99--z99') intersectionpoint subpath(0,1) of pcirc;
216 x8=x8'; bot y8=0;
217 %%ductus:=true;
218 if ductus:
219 pickup stylus;
220 draw z1'--z2'; draw z99--z99'; draw pcirc;
221 fi
222 draw_istem(1,2,srad);
223 draw z7{pdir}..z4{right}..z5{down}..{-pdir}z8;
224 ductus:=false;
225 proofpcbb(100, y100, y100);
226 penlabels(1,1',2,2',3,4,5,6,7,7',8,8',99,99',100);
227 endchar; % end "h"
228
229 cmchar "Uncial letter i";
230 beginchar("i", 2u#+hstretch*(thick#+2jut#), x_height#, 0);
231 adjust_fit(0,0);
232 pcshiftx := u+jut;
233 y100 = h/2; x100 = pcshiftx+y100; % square center
234 pickup quill;
235 x1=x2=w/2;
236 top y1=h; bot y2=0;
237 %%ductus:=true;
238 draw_istem(1,2,srad);
239 ductus:=false;
240 proofpcbb(100, y100, y100);
241 penlabels(1,2,100);
242 endchar; % end "i"
243
244 cmchar "Uncial letter j";
245 beginchar("j", 2u#+hstretch*(thick#+2jut#), x_height#, desc_depth#);
246 adjust_fit(0,0);
247 pcshiftx := u+jut;
248 sqyside:=h; sqxside:=sqyside;
249 y100 = h/2; x100 = pcshiftx+y100; % square center
250 pickup quill;
251 x1=x2=w/2;
252 top y1=h; bot y2=0;
253 %%ductus:=true;
254 draw_jstem(1,2,srad,2/3sqxside,desc_depth);
255 ductus:=false;
256 proofpcbb(100, y100, y100);
257 penlabels(1,2,100);
258 endchar; % end "j"
259
260 cmchar "Uncial letter k";
261 beginchar("k", 2u#+hstretch*(jut#+4/3x_height#), asc_height#, 0);
262 adjust_fit(0,0);
263 pcshiftx := u+jut;
264 sqyside:=h/2; % asc_height = 2x_height !!!
265 sqxside:=hstretch*sqyside;
266 y100 = side/2; x100 = pcshiftx+y100; % square center
267 pickup quill;
268 lft x1=lft x2=pcshiftx;
269 top y1=h; bot y2=0;
270 numeric rise,fall,fjut;
271 x3=x1; y3=2/3side;
272 rise:=1/3sqyside; fall:=-rise/2; fjut:=sqxside; %% fjut:=2/3side;
273 x4=x3+0.25thick; y4=y3+0.5thick;
274 x5=x3+side; y5=0;
275 %%ductus:=true;
276 if ductus:
277 pickup stylus;
278 fi
279 draw_istem(1,2,srad);
280 draw_flick(3,rise,fall,fjut);
281 draw_tstem(4,5,srad);
282 ductus:=false;
283 proofpcbb(100, y100, y100);
284 penlabels(1,2,3,4,5,100);
285 endchar; % end "k"
286
287 cmchar "Uncial letter l";
288 beginchar("l", 2u#+hstretch*(x_height#+jut#), asc_height#, 0);
289 adjust_fit(0,0);
290 pcshiftx := u+jut;
291 sqyside:=h/2; sqxside:=hstretch*sqyside;
292 y100 = h/2; x100 = pcshiftx+y100; % square center
293 pickup quill;
294 lft x1=lft x2=pcshiftx;
295 top y1=h; y2=h/4;
296 x3=0.5[x1,x4]; bot y3=0;
297 rt x4=w-u; y4=0.1h;
298 %%ductus:=true;
299 draw_tlserif(1,2,srad); % the stem
300 draw z2{down}..z3{right}..{pdir}z4; % the bowl
301 ductus:=false;
302 proofpcbb(100, y100, y100);
303 penlabels(1,2,100);
304 endchar; % end "l"
305
306 cmchar "Uncial letter m";
307 beginchar("m", 2u#+hstretch*(9/6x_height#), x_height#, 0);
308 adjust_fit(0,0);
309 pcshiftx := u;
310 sqyside:=h; sqxside:=hstretch*sqyside;
311 y100 = h/2; x100 = pcshiftx+y100; % square center
312 pickup quill;
313 x1=1/3sqxside; bot y1=0;
314 lft x2= pcshiftx; y2=h/2;
315 lft x4=pcshiftx+2/3sqxside; y4=2/3h;
316 x3=0.5[x2,x4]; top y3=h;
317 x5=x4; y5=y1;
318 z6=z4;
319 numeric rise,fall,mjut;
320 rise=h-y6; fall=y6; mjut=w-pcshiftx-x6;
321 %%ductus:=true;
322 draw z1..z2{up}..z3{right}..{down}z4; % left half
323 draw_tstem(4,5,srad); % middle stem
324 draw_hbowl(6,rise,fall,mjut); % right half
325 ductus:=false;
326 proofpcbb(100, y100, y100);
327 penlabels(1,2,3,4,5,6,100);
328 endchar; % end "m"
329
330 cmchar "Uncial letter n";
331 beginchar("n", 2u#+hstretch*(jut#+x_height#), x_height#, 0.5x_height#);
332 adjust_fit(0,0);
333 pcshiftx := u;
334 sqyside:=h; sqxside:=hstretch*sqyside;
335 y100 = h/2; x100 = pcshiftx+y100; % square center
336 pickup quill;
337 lft x1=pcshiftx; top y1=h;
338 x2=x1; y2=y1-thin;
339 numeric jjut, jdepth;
340 jjut=2jut; jdepth=y2+d-thin;
341 rt x4=pcshiftx+sqxside; y4=y1;
342 x3=x4; bot y3=0;
343 %%ductus:=true;
344 if ductus:
345 pickup stylus;
346 fi
347 draw_jcurve(1,srad,jjut,jdepth); % left stem
348 draw_istem(4,3,srad); % right stem
349 draw z1--z3; % diagonal
350 ductus:=false;
351 proofpcbb(100, y100, y100);
352 penlabels(1,2,3,4,100);
353 endchar; % end "n"
354
355 cmchar "Uncial letter o";
356 beginchar("o", u#+hstretch*(x_height#), x_height#, 0);
357 adjust_fit(0,0);
358 pcshiftx := u/2;
359 sqyside:=h;
360 sqxside:=hstretch*sqyside;
361 y100 = h/2; x100 = pcshiftx+y100; % square center
362 pickup quill;
363 lft x1=pcshiftx; rt x3=w-pcshiftx; y1=y3=h/2;
364 x2=x4=w/2; top y2=h+o; bot y4=-o;
365 %%ductus:=true;
366 if ductus:
367 pickup stylus;
368 fi
369 draw z1..z2..z3..z4..cycle;
370 ductus:=false;
371 proofpcbb(100, y100, y100);
372 penlabels(1,2,3,4,100);
373 endchar; % end "o"
374
375 cmchar "Uncial letter p";
376 beginchar("p", 2u#+hstretch*(x_height#+jut#), x_height#, x_height#);
377 adjust_fit(0,0);
378 pcshiftx := u+jut;
379 sqyside:=h; sqxside:=hstretch*sqyside;
380 y100 = h/2; x100 = pcshiftx+y100; % square center
381 pickup quill;
382 lft x1=pcshiftx; top y1=h;
383 numeric jjut, jdepth;
384 jjut=1/3sqxside-thin; jdepth=h+d-thin;
385 x2=x1; y2=3/4h; %% y2=2/3side;
386 rt x4=w-u;
387 lft x5=x1+thick; y5=0;
388 y4=0.4[y3,y5];
389 top y3=h; x3=0.5[x2,x4];
390 %%ductus:=true;
391 if ductus:
392 pickup stylus;
393 fi
394 draw_jcurve(1,srad,jjut,jdepth); % stem
395 %%draw z2..z3{right}..z4{down}..{-pdir}z5; % bowl
396 draw z1a..z3{right}..z4{down}..{-pdir}z5; % bowl
397 ductus:=false;
398 proofpcbb(100, y100, y100);
399 penlabels(1,2,3,4,5,100);
400 endchar; % end "p"
401
402 cmchar "Uncial letter q";
403 beginchar("q", 2u#+hstretch*(x_height#), x_height#, x_height#);
404 adjust_fit(0,0);
405 pcshiftx := u;
406 sqyside:=h; sqxside:=hstretch*sqyside;
407 y100 = h/2; x100 = pcshiftx+y100; % square center
408 pickup quill;
409 rt x1=w-pcshiftx; top y1=h;
410 numeric jjut, jdepth;
411 jjut=2jut; jdepth=h+d-thin;
412 x2=x1-jjut; y2=y1-jdepth;
413 numeric rad; rad := w/2;
414 x0=w/2; y0=h/2;
415 lft x4=pcshiftx; y4=y0;
416 x3=x5=x0; top y3=h; bot y5=0;
417 x7=x0+rad; y7=y0;
418 path p[];
419 p1=z1{down}..{-pdir}z2; % stem
420 p2=z4{down}..z5{right}..{up}z7;
421 z6'= p1 intersectionpoint p2;
422 rt x6=x6'; y6=y6';
423 %%ductus:=true;
424 if ductus:
425 pickup stylus;
426 fi
427 draw z1{down}...{-pdir}z2; % right stem
428 draw z1--z3..z4{down}..{right}z5..z6; % bowl
429 ductus:=false;
430 proofpcbb(100, y100, y100);
431 penlabels(0,1,2,3,4,5,6,6',7,100);
432 endchar; % end "q"
433
434 cmchar "Uncial letter r";
435 beginchar("r", 2u#+hstretch*(4/3x_height#), x_height#, 2/3x_height#);
436 adjust_fit(0,0);
437 sqyside:=h; sqxside:=hstretch*sqyside;
438 pcshiftx := u+jut;
439 y100 = h/2; x100 = pcshiftx+y100; % square center
440 pickup quill;
441 lft x1=pcshiftx; top y1=h;
442 numeric jjut, jdepth;
443 jjut=1/5sqxside; jdepth=h+d-thin;
444 x2=x1; y2=3/4h;
445 rt x4=pcshiftx+3/4sqxside;
446 lft x5=x1; bot y5=1/6h;
447 y4=0.4[y3,y5];
448 top y3=h; x3=0.5[x2,x4];
449 rt x7=w-u; y7=-thin;
450 %%ductus:=true;
451 if ductus:
452 pickup stylus;
453 fi
454 draw_jcurve(1,srad,jjut,jdepth); % stem
455 draw z1a..z3{right}..z4{down}..{-pdir}z5; % bowl
456 draw z5{-ppdir}..{right}z7; % leg
457 ductus:=false;
458 proofpcbb(100, y100, y100);
459 penlabels(1,2,3,4,5,6,7,100);
460 endchar; % end "r"
461
462 cmchar "Uncial letter s";
463 beginchar("s", 2u#+hstretch*(5/6x_height#), x_height#, 0);
464 adjust_fit(0,0);
465 pcshiftx := u;
466 sqyside:=h; sqxside:=hstretch*sqyside;
467 y100 = h/2; x100 = pcshiftx+y100; % square center
468 pickup quill;
469 rt x1=w-pcshiftx; top y1=h-thin;
470 x2=w/2; top y2=h;
471 lft x3=pcshiftx; y3=0.75h;
472 x4=w/2; y4=h/2;
473 rt x5=w-pcshiftx; y5=0.25h;
474 x6=w/2; bot y6=0;
475 lft x7= pcshiftx; bot y7 = thin;
476 path p[];
477 p1=z1..z2{left}..z3{down}..z4..z5{down}..z6{left}..z7;
478 pair vec[];
479 vec1= direction 0 of p1;
480 vec2= direction (length p1) of p1;
481 z11=z1 shifted vec1;
482 z17=z7 shifted -vec2;
483 %%ductus:=true;
484 if ductus:
485 pickup stylus;
486 fi
487 %%draw_serif(1,11,srad);
488 %%draw_serif(7,17,srad);
489 %%draw z1a..z2{left}..z3{down}..z4..z5{down}..z6{left}..z7a;
490 draw p1;
491 ductus:=false;
492 proofpcbb(100, y100, y100);
493 penlabels(1,2,3,4,5,6,7,11,17,100);
494 endchar; % end "s"
495
496 cmchar "Uncial letter t";
497 beginchar("t", u#+hstretch*(x_height#), x_height#, 0);
498 adjust_fit(0,0);
499 pcshiftx := u/2;
500 sqyside:=h; sqxside:=hstretch*sqyside;
501 y100 = h/2; x100 = pcshiftx+y100; % square center
502 pickup quill;
503 x1=x2=w/2;
504 top y1=h; bot y2=0;
505 lft x3=pcshiftx; top y3=h-thin;
506 x4=x2; top y4=h;
507 rt x5=w-pcshiftx; top y5=h+thin;
508 %%ductus:=true;
509 if ductus:
510 pickup stylus;
511 fi
512 draw_tstem(1,2,srad);
513 draw z3{pdir}..z4{right}..{pdir}z5;
514 ductus:=false;
515 proofpcbb(100, y100, y100);
516 penlabels(1,2,3,4,5,100);
517 endchar; % end "t"
518
519 cmchar "Uncial letter u";
520 beginchar("u", 2u#+hstretch*(x_height#+jut#), x_height#, 0);
521 adjust_fit(0,0);
522 pcshiftx := u;
523 sqyside:=h; sqxside:=hstretch*sqyside;
524 y100 = h/2; x100 = pcshiftx+y100; % square center
525 pickup quill;
526 lft x6=pcshiftx+thick;
527 top y6=h;
528 lft x7=pcshiftx; y7=h/2;
529 x8=pcshiftx+0.5sqxside; bot y8=0;
530 rt x1=w-pcshiftx-jut; y1=h;
531 x2=x1; bot y2=0;
532 x5=x1+sqxside-thick; y5=y6;
533 path p[];
534 p1=z1--z2;
535 p2=z6..z7{down}..z8{right}..z5;
536 z9= p2 intersectionpoint p1;
537 pair vec[];
538 vec2 = direction 0 of p2;
539 z16=z6 shifted vec2;
540 %%ductus:=true;
541 if ductus:
542 pickup stylus;
543 fi
544 draw_serif(6,16,srad); % left half
545 draw z6a..z7{down}..z8{right}..z9;
546 draw_istem(1,2,srad); % right stem
547 ductus:=false;
548 proofpcbb(100, y100, y100);
549 penlabels(1,2,3,4,5,6,7,8,9,11,16,100);
550 endchar; % end "u"
551
552 cmchar "Uncial letter v";
553 beginchar("v", 2u#+hstretch*(x_height#), x_height#, 0);
554 adjust_fit(0,0);
555 pcshiftx := u;
556 sqyside:=h; sqxside:=hstretch*sqyside;
557 y100 = h/2; x100 = pcshiftx+y100; % square center
558 pickup quill;
559 numeric midx; midx:= pcshiftx;
560 lft x1=midx+jut; top y1=h;
561 lft x2=midx; y2=h/2;
562 rt x4=midx+sqxside; y4=y2;
563 x3=0.5[x2,x4]; bot y3=0;
564 x5=x4-thick; y5=y1;
565 path p[];
566 p1=z1..z2{down}..z3{right}..z4{up}..z5;
567 pair vec[];
568 vec1 = direction 0 of p1;
569 z11=z1 shifted vec1;
570 %%ductus:=true;
571 if ductus:
572 pickup stylus;
573 fi
574 draw_serif(1,11,srad); % right half
575 draw z1a..z2{down}..z3{right}..z4{up}..z5;
576 ductus:=false;
577 proofpcbb(100, y100, y100);
578 penlabels(1,2,3,4,5,11,100);
579 endchar; % end "v"
580
581 cmchar "Uncial letter w";
582 beginchar("w", 2u#+hstretch*(5/3x_height#), x_height#, 0);
583 adjust_fit(0,0);
584 pcshiftx := u;
585 sqyside:=h; sqxside:=hstretch*sqyside;
586 y100 = h/2; x100 = pcshiftx+y100; % square center
587 pickup quill;
588 numeric midx; midx:= pcshiftx+2/3sqxside;
589 lft x1=midx+jut; top y1=h;
590 lft x2=midx; y2=h/2;
591 rt x4=midx+sqxside; y4=y2;
592 x3=0.5[x2,x4]; bot y3=0;
593 x5=x4-thick; y5=y1;
594 path p[];
595 p1=z1..z2{down}..z3{right}..z4{up}..z5;
596 lft x6=pcshiftx+thick;
597 y6=y1;
598 lft x7=pcshiftx; y7=y2;
599 x8=pcshiftx+0.5sqxside; y8=y3;
600 p2=z6..z7{down}..z8{right}..(z5 shifted -pdir);
601 z9= p2 intersectionpoint p1;
602 pair vec[];
603 vec1 = direction 0 of p1;
604 vec2 = direction 0 of p2;
605 z11=z1 shifted vec1;
606 z16=z6 shifted vec2;
607 %%ductus:=true;
608 if ductus:
609 pickup stylus;
610 fi
611 draw_serif(1,11,srad); % right half
612 draw z1a..z2{down}..z3{right}..z4{up}..z5;
613 draw_serif(6,16,srad); % left half
614 draw z6a..z7{down}..z8{right}..z9;
615 ductus:=false;
616 proofpcbb(100, y100, y100);
617 penlabels(1,2,3,4,5,6,7,8,9,11,16,100);
618 endchar; % end "w"
619
620 cmchar "Uncial letter x";
621 beginchar("x", u#+hstretch*(5/3x_height#), x_height#, 1/3x_height#);
622 adjust_fit(0,0);
623 pcshiftx := 0;
624 sqyside:=h; sqxside:=hstretch*sqyside;
625 y100 = h/2; x100 = pcshiftx+y100; % square center
626 pickup quill;
627 lft x1=pcshiftx+1/2sqxside; rt x2=w-jut;
628 y1=h; y2=0;
629 lft x3=pcshiftx; bot y3=-d;
630 z4=z3 shifted (jut*right);
631 z5=z4 shifted (jut*pdir);
632 rt x8=w-pcshiftx; top y8=h;
633 z7=z8 shifted (jut*left);
634 z6=z7 shifted (-jut*pdir);
635 %%ductus:=true;
636 if ductus:
637 pickup stylus;
638 fi
639 draw_istem(1,2,srad); % thick diagonal
640 draw z3---z4..z5---z6..z7---z8; % thin diagonal
641 ductus:=false;
642 proofpcbb(100, y100, y100);
643 penlabels(1,2,3,4,5,6,7,8,100);
644 endchar; % end "x"
645
646 cmchar "Uncial letter y";
647 beginchar("y", 2u#+hstretch*(4/3x_height#), x_height#, 2/3x_height#);
648 adjust_fit(0,0);
649 pcshiftx := u;
650 sqyside:=h; sqxside:=hstretch*sqyside;
651 y100 = h/2; x100 = pcshiftx+y100; % square center
652 pickup quill;
653 lft x1=pcshiftx; top y1=3/4h;
654 lft x3=w/2; bot y3=-d;
655 x2=0.8[x1,x3]; y2=0.5[y1,y3];
656 rt x4=w-pcshiftx; y4=y1;
657 x7=pcshiftx; y7=-d;
658 path p[];
659 p1=z1..z2..z3;
660 z6= (z7--z4) intersectionpoint p1;
661 x5=0.4[x6,x4]; y5=0.5[y6,y4];
662 x8=x6; y8=h;
663 if ductus:
664 pickup stylus;
665 fi
666 draw z1..z2..z3; % left stroke
667 draw z4{left}..z6; % right stroke
668 draw_pdot(8,dot_size);
669 ductus:=false;
670 proofpcbb(100, y100, y100);
671 penlabels(1,2,3,4,5,6,7,8,9,10,100);
672 endchar; % end "y"
673
674 cmchar "Uncial letter z";
675 beginchar("z", 2u#+hstretch*(4/3x_height#), x_height#, 0);
676 adjust_fit(0,0);
677 pcshiftx := u;
678 sqyside:=h; sqxside:=hstretch*sqyside;
679 y100 = h/2; x100 = pcshiftx+y100; % square center
680 pickup quill;
681 lft x4=pcshiftx; bot y4=0;
682 rt x6=w-pcshiftx; y6=y4;
683 x5=0.5[x4,x6]; y5=y4+thin;
684 x1=x4; top y1=h;
685 x3=pcshiftx+sqxside; y3=y1;
686 x2=0.5[x1,x3]; top y2=h-thin;
687 %%ductus:=true;
688 if ductus:
689 pickup stylus;
690 fi
691 draw z1..z2..z3; % top stroke
692 draw z4..z5..z6; % bottom stroke
693 pickup stylus;
694 draw z4--z3;
695 ductus:=false;
696 proofpcbb(100, y100, y100);
697 penlabels(1,2,3,4,5,6,100);
698 endchar; % end "z"
699