Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/pgothdig.mf

raw
1 %%
2 %% This is file `pgothdig.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% pgothic.dtx (with options: `dig')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19 cmchar "PGOTH digit 1";
20 beginchar("1", 2u#+fig_width#, fig_height#, 0);
21 adjust_fit(0,0);
22 pcshiftx := sb;
23 pickup quill;
24 x1 = x2 = 1/2w; y1 = h; y2 = 0;
25 z12 = 1/2[z1,z2];
26 draw_updiamondstem(1,12,1/2,1/2,diawd,diang);
27 draw z12--z2; draw_flat_foot(2);
28 penlabels(1,2,100);
29 endchar; % end "1"
30
31 cmchar "PGOTH digit 2";
32 beginchar("2", 2u#+fig_width#, fig_height#, 0);
33 adjust_fit(0,0);
34 pcshiftx := u;
35 numeric st; st := stem_width;
36 numeric n[];
37 n1 := 1/2st;
38 pickup quill;
39 lft x1=pcshiftx+n1; top y1=h-2n1;
40 rt x3=w-pcshiftx-n1; y3=3/4h;
41 x2=1/2[x1,x3]; top y2= h;
42 x5= lft x1; bot y5=0;
43 x6= rt x3; y6=y5;
44 %%ductus:=true;
45 if ductus:
46 pickup stylus;
47 fi
48 draw_wave(5,6,thin); % foot
49 draw z1--z2--z3--z5wl; % curve
50 ductus:=false;
51 penlabels(1,2,3,4,5,6,100);
52 endchar; % end "2"
53
54 cmchar "PGOTH digit 3";
55 beginchar("3", 2u#+fig_width#, fig_height#, 0);
56 adjust_fit(0,0);
57 numeric n[];
58 numeric st; st := stem_width;
59 n1 := st;
60 pcshiftx := u;
61 pickup quill;
62 %% top
63 lft x1 = pcshiftx + n1; rt x3 = w - pcshiftx - n1;
64 x2 = 1/2[x1,x3]; x4 = 1/2[x1,x2];
65 top y2 = h; y3 = 12/16h;
66 (z2-z1) = whatever*pdir;
67 (z3-z4) = whatever*pdir;
68 %% bottom
69 x5 = 12/16[x4, rt x4]; x6 = x3; x7 = x2;
70 x18 = x1-n1; x17 = x7;
71 bot y7 = thin;
72 y5 = 12/16[y4, top y4];
73 (z5-z6) = whatever*(z2-z3);
74 bot y18 = 0; bot y17 = 0;
75
76 draw z1--z2--z3--z4; % top
77 draw_wave(18,17,thin);
78 draw z5--z6--z18wr; % bottom
79 ductus:=false;
80 penlabels(1,2,3,4,5,6,7,8,9,10,17,18,100);
81 endchar; % end "3"
82
83 cmchar "PGOTH digit 4";
84 beginchar("4", 2u#+fig_width#, fig_height#, 0);
85 adjust_fit(0,0);
86 numeric st; st := stem_width;
87 numeric n[];
88 pcshiftx := u;
89 pickup quill;
90 x1=x2=w-pcshiftx-(wided+widedmin)*st;
91 y1=h; y2=0;
92 lft x3=pcshiftx; y3=7/16h;
93 rt x4=w-pcshiftx; y4=y3;
94 %%ductus:=true;
95 if ductus:
96 pickup stylus;
97 fi
98 draw z1--z2; draw_flat_foot(2);
99 draw z3--z4; % horizontal
100 draw z1--z3; % diagonal
101 ductus:=false;
102 penlabels(1,2,3,4,100);
103 endchar; % end "4"
104
105 cmchar "PGOTH digit 5";
106 beginchar("5", 2u#+fig_width#, fig_height#, 0);
107 adjust_fit(0,0);
108 pcshiftx := u;
109 numeric n[];
110 numeric st; st := stem_width;
111 n1 := st;
112 pickup quill;
113 rt x1=w-pcshiftx; top y1=h;
114 lft x2=pcshiftx+n1; y2=y1;
115 x3=x2; y3=0.5h;
116 x4=0.5[x1,x3]; y4=0.5[y3,y5];
117 rt x5=w-pcshiftx; y5=1/2[thick,y3];
118 x6=w/2; bot y6=0;
119 %%x16 = 12/16[x3,x5];
120 x16 = lft x5;
121 bot y16 = 0;
122 lft x17=pcshiftx; bot y17=0;
123 z167 = 1/2[z16,z17];
124 %%ductus:=true;
125 if ductus:
126 pickup stylus;
127 fi
128 draw_wave(2,1,thin); % top squiggle
129 draw z2wl--z3; % vertical
130 %%draw_wave(17,16,thin); % foot
131 draw z17{pdir}..{pdir}z16; % foot
132 draw z3{pdir}..z5{down}..z16; % curve
133 ductus:=false;
134 penlabels(1,2,3,4,5,6,7,100);
135 endchar; % end "5"
136
137 cmchar "PGOTH digit 6";
138 beginchar("6", 2u#+fig_width#, fig_height#, 0);
139 adjust_fit(0,0);
140 pcshiftx := sb;
141 numeric n[];
142 numeric st; st := stem_width;
143 n1 := 24/16st;
144 pickup quill;
145 %% bottom left
146 x1 = x4 = w/2; top y1 = h - thick; bot y4 = 0;
147 x2 = x3 = x1 + n1; x5 = x6 = x1 - n1;
148 n2 = top y1;
149 y2 = y6 = 3/4[y4,y1];
150 y3 = y5 = 1/4[y4,y1];
151 %% bowl
152 draw z1--z2--z3--z4--z5--z6--cycle;
153 %% head
154 x11 = x5; top y11 = h;
155 x12 = x2; y12 = y11;
156 draw_wave(11,12,thin);
157 x16 = x11; y16 = y11-thin;
158 draw z6--z16;
159 penlabels(1,2,3,4,5,6,12,100);
160 endchar; % end "6"
161
162 cmchar "PGOTH digit 7";
163 beginchar("7", 2u#+fig_width#, fig_height#, 0);
164 adjust_fit(0,0);
165 pcshiftx := u;
166 pickup quill;
167 lft x1=pcshiftx;
168 rt x2=w-pcshiftx;
169 top y1=top y2=h;
170 x4=w/2; bot y4=0;
171 x3=0.5[x2,x4]-3thin; y3=0.5[y2,y4];
172 %%ductus:=true;
173 if ductus:
174 pickup stylus;
175 fi
176 draw_wave(1,2,thin); % top bar
177 draw z1wr..z3..z4;
178 draw_flat_foot(4);
179 ductus:=false;
180 penlabels(1,2,3,4,5,6,100);
181 endchar; % end "7"
182
183 cmchar "PGOTH digit 8";
184 beginchar("8", 2u#+fig_width#, fig_height#, 0);
185 adjust_fit(0,0);
186 pcshiftx := u;
187 numeric alpha; alpha:=1;
188 pickup quill;
189 lft x1= pcshiftx; rt x3=w-pcshiftx; top y1 = y3 = 3/4h;
190 rt x2 = lft x4 = w/2; top y2=h; bot y4=0;
191 x5=x2; y5=h/2+2o;
192 lft x11=pcshiftx; rt x13=w-pcshiftx; y11 = bot y13 = 1/4h;
193 %%ductus:=true;
194 if ductus:
195 pickup stylus;
196 fi
197 %%draw z1..z2..z3..z5..z11..z4..z13..z5..cycle;
198 draw z1--z2--z3--z11--z4--z13--cycle;
199 ductus:=false;
200 penlabels(1,2,3,4,5,11,13,100);
201 endchar; % end "8"
202
203 cmchar "PGOTH digit 9";
204 beginchar("9", 2u#+fig_width#, fig_height#, 0);
205 adjust_fit(0,0);
206 pcshiftx := sb;
207 numeric n[];
208 numeric st; st := stem_width;
209 n1 := 24/16st;
210 pickup quill;
211 %% bottom left
212 x1 = x4 = w/2; top y1 = h; bot y4 = thick;
213 x2 = x3 = x1 + n1; x5 = x6 = x1 - n1;
214 y2 = y6 = 3/4[y4,y1];
215 y3 = y5 = 1/4[y4,y1];
216 %% bowl
217 draw z1--z2--z3--z4--z5--z6--cycle;
218 %% foot
219 x11 = x5; bot y11 = 0;
220 x12 = x2; y12 = y11;
221 draw_wave(11,12,thin);
222 x13 = x12; y13 = y12+thin;
223 draw z3--z13;
224 penlabels(1,2,3,4,5,6,12,100);
225 endchar; % end "9"
226
227 cmchar "PGOTH digit 0";
228 beginchar("0", 2u#+fig_width#, fig_height#, 0);
229 adjust_fit(0,0);
230 pcshiftx := sb;
231 numeric n[];
232 numeric st; st := stem_width;
233 n1 := 24/16st;
234 pickup quill;
235 %% bottom left
236 x1 = x4 = w/2; top y1 = h; bot y4 = 0;
237 x2 = x3 = x1 + n1; x5 = x6 = x1 - n1;
238 y2 = y6 = 3/4h;
239 y3 = y5 = 1/4h;
240
241 draw z1--z2--z3--z4--z5--z6--cycle;
242
243 penlabels(1,2,3,4,5,6,12,100);
244 endchar; % end "0"
245