Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/rusttitle.mf

raw
1 %%
2 %% This is file `rusttitle.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% rustic.dtx (with options: `mfd')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18 def makebox(text rule) =
19 for y=0,half_height,cap_height,body_height,x_height,-desc_depth,-body_depth:
20 rule((l,y)t_,(r,y)t_); endfor % horizontals
21 for x=l,r: rule((x,-body_depth)t_,(x,body_height)t_); endfor % verticals
22 for x=u*(1+floor(1/u)) step u until r-1:
23 rule((x,-body_depth)t_,(x,body_height)t_); endfor % more verticals
24 if charic<>0:
25 rule((r+charic*pt,h.o_),(r+charic*pt,.5h.o_)); fi % italic correction
26 enddef;
27
28
29 def proofpcbb(suffix $)(expr xoff, yoff) =
30 if proofing > 0:
31 x$bl = x$ - xoff; y$bl = y$ - yoff; % Bottom Left Hand Corner
32 z$br = (x$bl+side, y$bl); % BRHC
33 z$tr = (x$bl+side, y$bl+side); % TRHC
34 z$tl = (x$bl, y$bl+side); % TLHC
35 z$bc = 1/2[z$bl,z$br]; z$tc = 1/2[z$tl,z$tr]; % horizontal mid points
36 pair hc, vc;
37 hc = (2u,0); vc = (0,2u);
38 pickup pensquare scaled 2;
39 for s = z$bl, z$br, z$tr, z$tl, z$bc, z$tc:
40 draw s-hc--s+hc;
41 draw s-vc--s+vc;
42 endfor
43 fi
44 enddef;
45
46
47 def rustic_font_setup=
48 define_pixels(side,half_height,carol_height,comma_width);
49 define_pixels(u,dot_size,letter_size,cap_height,width_adj,serif_fit,
50 cap_serif_fit,jut,cap_jut);
51 define_pixels(hookjut,footjut,stem_offset,extra_fhjut,fig_width);
52 define_whole_pixels(letter_fit);
53 define_whole_vertical_pixels(body_height,asc_height,cap_height,x_height,
54 desc_depth,body_depth,fig_height);
55 define_corrected_pixels(o);
56 define_blacker_pixels(thick,thin);
57 let adjust_fit = normal_adjust_fit;
58 pickup pencircle scaled thin;
59 stylus:=savepen;
60 pickup pencircle xscaled thick yscaled thin rotated pangle;
61 quill:=savepen;
62 pickup pencircle xscaled thick yscaled thin rotated ((1/2(pangle+90)));
63 bowpen:=savepen;
64 numeric pcshiftx#; % x value of LHS of box wrt origin of char box
65 define_pixels(pcshiftx);
66 numeric sqxside#; % x size of the square
67 numeric sqyside#; % y size of the square
68 define_pixels(sqxside,sqyside);
69
70 enddef; % end of rustic_font_setup
71
72 boolean ductus;
73 ductus:=false;
74 pair pdir; pdir=dir(pangle);
75 pair ppdir; ppdir=dir(pangle+90);
76
77 def draw_rusticstem(suffix $, $$)=
78 numeric alpha, beta; alpha:=0.5thick;
79 beta:=60; % the ending angle
80 pair rustic[];
81 xpart rustic1=x$$; ypart rustic1=y$$+alpha*sind(beta);
82 z$a=1/2[z$,rustic1];
83 z$b=2/3[z$,rustic1];
84 z$c=5/6[z$,rustic1];
85 z$d=rustic1;
86 z$ar=z$a shifted (alpha*up); z$al=z$a shifted (alpha*down);
87
88 rustic2:=z$b shifted (alpha*right);
89 z$br=rustic2 rotatedaround(z$b,1/4[90,beta]); z$bl=z$br rotatedaround(z$b,180);
90
91 rustic2:=z$c shifted (alpha*right);
92 z$cr=rustic2 rotatedaround(z$c,1/2[90,beta]); z$cl=z$cr rotatedaround(z$c,180);
93
94 rustic2:=z$d shifted (alpha*right);
95 %% z$dr=rustic2 rotatedaround(z$d,60); z$dl=z$dr rotatedaround(z$d,180);
96 rustic3=rustic2 rotatedaround(z$d,beta);
97 x$dr=xpart rustic3; y$dr=ypart rustic3 - thin;
98 z$dl=z$dr rotatedaround(z$d,180);
99 pen oldpen; oldpen:=currentpen;
100 pickup stylus;
101 draw z$--z$al;
102 %% filldraw z$ar..z$br..z$cr..z$dr--z$dl..z$cl..z$bl..z$al--cycle;
103 filldraw z$ar..z$br..z$cr..z$dr--z$dl..z$bl..z$al--cycle;
104 pickup oldpen;
105 %% labels($a,$al,$ar,$b,$bl,$br,$c,$cl,$cr,$dl,$dr);
106 labels($a,$b,$c,$d,$dl,$dr);
107 enddef; % end of draw_rusticstem
108
109
110 def draw_hserif(suffix $, $$)(expr fr)=
111 pen oldpen; oldpen:=currentpen;
112 numeric beta, ajut, bjut;
113 beta=1-fr;
114 ajut=fr*jut; bjut=beta*jut;
115 pair rustic;
116 numeric tn, ang; ang:=70;
117 tn:=(sind ang)/(cosd ang);
118 x$g=x$-hookjut; y$g=y$-(hookjut*tn); % the tip
119 x$f=x$; y$f=y$g; % on the stem
120 pickup stylus;
121 %% filldraw z$g{dir(ang)}..{down}z$f--z$--cycle;
122 draw z$g--z$;
123 pickup oldpen;
124 labels($f,$g);
125 enddef; % end of draw_hserif
126
127
128 def draw_footstem(suffix $, $$)=
129 draw_rusticstem($, $$);
130 x$$fl=x$dl; bot y$$fl= y$$;
131 x$$fr=x$$fl+2footjut; y$$fr=y$$fl;
132 draw_squiggle($$fl,$$fr,wiggle,srad);
133 labels($$fl,$$fr);
134 enddef; % end of draw_footstem
135
136
137 def draw_foot(suffix $)=
138 x$fl=x$-footjut; bot y$fl= y$;
139 x$fr-x$=x$-x$fl; y$fr=y$fl;
140 draw_squiggle($fl,$fr,wiggle,srad);
141 labels($fl,$fr);
142 enddef; % end of draw_foot
143
144
145 def draw_head(suffix $)=
146 x$hl=x$-footjut; top y$hl= y$;
147 x$hr-x$=x$-x$hl; y$hr=y$hl;
148 draw_squiggle($hl,$hr,wiggle,srad);
149 labels($hl,$hr);
150 enddef; % end of draw_head
151
152
153 def draw_bow(suffix $, $$)(expr fr)=
154 pen oldpen; oldpen:=currentpen;
155 z$bm=1/2[z$,z$$];
156 l:=length(z$-z$$);
157 bdir:=angle(z$-z$$);
158 %% z$bo=z$bm shifted (fr*l*dir(bdir+90));
159 z$bo=z$bm shifted (fr*l*dir(bdir-90));
160 pickup bowpen;
161 draw z$..z$bo..z$$;
162 pickup oldpen;
163 labels($bm,$bo);
164 enddef; % end of draw_bow
165
166
167 def draw_squiggle(suffix $, $$)(expr w, fr)=
168 z$si=1/4[z$,z$$]; z$sii=3/4[z$,z$$];
169 l:=length(z$-z$$);
170 bdir:=angle(z$-z$$);
171 %% z$sio=z$si shifted (w*l*dir(bdir+90));
172 %% z$siio=z$sii shifted (w*l*dir(bdir-90));
173 z$sio=z$si shifted (w*l*dir(bdir-90));
174 z$siio=z$sii shifted (w*l*dir(bdir+90));
175 draw z$..z$sio..z$siio..z$$; % the squiggle
176 %% draw_serif($,$$,fr);
177 %% draw_serif($$,$,fr);
178 labels($sio,$siio);
179 enddef; % end of draw_squiggle
180
181
182 def draw_serif(suffix $, $$)(expr fr)=
183 numeric beta, ajut, bjut;
184 beta=1-fr;
185 ajut=fr*jut; bjut=beta*jut;
186 pair vec[]; vec1=unitvector(z$$-z$);
187 vec2=ajut*vec1;
188 z$a=z$ shifted vec2;
189 z$b=z$a rotatedaround (z$,-90);
190 boolean top_serif;
191 if y$>y$$:
192 top_serif := true;
193 z$c=z$b shifted (-bjut*pdir);
194 else:
195 if y$=y$$:
196 if x$<x$$:
197 top_serif := true;
198 z$c=z$b shifted (-bjut*pdir);
199 else:
200 top_serif := false;
201 z$c=z$b shifted (bjut*pdir);
202 fi
203 else:
204 top_serif:=false;
205 z$c=z$b shifted (bjut*pdir);
206 fi
207 fi
208 if top_serif:
209 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
210 else:
211 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
212 fi
213 labels($a,$b,$c);
214 enddef; % end of draw_serif
215
216
217 def draw_istem(suffix $, $$)(expr fr)=
218 draw_serif($, $$, fr); % top serif
219 draw_serif($$, $, fr); % bottom serif
220 draw z$a--z$$a; % the stem
221 enddef; % end of draw_istem
222
223
224 def draw_tlserif(suffix $, $$)(expr fr)=
225 draw_serif($, $$, fr); % the serif
226 draw z$a--z$$; % the stem
227 enddef; % end of draw_tlserif
228
229
230 def draw_pdot(suffix $)(expr sz)=
231 z$s = z$ shifted (0.5sz*left);
232 z$t = z$ shifted (0.5sz*up);
233 z$u = z$s shifted (sz*right);
234 z$v = z$t shifted (sz*down);
235 pickup stylus;
236 filldraw z$s--z$t--z$u--z$v--cycle;
237 labels($s,$t,$u,$v);
238 enddef; % end of draw_pdot
239
240
241 def draw_pcomma(suffix $)(expr sz, ar)=
242 z$s = z$ shifted (0.5sz*left);
243 z$t = z$s shifted (sz*right);
244 x$v=x$s-ar; y$v=y$s-ar;
245 z$u = z$v shifted (sz*right);
246 pickup stylus;
247 filldraw z$s--z$t--z$u--z$v--cycle;
248 labels($s,$t,$u,$v);
249 enddef; % end of draw_pcomma
250
251
252 def draw_plq(suffix $)(expr sz, ar)=
253 z$s = z$ shifted (0.5sz*left);
254 z$t = z$s shifted (sz*right);
255 x$v=x$s+ar; y$v=y$s-ar;
256 z$u = z$v shifted (sz*right);
257 pickup stylus;
258 filldraw z$s--z$t--z$u--z$v--cycle;
259 labels($s,$t,$u,$v);
260 enddef; % end of draw_plq
261
262
263 font_coding_scheme:="ASCII minuscules and punctuation";
264 mode_setup;
265 rustic_font_setup;
266
267
268 input rustl; % normal letters
269 input rustu; % capital letters
270 input rustdig; % arabic digits
271 input rustpunct; % punctuation
272 input rustlig; % the several dashes
273 %%%%input rustp; % ampersand and ?mark
274
275
276 font_slant slant; font_x_height x_height#;
277 if monospace: font_normal_space 9u#; % no stretching or shrinking
278 font_quad 18u#;
279 font_extra_space 9u#;
280 else: font_normal_space 6u#+2letter_fit#;
281 font_normal_stretch 3u#; font_normal_shrink 2u#;
282 font_quad 18u#+4letter_fit#;
283 font_extra_space 2u#;
284 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
285 %% ligtable "P": "T": "Y": "A" kern kk#;
286 %% ligtable "F": "V": "W": "A" kern if serifs: kkk# else: kk#fi,
287 %% "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
288 %% ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
289 %% "V" kern k#, "Y" kern k#;
290 %% ligtable "A": if serifs: "R": fi
291 %% "C" kern k#, "O" kern k#, "G" kern k#, "U" kern k#, "Q" kern k#,
292 %% "L": "T" kern kk#, "Y" kern kkk#, "V" kern kk#, "W" kern kkk#;
293 %%ligtable "I": "I" kern -k#; % Richard III
294 fi
295
296 bye.
297