Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/tgothpunct.mf

raw
1 %%
2 %% This is file `tgothpunct.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% tgothic.dtx (with options: `punct')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19
20 cmchar "Exclamation mark";
21 beginchar("!", 2sb#+hstretch*(thick#+trijut#),
22 asc_height#, 0);
23 adjust_fit(0,0);
24 pcshiftx := sb;
25 pickup quill;
26 x1=w/2; top y1 = h;
27 z3=(x1, 1/2dot_size);
28 z2=(x1, y3+3/2dot_size);
29 draw z1--z2;
30 draw_pdot(3,dot_size);
31 penlabels(1,2,3);
32
33 endchar; % end of "!"
34
35
36 cmchar "Question mark";
37 beginchar("?", 2sb#+hstretch*((3+wided+widedmin)*stem_width#),
38 asc_height#, 0);
39 adjust_fit(0,0);
40 pcshiftx := sb;
41 numeric n[];
42 path pth[];
43 pickup quill;
44 n1 := w-2pcshiftx; % actual character width
45 n2 := 1/3h; % height of top bowl
46 n3 := n2; % height of bottom bowl
47 z5=(1/2w,1/2dot_size);
48 x45 = x5; y45=y5+3/2dot_size;
49 lft x1 = pcshiftx; y1 = 3/4h;
50 x2 = 1/2w; top y2 = h;
51 rt x3 = w-pcshiftx; y3 = 11/16h;
52
53 x4 = x45;
54 (z3-z4) = whatever*pdir;
55
56 %%ductus:= true;
57 if ductus:
58 pickup stylus;
59 fi
60 %%draw z1..z2{right}..z3{down}..z4{down};
61 draw z1--z2--z3--z4--z45;
62 draw_pdot(5, dot_size);
63 penlabels(1,2,3,4,45,5);
64 endchar; % end of "?"
65
66
67 cmchar "Comma";
68 beginchar(",",2sb#+hstretch*(comma_width#+dot_size#),x_height#,0);
69 adjust_fit(0,0);
70 pcshiftx:=sb;
71 x1=w-pcshiftx-(0.5hstretch*dot_size); y1=1/2dot_size;
72 draw_pcomma(1,dot_size,comma_width);
73 penlabels(1);
74 endchar; % end of ","
75
76
77 cmchar "Period";
78 beginchar(".",2sb#+hstretch*(dot_size#),x_height#,0);
79 pcshiftx:=sb;
80 z1=(w/2, 1/2dot_size);
81 draw_pdot(1,dot_size);
82 penlabels(1);
83 endchar; % end of "."
84
85
86 cmchar "Colon";
87 beginchar(":",2sb#+hstretch*(dot_size#),x_height#,0);
88 pcshiftx:=sb;
89 x1=x2=w/2; y1=3/4h; y2=1/4h;
90 draw_pdot(1,dot_size);
91 draw_pdot(2,dot_size);
92 penlabels(1,2);
93 endchar; % end ":"
94
95
96 cmchar "Semicolon";
97 beginchar(";",2sb#+hstretch*(comma_width#+dot_size#),x_height#,0);
98 adjust_fit(0,0);
99 pcshiftx:=sb;
100 x1=x2=w-pcshiftx-(0.5hstretch*dot_size); y1=3/4h; y2=1/2dot_size;
101 draw_pdot(1,dot_size);
102 draw_pcomma(2,dot_size,comma_width);
103 penlabels(1,2);
104 endchar; % end of ";"
105
106
107 cmchar "Apostrophe";
108 beginchar("'",2sb#+hstretch*(comma_width#+dot_size#),4/3x_height#,0);
109 adjust_fit(0,0);
110 pcshiftx:=sb;
111 x1=w-pcshiftx-(0.5hstretch*dot_size); y1=h;
112 draw_pcomma(1,dot_size,comma_width);
113 penlabels(1);
114 endchar; % end of "'"
115
116
117 cmchar "Reverse apostrophe";
118 beginchar("`",2sb#+hstretch*(comma_width#+dot_size#),4/3x_height#,0);
119 adjust_fit(0,0);
120 pcshiftx:=sb;
121 x1=pcshiftx+(0.5hstretch*dot_size); y1=h;
122 draw_plq(1,dot_size,comma_width);
123 penlabels(1);
124 endchar; % end of "`"
125