Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/imajdig.mf

raw
1 %%
2 %% This is file `imajdig.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% inslrmaj.dtx (with options: `dig')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19 cmchar "IMAJ digit 1";
20 beginchar("1", 2sb#+fig_width#, fig_height#, 0);
21 adjust_fit(0,0);
22 pcshiftx := sb;
23 pickup quill;
24 x1=x2=w/2;
25 y1=h; bot y2=0;
26 %%ductus:=true;
27 if ductus:
28 pickup stylus;
29 fi
30 draw_tstem(1,2,srad);
31 draw_triserif(1,trijut);
32 ductus:=false;
33 penlabels(1,2,100);
34 endchar; % end "1"
35
36 cmchar "IMAJ digit 2";
37 beginchar("2", 2sb#+fig_width#, fig_height#, 0);
38 adjust_fit(0,0);
39 pcshiftx := sb;
40 pickup quill;
41 %% stem
42 lft x1=pcshiftx+o; top y1=h-2thin;
43 x2=1/2w; top y2= h+o;
44 rt x3=w-pcshiftx-o; y3=3/4h;
45 %% foot
46 lft x5=pcshiftx; bot y5=0;
47 rt x6=w-pcshiftx; y6=y5;
48 %%ductus:=true;
49 if ductus:
50 pickup stylus;
51 fi
52 draw z1..z2{right}..z3{down}..{down}z5; % curve
53 draw z5--z6; % foot
54 draw_utriangle(6,thick);
55 ductus:=false;
56 penlabels(1,2,3,4,5,6,100);
57 endchar; % end "2"
58
59 cmchar "IMAJ digit 3";
60 beginchar("3", 2sb#+fig_width#, fig_height#, 0);
61 adjust_fit(0,0);
62 pcshiftx := sb;
63 pickup quill;
64 %% x values
65 lft x3=pcshiftx; x10=x3;
66 rt x5=w-pcshiftx; x8=x5-3thin;
67 x4=0.5[x3,x5];
68 x9=0.5[x10,x8];
69 lft x6=pcshiftx+3thin; x7=x6;
70 %% y values
71 bot y3=thin; top y10=h-2thin;
72 y6=0.5[y3,y10]; y7=y6;
73 bot y4=-thin; top y9=h+thin;
74 y5=0.5[y3,y6];
75 y8=11/12[y7,y10];
76 %%ductus:=true;
77 if ductus:
78 pickup stylus;
79 fi
80 draw z3..z4{right}..z5{up}...{-pdir}z6; % bottom bowl
81 draw z7{pdir}...z8{up}..z9{left}..z10; % top bowl
82 ductus:=false;
83 penlabels(1,2,3,4,5,6,7,8,9,10,100);
84 endchar; % end "3"
85
86 cmchar "IMAJ digit 4";
87 beginchar("4", 2sb#+fig_width#, fig_height#, 0);
88 adjust_fit(0,0);
89 pcshiftx := sb;
90 pickup quill;
91 %% the stem
92 x1=x2=w-pcshiftx-jut;
93 y1=h; bot y2=0;
94 %% the crossbar
95 lft x3=pcshiftx; y3=0.33h;
96 rt x4=w-pcshiftx; y4=y3;
97 %% the diagonal
98 lft x5=pcshiftx+jut; y5=h;
99 x6=x5; y6=y4;
100 %%ductus:=true;
101 if ductus:
102 pickup stylus;
103 fi
104 draw_tstem(1,2,srad); % main stem
105 %%draw_clubbase(1, 2, 1/3, 0, clubjut);
106 draw z3--z4; % crossbar
107 draw z3{(1,1)}..{(1,1)}z1; % diagonal
108 ductus:=false;
109 penlabels(1,2,3,4,100);
110 endchar; % end "4"
111
112 cmchar "IMAJ digit 5";
113 beginchar("5", 2sb#+fig_width#, fig_height#, 0);
114 adjust_fit(0,0);
115 numeric n[];
116 pcshiftx := sb;
117 pickup quill;
118 %% for the top
119 rt x1=w-pcshiftx; top y1=h;
120 lft x2=pcshiftx; y2=y1;
121 z2'=(lft x2, top y2); z2''=(rt x2, y2');
122 z0'=(x2', 0); z0''=(x2'', 0);
123 %% bowl
124 n1 := w-2pcshiftx+4/3thick; % width of bowl
125 n2 := 2/3h; % height of bowl
126 z3=(w-pcshiftx-n1, 0);
127 obowl(3, n1, n2);
128 z10o = (z2''--z0'') intersectionpoint subpath (3,4) of obouter;
129 z10i = (z2'--z0') intersectionpoint subpath (3,4) of obinner;
130 z10'=(x10i,y10o);
131 z20o = (z2'--z0') intersectionpoint subpath (2,3) of obouter;
132 z20i = (z2'--z0') intersectionpoint subpath (2,3) of obinner;
133 %%ductus:=true;
134 if ductus:
135 pickup stylus;
136 draw z2--z1; draw z2'--z0'; draw z2''--z0'';
137 draw obouter; draw obinner;
138 else:
139 draw z2--z1; % top bar
140 draw_triangle(1,thick);
141 fill z2'--z10i--z10o--z2''--cycle; % stem
142 fill z10o..z3minlo{pdir}..z3maxro{-ppdir}..z3minro{-pdir}..z20o--
143 z20i..z3minri{pdir}..z3maxri{ppdir}..z3minli{-pdir}..z10i--
144 z10'--cycle;
145 fi
146 ductus:=false;
147 penlabels(1,2,3,4,5,6,7,100);
148 endchar; % end "5"
149
150 cmchar "IMAJ digit 6";
151 beginchar("6", 2sb#+fig_width#, fig_height#, 0);
152 adjust_fit(0,0);
153 numeric n[];
154 path pth[];
155 pcshiftx := sb;
156 pickup quill;
157 n1 := w-2pcshiftx; % width of character
158 n2 := h; % height of character
159 %% main bowl
160 z3=(w-pcshiftx-n1,0);
161 obowl(3, n1, n2);
162 pth1 := obouter; pth2 := obinner;
163 z0 = (0,0); z0'=(w,h);
164 z10o' = (z0--z0') intersectionpoint subpath (0,1) of pth1;
165 z10i' = (z0--z0') intersectionpoint subpath (0,1) of pth2;
166 n0 := w-pcshiftx-x10o';
167 z10o=(x10o'+n0, y10o');
168 z10i=(x10i'+n0, y10i');
169 %% bottom bowl
170 n3 := 16/12n2; % width
171 n4 := 2/3n2; % height
172 z13=(w-pcshiftx-n3, 0);
173 obowl(13, n3, n4);
174 pth11 := obouter; pth12 := obinner;
175 z20o = subpath (2,4) of pth2 intersectionpoint
176 (subpath (3,4) of pth11 & subpath (0,1) of pth11);
177 z20i = subpath (2,4) of pth2 intersectionpoint
178 (subpath (3,4) of pth12 & subpath (0,1) of pth12);
179 %%ductus:=true;
180 if ductus:
181 pickup stylus;
182 draw subpath (2,4) of pth2;
183 draw (subpath (3,4) of pth11 & subpath (0,1) of pth11);
184 draw (subpath (3,4) of pth12 & subpath (0,1) of pth12);
185 else:
186 fill z10o..z3minlo{-pdir}..z3maxlo{-ppdir}..z3minro{pdir}..
187 z13maxro{ppdir}..{-pdir}z20o--z20i{pdir}..z13maxri{-ppdir}..
188 z3minri{-pdir}..z3maxli{ppdir}..z3minli{pdir}..z10i--
189 cycle;
190 fi
191 ductus:=false;
192 penlabels(1,2,3,4,5,6,8,100);
193 endchar; % end "6"
194
195 cmchar "IMAJ digit 7";
196 beginchar("7", 2sb#+fig_width#, fig_height#, 0);
197 adjust_fit(0,0);
198 pcshiftx := sb;
199 pickup quill;
200 %% top bar
201 lft x1=pcshiftx;
202 rt x2=w-pcshiftx;
203 top y1=top y2=h;
204 x8=pcshiftx+3/8jut; y8=h-0.5thin;
205 %% bowed leg
206 x4=w/2; bot y4=0;
207 x3=0.5[x2,x4]-3thin; y3=0.5[y2,y4];
208 %%ductus:=true;
209 if ductus:
210 pickup stylus;
211 fi
212 draw z1--z2; % top bar
213 draw_triangle(1,thick);
214 draw z2..z3..z4; % leg
215 ductus:=false;
216 penlabels(1,2,3,4,5,6,7,8,100);
217 endchar; % end "7"
218
219 cmchar "IMAJ digit 8";
220 beginchar("8", 2sb#+fig_width#, fig_height#, 0);
221 adjust_fit(0,0);
222 pcshiftx := sb;
223 numeric alpha; alpha:=1;
224 pickup quill;
225 lft x1=alpha*pcshiftx+o; rt x3=w-alpha*pcshiftx-o; y1=y3=3/4h;
226 x2=x4=w/2; top y2=h+o; bot y4=-o;
227 x5=x2; y5=h/2+2o;
228 lft x11=pcshiftx; rt x13=w-pcshiftx; y11=y13=1/4h;
229 %%ductus:=true;
230 if ductus:
231 pickup stylus;
232 fi
233 draw z1..z2..z3..z5..z11..z4..z13..z5..cycle;
234 ductus:=false;
235 penlabels(1,2,3,4,5,11,13,100);
236 endchar; % end "8"
237
238 cmchar "IMAJ digit 9";
239 beginchar("9", 2sb#+fig_width#, fig_height#, 0);
240 adjust_fit(0,0);
241 numeric n[];
242 path pth[];
243 pcshiftx := sb;
244 pickup quill;
245 n1 := w-2pcshiftx; % width of character
246 n2 := h; % height of character
247 %% main bowl
248 z3=(w-pcshiftx-n1,0);
249 obowl(3, n1, n2);
250 pth1 := obouter; pth2 := obinner;
251 z0=(0,0); z0'=(w,h);
252 z20o' = (z0--z0') intersectionpoint subpath (2,3) of pth1;
253 z20i' = (z0--z0') intersectionpoint subpath (2,3) of pth2;
254 n0 := x20o'-pcshiftx;
255 z20o=(x20o'-n0, y20o');
256 z20i=(x20i'-n0, y20i');
257 %% bottom bowl
258 n3 := 16/12n2; % width
259 n4 := 2/3n2; % height
260 z13=(pcshiftx,h-n4);
261 obowl(13, n3, n4);
262 pth11 := obouter; pth12 := obinner;
263 z10o = subpath (0,2) of pth2 intersectionpoint subpath (1,3) of pth11;
264 z10i = subpath (0,2) of pth2 intersectionpoint subpath (1,3) of pth12;
265 %%ductus:=true;
266 if ductus:
267 pickup stylus;
268 draw subpath (0,2) of pth2;
269 draw subpath (1,3) of pth11;
270 draw subpath (1,3) of pth12;
271 else:
272 fill z20o..z3minro{pdir}..z3maxro{ppdir}..z3minlo{-pdir}..
273 z13maxlo{-ppdir}..{pdir}z10o--z10i{-pdir}..z13maxli{ppdir}..
274 z3minli{pdir}..z3maxri{-ppdir}..z3minri{-pdir}..z20i--
275 cycle;
276 fi
277 ductus:=false;
278 penlabels(1,2,3,4,5,6,100);
279 endchar; % end "9"
280
281 cmchar "Uncial digit 0";
282 beginchar("0", 2sb#+fig_width#, fig_height#, 0);
283 adjust_fit(0,0);
284 numeric n[];
285 pcshiftx := sb;
286 pickup quill;
287 n1 := w-2pcshiftx; % bowl width
288 n2 := h+2o; % bowl height
289 z1=(pcshiftx,-o);
290 obowl(1, n1, n2);
291 %%ductus:=true;
292 if ductus:
293 pickup stylus;
294 fi
295 fill obouter; unfill obinner;
296 ductus:=false;
297 %%%proofpcbb(100, y100, y100);
298 penlabels(1,2,3,4,100);
299 endchar; % end "0"
300