Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/egothu.mf

raw
1 %%
2 %% This is file `egothu.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% egothic.dtx (with options: `maj')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19 cmchar "EGOTH letter A";
20 beginchar("A", 2cap_sb#+caprat*hstretch*(14/13x_height#),
21 caprat*x_height#, 0);
22 adjust_fit(0,0);
23 pcshiftx := cap_sb;
24 numeric n[];
25 path pth[];
26 pair pr[];
27 pickup capquill;
28 x100 = 0;
29 n1 := sqrcjut;
30 n2 := sqrcjutrat*sqrcjut;
31 %% legs
32 x1 = 6/16w; top y1=h;
33 rt x3 = w-pcshiftx - n1; bot y3= 0;
34 pickup capthinquill;
35 lft x2 = pcshiftx; bot y2 = 0;
36 x21 = x2 + n2; y21 = y2;
37 y22 = y21+n2; z22 = whatever[z2,z1];
38 pickup capquill;
39 %%ductus:=true;
40 if ductus:
41 pickup stylus;
42 fi
43 draw z1--z3; draw (x1-n1,y1)--(x1,y1); draw (x3,y3)--(x3+n1,y3); %% right leg
44 pickup capthinquill;
45 draw z1--z2; %% left leg
46 filldraw z2--z21{left}..{z1-z2}z22--cycle;
47 ductus:=false;
48 penlabels(1,2,3,4,5,6,7,8,11,12,13,14,15,100);
49 endchar; % end "A"
50
51 cmchar "EGOTH letter B";
52 beginchar("B", 2cap_sb#+caprat*hstretch*(14/13x_height#),
53 caprat*x_height#, 0);
54 adjust_fit(0,0);
55 numeric n[];
56 path pth[];
57 pcshiftx := cap_sb;
58 pickup capquill;
59 x100 = 0;
60 n1 := sqrcjut;
61 %% stem
62 lft x1 = pcshiftx + n1; top y1 = h;
63 x2 = x1; bot y2 = 0;
64 z12 = 1/2[z1,z2];
65 %% bottom bowl
66 lft x21 = pcshiftx; bot y21 = 0;
67 z22=z2;
68 lft x27 = rt x12; y27 = y12;
69 rt x25 = w-pcshiftx; y25 = 1/2[y22,y27];
70 pth1 := z21--z22{right}..z25{up}..{left}z27;
71 %% top bowl
72 z32 = z27; z37 = z1;
73 x38 = x21; y38 = y37;
74 rt x35 = x25; y35 = 1/2[y32,y37];
75 pth2 := z38--z37{right}..z35{down}..{left}z27;
76 if ductus:
77 pickup stylus;
78 fi
79 draw z1--z2;
80 draw pth1; draw pth2;
81 ductus:=false;
82 penlabels(1,2,3,4,5,6,7,8,9,100);
83 endchar; % end "B"
84
85 cmchar "EGOTH letter C";
86 beginchar("C", 2cap_sb#+caprat*hstretch*(14/13x_height#),
87 caprat*x_height#, 0);
88 adjust_fit(0,0);
89 numeric n[];
90 pcshiftx := cap_sb;
91 pickup capquill;
92 n1:=w-2pcshiftx; % actual letter width
93 n2:=6/5w-2pcshiftx; % width of full bowl
94 x1=pcshiftx + 1/2n1; top y1 = h;
95 lft x2 = pcshiftx; y2 = 1/2h;
96 x3 = x1; bot y3 = 0;
97 rt x4 = w-pcshiftx; y4 = 1/4h;
98 x24 = x4; y24 = 3/4h;
99 %%ductus:=true;
100 if ductus:
101 pickup stylus;
102 fi
103 draw z24..z1{left}..z2{down}..z3{right}..z4{3pdir};
104 ductus:=false;
105 penlabels(1,2,3,4,5,6,14,16,17,18,100);
106 endchar; % end "C"
107
108 cmchar "EGOTH letter D";
109 beginchar("D", 2cap_sb#+caprat*hstretch*(14/13x_height#),
110 caprat*x_height#, 0);
111 adjust_fit(0,0);
112 numeric n[];
113 path pth[];
114 pcshiftx := cap_sb;
115 pickup capquill;
116 x100 = 0; n1 := rt x100 - lft x100;
117 %% stem
118 lft x1 = pcshiftx+sqrcjut; top y1=h;
119 x2 = x1; bot y2 = 0;
120 %% bowl
121 lft x3 = pcshiftx; y3 = y1;
122 z7 = (x3,y2);
123 rt x5 = w-pcshiftx; y5 = 1/2[y3,y7];
124 pth1 := z3--z1{right}..{down}z5..{left}z2--z7;
125 if ductus:
126 pickup stylus;
127 fi
128 draw z1--z2; %% stem
129 draw pth1;
130 ductus:=false;
131 penlabels(0,1,2,3,4,5,6,7,8,100);
132 endchar; % end "D"
133
134 cmchar "EGOTH letter E";
135 beginchar("E", cap_sb#+caprat*hstretch*(9/13x_height#),
136 caprat*x_height#, 0);
137 adjust_fit(0,0);
138 pcshiftx := cap_sb;
139 numeric n[];
140 path pth[];
141 pickup capquill;
142 x100 = 0;
143 n1 = rt x100 - lft x100;
144 %% stem
145 lft x1 = pcshiftx+sqrcjut; top y1 = h;
146 x2 = x1; bot y2=0;
147 %% bars
148 lft x3 = pcshiftx; y3 = y1; rt x4 = w-pcshiftx; y4=y3;
149 x5=x1; y5 = 6/16[y1,y2]; x6 = x4; y6 = y5;
150 x7 = x3; y7 = y2; x8 = x4; y8=y7;
151 %%ductus:=true;
152 if ductus:
153 pickup stylus;
154 fi
155 draw z1--z2; % stem
156 draw z3--z4; draw z5--z6; draw z7--z8;
157 ductus:=false;
158 penlabels(1,2,3,4,5,6,7,8,9,17,70,100);
159 endchar; % end "E"
160
161 cmchar "EGOTH letter F";
162 beginchar("F", 2cap_sb#+caprat*hstretch*(9/13x_height#),
163 caprat*x_height#, 0);
164 adjust_fit(0,0);
165 numeric n[];
166 pcshiftx := cap_sb;
167 pickup capquill;
168 x100 = 0;
169 n1 := rt x100 - lft x100;
170 %% stem
171 lft x1=lft x2=pcshiftx+sqrcjut; bot y1=h; bot y2=0;
172 %% bars
173 lft x3 = pcshiftx; y3 = y1; rt x4 = w-pcshiftx; y4 = y3;
174 x5=x1; y5 = 6/16[y1,y2]; x6 = x4; y6 = y5;
175 %%ductus:=true;
176 if ductus:
177 pickup stylus;
178 fi
179 draw z1--z2;
180 draw z3--z4; draw z5--z6;
181 ductus:=false;
182 penlabels(1,2,3,4,5,6,7,14,15,16,100);
183 endchar; % end "F"
184
185 cmchar "EGOTH letter G";
186 beginchar("G", 2cap_sb#+caprat*hstretch*(14/13x_height#),
187 caprat*x_height#, 0);
188 adjust_fit(0,0);
189 path pth[];
190 pair vec[];
191 numeric n[];
192 pcshiftx := cap_sb;
193 pickup capquill;
194 x100 = 0;
195 n1 := sqrcjut;
196 %% bar
197 rt x52 = w - pcshiftx; y52 = 1/2h;
198 x51 = x52 - 2n1; y51 = y52;
199 z512 = 1/2[z51,z52];
200 x54=x512; bot y54 = 0;
201 %% bowl
202 lft x2 = pcshiftx; y2 = 1/2h;
203 x4 = x512; y4 = 1/4h;
204 x3 = x1 = 1/2[x2,x4]; bot y3 = 0; top y1 = h;
205 x24 = x512; y24 = 3/4h;
206 pth1 := z24..z1{left}..z2{down}..z3{right}..z4;
207 %%ductus:=true;
208 if ductus:
209 pickup stylus;
210 fi
211 draw pth1;
212 %%draw z4--z512; draw z51--z52;
213 draw z512--z54; draw (x512-n1,y512)--(x512,y512);
214 ductus:=false;
215 penlabels(1,2,3,4,5,6,7,8,9,11,12,13,24,31,32,33,34,35,36,51,52,512,100);
216 endchar; % end "G"
217
218 cmchar "EGOTH letter H";
219 beginchar("H", 2cap_sb#+caprat*hstretch*(14/13x_height#),
220 caprat*x_height#, 0);
221 adjust_fit(0,0);
222 pcshiftx := cap_sb;
223 pickup capquill;
224 numeric n[];
225 x100 = 0;
226 n1 := sqrcjut;
227 %% stems
228 lft x1=lft x2=pcshiftx+sqrcjut;
229 top y1=h; bot y2=0;
230 rt x3 = w - pcshiftx - sqrcjut; x4 = x3; y3 = y1; y4 = y2;
231 %% bar
232 z12 = 7/16[z1,z2]; z34 = 7/16[z3,z4];
233 %%ductus:=true;
234 if ductus:
235 pickup stylus;
236 fi
237 draw z1--z2; draw z3--z4; draw z12--z34;
238 %% serifs
239 draw (x1-n1,y1)--(x1,y1); draw (x2,y2)--(x2+n1,y2);
240 draw (x3-n1,y3)--(x3,y3); draw (x4,y4)--(x4+n1,y4);
241 ductus:=false;
242 penlabels(1,2,3,4,5,6,100);
243 endchar; % end "H"
244
245 cmchar "EGOTH letter I";
246 beginchar("I", 2cap_sb#+caprat*hstretch*(thick#+2sqrcjut#),
247 caprat*x_height#, 0);
248 adjust_fit(0,0);
249 pcshiftx := cap_sb;
250 numeric n[];
251 pickup capquill;
252 x100 = 0;
253 n1 := rt x100 - lft x100;
254 x1 = x2 = 1/2w;
255 top y1=h; bot y2=0;
256 %% serifs
257 lft x111 = pcshiftx; rt x112 = w-pcshiftx;
258 x211 = x111; x212 = x112;
259 draw z1--z2;
260 %% serifs
261 draw (x111,y1)--(x112,y1);
262 draw (x211,y2)--(x212,y2);
263 ductus:=false;
264 penlabels(1,2,100);
265 endchar; % end "I"
266
267 cmchar "EGOTH letter J";
268 beginchar("J", 2cap_sb#+caprat*hstretch*(2thick#+sqrcjut#),
269 caprat*x_height#, 0);
270 adjust_fit(0,0);
271 pcshiftx := cap_sb;
272 path pth[];
273 numeric n[];
274 pickup capquill;
275 x100 = 0;
276 n1 := sqrcjut;
277 %% stem
278 rt x1 = w-pcshiftx; top y1 = h;
279 x2 = x1; y2 = 1/4h;
280 %% hook
281 lft x4 = pcshiftx; bot y4 = 0;
282 pth1 := z4{pdir}..z2{up};
283 %%ductus:=true;
284 if ductus:
285 pickup stylus;
286 fi
287 draw z1--z2{down}..{-pdir}z4; % stem & hook
288 draw (x1-n1,y1)--z1;
289 ductus:=false;
290 penlabels(1,2,3,100);
291 endchar; % end "J"
292
293 cmchar "EGOTH letter K";
294 beginchar("K", 2cap_sb#+caprat*hstretch*(16/13x_height#),
295 caprat*x_height#, 0);
296 adjust_fit(0,0);
297 pcshiftx := cap_sb;
298 path pth[];
299 numeric n[];
300 pickup capquill;
301 x100 = 0;
302 n1 := sqrcjut;
303 %% stem
304 lft x1 = pcshiftx+n1; top y1 = h;
305 x2 = x1; bot y2 = 0;
306 z12 = 1/2[z1,z2];
307 %% top arm
308 x3 = rt x12; y3 = y12;
309 x5 = 1/2[w - pcshiftx, x1]; y5 = y1;
310 %%pth1 := z3{pdir}..{up}z5;
311 pth1 := z3--z5;
312 %% lower arm
313 z7 = z3;
314 rt x9 = w-pcshiftx; bot y9 = 0;
315 pth2 := z7{-ppdir}..{right}z9;
316 pickup capquill;
317 %%ductus:=true;
318 if ductus:
319 pickup stylus;
320 fi
321 draw z1--z2; draw pth1; draw pth2;
322 draw (x1-n1,y1)--(x1,y1);
323 draw (x2-n1,y2)--(x2+n1,y2);
324 draw (x5,y5)--(x5+n1,y5);
325 ductus:=false;
326 penlabels(1,2,3,4,5,6,7,8,9,13,14,100);
327 endchar; % end "K"
328
329 cmchar "EGOTH letter L";
330 beginchar("L", 2cap_sb#+caprat*hstretch*(9/13x_height#),
331 caprat*x_height#, 0);
332 adjust_fit(0,0);
333 pcshiftx := cap_sb;
334 numeric n[];
335 pickup capquill;
336 x100 = 0;
337 n1 := sqrcjut;
338 lft x1=pcshiftx+n1; bot y1=h;
339 x2=x1; bot y2 =0;
340 x3 = x2; rt x4 = w-pcshiftx; y3 = y4 = y2;
341 %%ductus:=true;
342 if ductus:
343 pickup stylus;
344 fi
345 draw z1--z2; draw z3--z4;
346 draw (x1-n1,y1)--(x1,y1);
347 ductus:=false;
348 penlabels(1,2,3,4,100);
349 endchar; % end "L"
350
351 cmchar "EGOTH letter M";
352 beginchar("M", 2cap_sb#+caprat*hstretch*(19/13x_height#),
353 caprat*x_height#, 0);
354 adjust_fit(0,0);
355 pcshiftx := cap_sb;
356 numeric n[];
357 path pth[];
358 pickup capquill;
359 x100 = 0;
360 n1 := sqrcjut;
361 n2 := sqrcjutrat*sqrcjut;
362 %% thick stem tops
363 lft x1=pcshiftx+n1; top y1=h;
364 rt x3 = w - pcshiftx -2n1; y3 = y1;
365 %% right stem bottom
366 rt x4 = w - pcshiftx - n1; bot y4 = 0;
367 %% the V
368 x24 = 1/2w; bot y24 = 0;
369 %% left stem top and bottom
370 x81 = lft x1; y81 = top y1;
371 pickup capthinquill;
372 lft x11 = x81; top y11 = y81;
373 lft x2 = pcshiftx; bot y2 = 0;
374 x2a = x2+n2; y2a = y2;
375 y2b = y2+n2; z2b = whatever[z2,z11];
376 pickup capquill;
377 %% thin middle top and bottom
378 x83 = lft x3; y83 = top y3;
379 x824 = rt x24; y824 = bot y24;
380 pickup capthinquill;
381 lft x13 = x83; top y13 = y83;
382 rt x124 = x824; bot y124 = y824;
383 pickup capquill;
384 pth124 := z1{-ppdir}..z24;
385 pth34 := z3{down}..z4;
386 %%ductus:=true;
387 if ductus:
388 pickup stylus;
389 fi
390 %% thick legs
391 draw pth124; draw pth34;
392 draw (x1-n1,y1)--(x1,y1); draw (x3-n1,y3)--(x3,y3); draw (x4,y4)--(x4+n1,y4);
393 %% thin legs
394 pickup capthinquill;
395 draw z11--z2;
396 filldraw z2--z2a{left}..{z11-z2}z2b--cycle;
397 %%%%pickup quarterquill;
398 draw z13--z124;
399 ductus:=false;
400 penlabels(1,2,3,4,5,6,7,8,9,13,14,33,34,100);
401 endchar; % end "M"
402
403 cmchar "EGOTH letter N";
404 beginchar("N", 2cap_sb#+caprat*hstretch*(14/13x_height#),
405 caprat*x_height#, 0);
406 adjust_fit(0,0);
407 pcshiftx := cap_sb;
408 path pth[];
409 numeric n[];
410 pickup capquill;
411 x100 = 0;
412 n1 := sqrcjut;
413 n2 := sqrcjutrat*sqrcjut;
414 %% diagonal
415 lft x1=pcshiftx+n1; top y1=h;
416 rt x4 = w -pcshiftx-n1; bot y4 = 0;
417 x101 = lft x1;
418 x104 = rt x4;
419 pth1 := z1{-ppdir}..z4;
420 %% stems
421 pickup capthinquill;
422 lft x21 = x101; top y21 =h;
423 x22 = x21; bot y22 = 0;
424 x22a = x22+n2; y22a=y22;
425 x22b = x22; y22b=y22+n2;
426 rt x24 = x104; bot y24 = 0;
427 x23 = x24; top y23 = h;
428 x23a = x23-n2; x23b = x23+n1; y23a = y23b = y23;
429 x23c = x23; y23c = y23-n2;
430 pickup capquill;
431 %%ductus:=true;
432 if ductus:
433 pickup stylus;
434 fi
435 %% diagonal
436 draw pth1; draw (x1-n1,y1)--(x1,y1);
437 %% stems
438 pickup capthinquill;
439 draw z21--z22;
440 filldraw z22--z22a{left}..{up}z22b--cycle;
441 draw z23--z24;
442 filldraw z23--z23a{right}..{down}z23c{up}..{right}z23b--cycle;
443 ductus:=false;
444 penlabels(1,2,3,4,5,6,13,14,23,23a,23b,23c,100);
445 endchar; % end "N"
446
447 cmchar "EGOTH letter O";
448 beginchar("O", 2cap_sb#+caprat*hstretch*(17/13x_height#),
449 caprat*x_height#, 0);
450 adjust_fit(0,0);
451 pcshiftx := cap_sb;
452 pickup capquill;
453 lft x1=pcshiftx; rt x3=w-pcshiftx; y1=y3=h/2;
454 x2=x4=w/2; top y2=h+o; bot y4=-o;
455 %%ductus:=true;
456 if ductus:
457 pickup stylus;
458 fi
459 draw z1..z2..z3..z4..cycle;
460 ductus:=false;
461 penlabels(1,2,3,4,5,100);
462 endchar; % end "O"
463
464 cmchar "EGOTH letter P";
465 beginchar("P", 2cap_sb#+caprat*hstretch*(13/13x_height#),
466 caprat*x_height#, 0);
467 adjust_fit(0,0);
468 pcshiftx := cap_sb;
469 path pth[];
470 numeric n[];
471 pickup capquill;
472 x100 = 0;
473 n1:= sqrcjut;
474 %% stem
475 lft x1=lft x2=pcshiftx+n1;
476 top y1=h; bot y2=0;
477 z12 = 1/2[z1,z2];
478 %% bowl
479 lft x3 = pcshiftx; y3 = y1;
480 x7 = x12; top y7 = y12;
481 rt x5 = w-pcshiftx; y5 = 1/2[y3,y7];
482 pth1 := z3--z1{right}..z5{down}..{left}z7;
483 %%ductus:=true;
484 if ductus:
485 pickup stylus;
486 fi
487 draw z1--z2; draw pth1;
488 %%draw (x2-n1,y2)--(x2+n1,y2);
489 ductus:=false;
490 penlabels(1,2,3,4,5,6,7,8,100);
491 endchar; % end "P"
492
493 cmchar "EGOTH letter Q";
494 beginchar("Q", 2cap_sb#+caprat*hstretch*(17/13x_height#),
495 caprat*x_height#, 0);
496 adjust_fit(0,0);
497 pcshiftx := cap_sb;
498 numeric n[];
499 path pth[];
500 pickup capquill;
501 %% bowl
502 lft x1=pcshiftx; rt x3=w-pcshiftx; y1=y3=h/2;
503 x2=x4=w/2; top y2=h+o; bot y4=-o;
504 pth1 := z1..z4..z3..z2..cycle;
505 %% tail
506 n1 := rt x1 - lft x1;
507 pth2 := z1..z2..z3..z4;
508 z5 = directionpoint pdir of pth1;
509 x7 = x3 + 2n1; top y7 = -n1;
510 pth3 := z5{-ppdir}..{pdir}z7;
511 %%ductus:=true;
512 if ductus:
513 pickup stylus;
514 fi
515 draw pth1;
516 draw pth3;
517 ductus:=false;
518 penlabels(0,1,2,3,4,5,6,7,8,100);
519 endchar; % end "Q"
520
521 cmchar "EGOTH letter R";
522 beginchar("R", 2cap_sb#+caprat*hstretch*(15/13x_height#),
523 caprat*x_height#, 0);
524 adjust_fit(0,0);
525 pcshiftx := cap_sb;
526 numeric n[];
527 path pth[];
528 pickup capquill;
529 x100 = 0;
530 n1:= sqrcjut;
531 n3 := sqrcjutrat*sqrcjut;
532 n2 := 11/15; %% P/R width ratio
533 %% stem
534 pickup capthinquill;
535 lft x1=lft x2=pcshiftx+n1;
536 top y1=h; bot y2=0;
537 x2a = x2 + n3; y2a = y2;
538 x2b = x2; y2b = y2+n3;
539 z12 = 1/2[z1,z2];
540 pickup capquill;
541 %% bowl
542 lft x3 = pcshiftx; top y3 = h; x13 = x1; y13 = y3;
543 lft x7 = x12; top y7 = y12;
544 rt x5 = w*n2 - pcshiftx; y5 = 1/2[y3,y7];
545 pth1 := z3--z13{right}..z5{down}..{left}z7;
546 %% leg
547 z21 = z7;
548 rt x23 = w-pcshiftx; bot y23 = 0;
549 pth2 := z21{-ppdir}..{right}z23;
550 %%ductus:=true;
551 if ductus:
552 pickup stylus;
553 fi
554 draw pth1; draw pth2;
555 pickup capthinquill;
556 draw z1--z2;
557 filldraw z2--z2a{left}..{up}z2b--cycle;
558 ductus:=false;
559 penlabels(1,2,3,4,5,6,7,8,9,100);
560 endchar; % end "R"
561
562 cmchar "EGOTH letter S";
563 beginchar("S", 2cap_sb#+caprat*hstretch*(15/18x_height#),
564 caprat*x_height#, 0);
565 adjust_fit(0,0);
566 numeric n[];
567 path pth[];
568 pcshiftx := cap_sb;
569 pickup capquill;
570 x100 = 0;
571 n1 := rt x100 - lft x100;
572 x1 = x3 = x5 = 1/2w;
573 top y1 = h; bot y5 = 0; y3 = 1/2[y1,y5];
574 lft x2 = pcshiftx; rt x4 = w-pcshiftx;
575 y2 = 1/2[y1,y3]; y4 = 1/2[y3,y5];
576 rt x101 = w-pcshiftx; top y101 = y1;
577 lft x102 = pcshiftx; bot y102 = y5;
578 pth1 := z101..z1..z2..z3..z4..z5..z102;
579 %%ductus:=true;
580 if ductus:
581 pickup stylus;
582 fi
583 draw pth1;
584 ductus:=false;
585 penlabels(1,2,3,4,5,6,7,11,17,20,26,27,28,100);
586 endchar; % end "S"
587
588 cmchar "EGOTH letter T";
589 beginchar("T", 2cap_sb#+caprat*hstretch*(10/13x_height#),
590 caprat*x_height#, 0);
591 adjust_fit(0,0);
592 pcshiftx := cap_sb;
593 numeric n[];
594 path pth[];
595 pickup capquill;
596 %% bar
597 lft x1 = pcshiftx; rt x2=w-pcshiftx;
598 top y1 = top y2 = h;
599 pth1 := z1{pdir}..{pdir}z2;
600 %% stem
601 z3 = 1/2[z1,z2];
602 x4 = x3; bot y4 = 0;
603 %%ductus:=true;
604 if ductus:
605 pickup stylus;
606 fi
607 draw pth1; % bar
608 draw z3--z4; % stem
609 ductus:=false;
610 penlabels(1,2,3,4,5,6,11,12,100);
611 endchar; % end "T"
612
613 cmchar "EGOTH letter U";
614 beginchar("U", 2cap_sb#+caprat*hstretch*(15/13x_height#),
615 caprat*x_height#, 0);
616 adjust_fit(0,0);
617 pcshiftx := cap_sb;
618 numeric n[];
619 path pth[];
620 pickup capquill;
621 x100 = 0;
622 n1 := sqrcjut;
623 %% left stem
624 lft x1 = pcshiftx + n1; top y1 = h;
625 lft x13=pcshiftx; y13=1/3h;
626 rt x3=w-pcshiftx-n1; y3=y1;
627 x4=x3; bot y4=0;
628 z33=1/4[z4,z3]; % start of bowl
629 x14=1/3[x1,x3]; bot y14=0;
630 pth1 := z1..z13{down}..z14{right}..{pdir}z33;
631 %%ductus:=true;
632 if ductus:
633 pickup stylus;
634 fi
635 draw pth1;
636 draw (x1-n1,y1)--(x1,y1);
637 draw z3--z4;
638 draw (x3-n1,y3)--(x3,y3);
639 draw (x4,y4)--(x4+n1,y4);
640 ductus:=false;
641 penlabels(1,2,3,4,5,6,7,8,9,11,13,14,16,33,100);
642 endchar; % end "U"
643
644 cmchar "EGOTH letter V";
645 beginchar("V", 2cap_sb#+caprat*hstretch*(13/13x_height#),
646 caprat*x_height#, 0);
647 adjust_fit(0,0);
648 pcshiftx := cap_sb;
649 numeric n[];
650 path pth[];
651 pickup capquill;
652 x100 = 0;
653 n1 := sqrcjut;
654 n2 := sqrcjutrat*sqrcjut;
655 %% stem tops
656 lft x1 = pcshiftx + n1; top y1 = h;
657 pickup capthinquill;
658 rt x3 = w - pcshiftx; top y3 = h;
659 x3a = x3-n2; y3a=y3;
660 x3b = x3; y3b = y3-n2;
661 pickup capquill;
662 %% bottom
663 x13 = 10/16[x1,x3]; bot y13 = 0;
664 x83 = rt x13; y83 = top y13;
665 pth1 := z1{down}..z13;
666 pth2 := z3{down}..z83;
667 %%ductus:=true;
668 if ductus:
669 pickup stylus;
670 fi
671 draw pth1;
672 draw (x1-n1,y1)--(x1,y1);
673
674 pickup capthinquill;
675 draw pth2;
676 filldraw z3--z3a{right}..{down}z3b--cycle;
677 ductus:=false;
678 penlabels(1,2,3,4,5,11,13,14,23,26,100);
679 endchar; % end "V"
680
681 cmchar "EGOTH letter W";
682 beginchar("W", 2cap_sb#+caprat*hstretch*(22/13x_height#),
683 caprat*x_height#, 0);
684 adjust_fit(0,0);
685 pcshiftx := cap_sb;
686 numeric n[];
687 path pth[];
688 pickup capquill;
689 x100 = 0;
690 n1 := sqrcjut;
691 n2 := sqrcjutrat*sqrcjut;
692 %% thick leg tops
693 lft x1 = pcshiftx + n1; top y1 = h;
694 x3 = 1/2w; y3 = y1;
695 %% thin leg top
696 pickup capthinquill;
697 rt x5 = w-pcshiftx; top y5 = h;
698 x5a = x5-n2; y5a = y5;
699 x5b = x5; y5b = y5-n2;
700 pickup capquill;
701 %% V bottoms
702 x13 = 1/2[x1,x3]; bot y13 = 0;
703 x35 = 1/2[x3,x5]; bot y35 = 0;
704 pth113 := z1{down}..z13;
705 pth335 := z3{down}..z35;
706 x83 = x3; y83 = top y3;
707 x813 = rt x13; y813 = bot y13;
708 x835 = rt x35; y835 = bot y35;
709 %% thin legs
710 pickup capthinquill;
711 rt x113 = x813; bot y113 = y813;
712 rt x135 = x835; bot y135 = y835;
713 %%ductus:=true;
714 if ductus:
715 pickup stylus;
716 fi
717 pickup capquill;
718 draw pth113; draw pth335; draw (x1-n1,y1)--(x1,y1);
719 pickup capthinquill;
720 draw z113..{up}z3; draw z135..{up}z5;
721 filldraw z5--z5a{right}..{down}z5b--cycle;
722 ductus:=false;
723 penlabels(1,2,3,4,5,6,7,8,9,11,13,14,33,34,53,16,100);
724 endchar; % end "W"
725
726 cmchar "EGOTH letter X";
727 beginchar("X", 2cap_sb#+caprat*hstretch*(17/13x_height#),
728 caprat*x_height#, 0);
729 adjust_fit(0,0);
730 path pth[];
731 numeric n[];
732 pcshiftx := cap_sb;
733 pickup capquill;
734 x100 = 0;
735 n1 := sqrcjut;
736 n2 := sqrcjutrat*sqrcjut;
737 %% diag top left to bottom right
738 lft x1=pcshiftx+n1; top y1 = h;
739 rt x2 = w - pcshiftx - n1; bot y2 = 0;
740 %% diag top right to bottom left
741 pickup capthinquill;
742 rt x3 = w - pcshiftx - n1; top y3 = h;
743 lft x4 = pcshiftx; bot y4 = 0;
744 x3a = x3-n2; x3b = x3+n1; y3a = y3b = y3;
745 y3c = y3-n2; z3c = whatever[z3,z4];
746 x4a = x4+n2; y4a = y4;
747 y4b = y4+n2; z4b = whatever[z4,z3];
748 pickup capquill;
749 %%ductus:=true;
750 if ductus:
751 pickup stylus;
752 fi
753 draw z1--z2;
754 draw (x1-n1,y1)--(x1,y1);
755 draw (x2,y2)--(x2+n1,y2);
756 pickup capthinquill;
757 draw z3--z4;
758 filldraw z3--z3a{right}..{z4-z3}z3c{z3-z4}..{right}z3b--cycle;
759 filldraw z4--z4a{left}..{z3-z4}z4b--cycle;
760 ductus:=false;
761 penlabels(1,2,3,4,5,6,7,8,10,25,251,252,40,50,150,60,160,100);
762 endchar; % end "X"
763
764 cmchar "EGOTH letter Y";
765 beginchar("Y", 2cap_sb#+caprat*hstretch*(13/13x_height#),
766 caprat*x_height#, 0);
767 adjust_fit(0,0);
768 pcshiftx := cap_sb;
769 path pth[];
770 numeric n[];
771 pickup capquill;
772 x100 = 0;
773 n1 := sqrcjut;
774 n2 := sqrcjutrat*sqrcjut;
775 %% upright
776 x5 = 1/2w; y5 = 1/2h;
777 x6 = x5; bot y6 = 0;
778 %% left stem top
779 lft x1 = pcshiftx + n1; top y1 = h;
780 %% right stem
781 x85 = rt x5; y85 = top y5;
782 pickup capthinquill;
783 rt x3=w-pcshiftx; top y3 = h;
784 x4=x85; y4 = y85;
785 x3a=x3-n2; y3a = y3;
786 y3b = y3-n2; z3b = whatever[z3,z4];
787 pickup capquill;
788 %%ductus:=true;
789 if ductus:
790 pickup stylus;
791 fi
792 draw z5--z6; draw (x6-n1,y6)--(x6+n1,y6); % stem
793 draw z1--z5; draw (x1-n1,y1)--(x1,y1); % left arm
794 pickup capthinquill;
795 draw z3--z4;
796 filldraw z3--z3a{right}..{z4-z3}z3b--cycle;
797 ductus:=false;
798 penlabels(1,2,3,4,5,6,7,8,9,10,100);
799 endchar; % end "Y"
800
801 cmchar "EGOTH letter Z";
802 beginchar("Z", 2cap_sb#+caprat*hstretch*(13/13x_height#),
803 caprat*x_height#, 0);
804 adjust_fit(0,0);
805 numeric n[];
806 n1 := sqrcjutrat*sqrcjut;
807 path pth[];
808 pcshiftx := cap_sb;
809 pickup capquill;
810 %% top bar ends
811 lft x1 = pcshiftx; rt x2 = w -pcshiftx; top y1 = top y2 = h;
812 x101 = lft x1; y101 = top y1;
813 %% bottom bar ends
814 lft x3 = pcshiftx; rt x4 = w -pcshiftx; bot y3 = bot y4 = 0;
815 x104 = rt x4; y104 = bot y4;
816 pickup stylus;
817 lft x11 = x101; top y11 = y101;
818 x12 = x11; y12 = y11-n1;
819 x13 = x11+n1; y13 = y11;
820 rt x14 = x104; bot y14 = y104;
821 x15 = x14; y15 = y14 + n1;
822 x16 = x14 - n1; y16 = y14;
823 pickup capquill;
824 %%ductus:=true;
825 if ductus:
826 pickup stylus;
827 fi
828 draw z1--z2; draw z3--z4;
829 draw z2--z3;
830 pickup stylus;
831 filldraw z11--z12{up}..{right}z13--cycle;
832 filldraw z14--z15{down}..{left}z16--cycle;
833 ductus:=false;
834 penlabels(1,2,3,4,5,6,10o,10i,14,14,16,20o,20i,100);
835 endchar; % end "Z"
836