Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/egothlig.mf

raw
1 %%
2 %% This is file `egothlig.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% egothic.dtx (with options: `lig')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19
20 ligtable "`": "`"=:oct"134";
21 ligtable "'": "'"=:oct"042"; %% , "?" kern 2u#, "!" kern 2u#;
22
23 ligtable "-": "-"=:oct"173";
24 ligtable oct"173": "-"=:oct"174";
25
26 ligtable "c": "t"=:oct"014";
27 ligtable "s": "t"=:oct"015";
28
29
30 cmchar "EGOTH ct ligature";
31 beginchar(oct"014", 2sb#+hstretch*(6/4x_height#),
32 asc_height#, 0);
33 adjust_fit(0,0);
34 pcshiftx := sb;
35 numeric n[];
36 path pth[];
37 pair vc[];
38 pickup quill;
39 %%%%%%%%%%% C
40
41 n1:=1/2(w-2pcshiftx); % actual letter width
42 n2 := h/ascratio; % x-height
43 x1=pcshiftx + 1/2n1; top y1 = n2;
44 lft x2 = pcshiftx; y2 = 1/2n2;
45 x3 = x1; bot y3 = 0;
46 rt x4 = n1; y4 = 1/4n2;
47 x6 = x4;
48 %%y6 = 3/4n2;
49 top y6 = y1;
50 pth1 := z6..z1{left}..z2{down}..z3{right}..z4{pdir};
51 %%%%%%%%%%%%% T
52
53 %% bar
54 top y33=n2; n3 := n2 - top y33;
55 %%lft x31 = n1+pcshiftx;
56 lft x31 = n1;
57 rt x32=w-pcshiftx;
58 %%top y31 = y33-n3; bot y32=y33+n3;
59 top y31 = y33-n3; y32=y33;
60 x33=1/2[x31,x32];
61 pth2 := z31{pdir}..z33..z32{pdir}; % T bar
62 n31 := n1; % width of bowl
63 %%lft x34 = pcshiftx + n1 + 1/8n31;
64 lft x34 = n1 + 1/8n31;
65 y34 = 1/2n2;
66 x35=x33; bot y35 = 0;
67 rt x36 = pcshiftx + n1 + 3/4n31; top y36 = 1/4n2;
68 pth3 := z33..z34{down}..z35{right}..z36{pdir}; % T bowl
69
70 %%%%%%%%%%%%%%%%% Ligature
71
72 z51=z6;
73 z55=z33;
74 x53 = 1/2[x51,x55];
75 top y53 = h;
76 vc51 := direction 0 of pth1;
77 vc55 := direction 0 of pth3;
78 pth4 := z51{vc51}..z53{right}..z55{vc55}; % loop
79 %%ductus:=true;
80 if ductus:
81 pickup stylus;
82 fi
83 draw pth1; % C
84 draw pth2; % T bar
85 draw pth3; % T bowl
86 draw pth4; % ligature loop
87 ductus:=false;
88 penlabels(1,2,3,4,5,6,14,16,17,18,31,32,33,34,35,36,100);
89 endchar; % end of "ct"
90
91
92 cmchar "EGOTH st ligature";
93 beginchar(oct"015", 2sb#+hstretch*(9/8x_height#+clubjut#),
94 asc_height#, 0);
95 adjust_fit(0,0);
96 pcshiftx := sb;
97 numeric n[];
98 path pth[];
99 pair vc[];
100 pickup quill;
101 %%%%%%%%%%% S
102
103 n1:=3/7(w-2pcshiftx-clubjut); % actual letter width
104 n2 := h/ascratio; % x-height
105
106 %% stem
107 lft x1=lft x2=pcshiftx+clubjut; top y1=n2; bot y2=0;
108 %% flick
109 x4=x2; y4 = 1/2n1;
110 %%%%%%%%%%%%% T
111
112 %% bar
113 top y33=n2; n3 := n2 - top y33;
114 %%lft x31 = n1+pcshiftx;
115 lft x31 = n1;
116 rt x32=w-pcshiftx;
117 %%top y31 = y33-n3; bot y32=y33+n3;
118 top y31 = y33-n3; y32=y33;
119 x33=1/2[x31,x32];
120 pth2 := z31{pdir}..z33..z32{pdir}; % T bar
121 n31 := n1; % width of bowl
122 %%lft x34 = pcshiftx + n1 + 1/8n31;
123 lft x34 = n1 + 1/8n31;
124 y34 = 1/2n2;
125 x35=x33; bot y35 = 0;
126 rt x36 = pcshiftx + n1 + 3/4n31; top y36 = 1/4n2;
127 pth3 := z33..z34{down}..z35{right}..z36{pdir}; % T bowl
128
129 %%%%%%%%%%%%%%%%% Ligature
130
131 z51=z4;
132 z55=z33;
133 x53 = 5/8[x51,x55];
134 top y53 = h;
135 vc51 := up;
136 vc55 := direction 0 of pth3;
137 pth4 := z51{vc51}...z53{right}..z55{vc55}; % loop
138 %%ductus:=true;
139 if ductus:
140 pickup stylus;
141 fi
142 draw z1--z2; % S stem
143 draw_clubserif(1,2,0.5);
144 draw_roundserif(2,1,srad);
145 draw pth2; % T bar
146 draw pth3; % T bowl
147 draw pth4; % ligature loop
148 ductus:=false;
149 penlabels(1,2,3,4,5,6,14,16,17,18,31,32,33,34,35,36,100);
150 endchar; % end of "st"
151
152
153 cmchar "Closing quotes";
154 beginchar(oct"042",2sb#+hstretch*(comma_width#+3dot_size#),4/3x_height#,0);
155 adjust_fit(0,0);
156 pcshiftx:=sb;
157 x1=w-pcshiftx-(0.5hstretch*dot_size); y1=y2=h;
158 x2=x1-(2hstretch*dot_size);
159 draw_pcomma(1,dot_size,comma_width); % right
160 draw_pcomma(2,dot_size,comma_width); % left
161 penlabels(1,2);
162 endchar; % end of "''"
163
164
165 cmchar "Opening quotes";
166 beginchar(oct"134",2sb#+hstretch*(comma_width#+3dot_size#),4/3x_height#,0);
167 adjust_fit(0,0);
168 pcshiftx:=sb;
169 x1=pcshiftx+(0.5hstretch*dot_size); y1=y2=h;
170 x2=x1+(2hstretch*dot_size);
171 draw_plq(1,dot_size,comma_width); % left
172 draw_plq(2,dot_size,comma_width); % right
173 penlabels(1,2);
174 endchar; % end of "``"
175
176
177 cmchar "Hyphen";
178 beginchar("-",sb#+hstretch*(0.8x_height#),x_height#,0);
179 adjust_fit(0,0);
180 pcshiftx:=sb/2;
181 %%numeric alpha; alpha:=w/8;
182 %%pickup quill;
183 %%lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
184 %%x11=lft x1+alpha/2; y11=top y1-0.5thin;
185 %%x12=rt x2; y12=bot y1+0.5thin;
186 %%draw_triangle(11,alpha);
187 %%draw_rutriangle(12,alpha);
188 pickup halfquill;
189 lft x21=pcshiftx+jut; rt x22=w-pcshiftx-jut; y21=y22=1/2h;
190 draw z21--z22;
191 draw_roundserif(21,22,srad); draw_flatserif(22,21,srad);
192 penlabels(1,2);
193 endchar; % end of "-"
194
195
196 cmchar "En dash";
197 beginchar(oct"173",sb#+hstretch*(x_height#),x_height#,0);
198 adjust_fit(0,0);
199 pcshiftx:=sb/2;
200 %%numeric alpha; alpha:=w/8;
201 %%pickup quill;
202 %%lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
203 %%x11=lft x1+alpha/2; y11=top y1-0.5thin;
204 %%x12=rt x2; y12=bot y1+0.5thin;
205 %%draw_triangle(11,alpha);
206 %%draw_rutriangle(12,alpha);
207 pickup halfquill;
208 lft x21=pcshiftx+jut; rt x22=w-pcshiftx-jut; y21=y22=1/2h;
209 draw z21--z22;
210 draw_roundserif(21,22,srad); draw_flatserif(22,21,srad);
211 penlabels(1,2);
212 endchar; % end of "--"
213
214
215 cmchar "Em dash";
216 beginchar(oct"174",sb#+hstretch*(2x_height#),x_height#,0);
217 adjust_fit(0,0);
218 pcshiftx:=sb/2;
219 %%numeric alpha; alpha:=w/8;
220 %%pickup quill;
221 %%lft x1 = pcshiftx; rt x2=w-pcshiftx; y1=y2=h/2;
222 %%x11=lft x1+alpha/2; y11=top y1-0.5thin;
223 %%x12=rt x2; y12=bot y1+0.5thin;
224 %%draw_triangle(11,alpha);
225 %%draw_rutriangle(12,alpha);
226 pickup halfquill;
227 lft x21=pcshiftx+jut; rt x22=w-pcshiftx-jut; y21=y22=1/2h;
228 draw z21--z22;
229 draw_roundserif(21,22,srad); draw_flatserif(22,21,srad);
230 penlabels(1,2);
231 endchar; % end of "---"
232
233
234 cmchar "EGOTH ampersand";
235 beginchar("&", 2sb#+hstretch*(5/4x_height#+2jut#), asc_height#, 0);
236 adjust_fit(0,0);
237 numeric n[];
238 path pth[];
239 pcshiftx:=sb;
240 pickup quill;
241 %% alpha looking part
242 n1 := w-2pcshiftx-jut; % actual letter width
243 n2 := h/ascratio; % x-height
244 n3 := 16/16n2; % height of alpha
245 x1 = w-pcshiftx; bot y1 = 0;
246 x3 = pcshiftx + 12/16n1; y3 = 1/2n3;
247 lft x5 = pcshiftx; y5 = y3;
248 x4 = x6 = 1/2[x5,x3];
249 top y4 = n3; bot y6 = 0;
250 rt x8 = w-pcshiftx; top y8=h;
251 x9 = x8-2jut; x10-x8 = x8-x9;
252 y9=y10=y8;
253 pth1 := z1{left}..z3..z4{left}..z5{down}..z6{right}..z3..z8{up};
254 %% loop
255 z21 = z5;
256 z25 = point 1.5 of pth1;
257 x23 = 1/2[x21,x25];
258 y23 = 6/8[y4,y8];
259 pth2 := z21{up}..z23{right}..z25{down};
260 %%ductus:=true;
261 if ductus:
262 pickup stylus;
263 fi
264 draw pth1; draw z9--z8; % alpha
265 draw pth2; % loop
266 ductus:=false;
267 penlabels(1,2,3,4,5,6,7,8,9,10,16,17,18,19,21,22,23,24,25);
268 endchar; % end of "&"
269