Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/imintitle.mf

raw
1 %%
2 %% This is file `imintitle.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% inslrmin.dtx (with options: `mfd')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18 def makebox(text rule) =
19 for y=0,half_height,cap_height,body_height,x_height,-desc_depth,-body_depth:
20 rule((l,y)t_,(r,y)t_); endfor % horizontals
21 for x=l,r: rule((x,-body_depth)t_,(x,body_height)t_); endfor % verticals
22 for x=u*(1+floor(1/u)) step u until r-1:
23 rule((x,-body_depth)t_,(x,body_height)t_); endfor % more verticals
24 if charic<>0:
25 rule((r+charic*pt,h.o_),(r+charic*pt,.5h.o_)); fi % italic correction
26 enddef;
27
28
29 def proofpcbb(suffix $)(expr xoff, yoff) =
30 if proofing > 0:
31 x$bl = x$ - xoff; y$bl = y$ - yoff; % Bottom Left Hand Corner
32 z$br = (x$bl+side, y$bl); % BRHC
33 z$tr = (x$bl+side, y$bl+side); % TRHC
34 z$tl = (x$bl, y$bl+side); % TLHC
35 z$bc = 1/2[z$bl,z$br]; z$tc = 1/2[z$tl,z$tr]; % horizontal mid points
36 pair hc, vc;
37 hc = (2u,0); vc = (0,2u);
38 pickup pensquare scaled 2;
39 for s = z$bl, z$br, z$tr, z$tl, z$bc, z$tc:
40 draw s-hc--s+hc;
41 draw s-vc--s+vc;
42 endfor
43 fi
44 enddef;
45
46
47 def inslrmin_font_setup= % contains special stuff for inslrmin fonts
48 define_pixels(side,half_height,carol_height,comma_width);
49 define_pixels(u,dot_size,letter_size,cap_height,width_adj,serif_fit,
50 cap_serif_fit,jut,cap_jut,trijut);
51 define_pixels(fig_width);
52 define_whole_pixels(letter_fit,sb);
53 define_whole_vertical_pixels(body_height,asc_height,cap_height,x_height,
54 desc_depth,body_depth,fig_height);
55 define_corrected_pixels(o);
56 define_blacker_pixels(thick,thin);
57 let adjust_fit = normal_adjust_fit;
58 pickup pencircle scaled thin;
59 stylus:=savepen;
60 pickup pencircle scaled (1.5thin);
61 thickstylus:=savepen;
62 pickup pencircle xscaled thick yscaled thin rotated pangle;
63 quill:=savepen;
64 numeric pcshiftx#; % x value of LHS of box wrt origin of char box
65 define_pixels(pcshiftx);
66 numeric sqxside#; % x size of the square
67 numeric sqyside#; % y size of the square
68 define_pixels(sqxside,sqyside);
69
70 enddef; % end of inslrmin_font_setup
71
72 boolean ductus;
73 ductus:=false;
74 numeric qhor, qvert;
75 qhor:=cosd(pangle); qvert:=sind(pangle);
76 pair pdir; pdir=dir(pangle);
77 pair ppdir; ppdir=dir(pangle+90);
78
79 def draw_serif(suffix $, $$)(expr fr)=
80 numeric beta, ajut, bjut;
81 beta=1-fr;
82 ajut=fr*jut; bjut=beta*jut;
83 pair vec[]; vec1=unitvector(z$$-z$);
84 vec2=ajut*vec1;
85 z$a=z$ shifted vec2;
86 z$b=z$a rotatedaround (z$,-90);
87 boolean top_serif;
88 if y$>y$$:
89 top_serif := true;
90 z$c=z$b shifted (-bjut*pdir);
91 else:
92 top_serif:=false;
93 z$c=z$b shifted (bjut*pdir);
94 fi
95 if top_serif:
96 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
97 else:
98 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
99 fi
100 labels($a,$b,$c);
101 enddef; % end of draw_serif
102
103
104 def draw_roundserif(suffix $, $$)(expr fr)=
105 draw_serif($, $$, fr);
106 undraw z$--z$a;
107 enddef; % end of draw_roundserif
108
109
110 def draw_flatserif(suffix $, $$)(expr fr)=
111 numeric beta, ajut, bjut;
112 beta=1-fr;
113 ajut=fr*jut; bjut=beta*jut;
114 pair vec[]; vec1=unitvector(z$$-z$);
115 vec2=ajut*vec1;
116 z$a=z$ shifted vec2;
117 %%% z$b=z$a rotatedaround (z$,-90);
118 boolean top_serif;
119 if y$>y$$:
120 top_serif := true;
121 z$c=z$ shifted (-jut*pdir);
122 else:
123 top_serif:=false;
124 z$c=z$ shifted (jut*pdir);
125 fi
126 z$b = fr[z$,z$c];
127 draw z$a--z$;
128 if top_serif:
129 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
130 else:
131 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
132 fi
133 labels($a,$b,$c);
134 enddef; % end of draw_flatserif
135
136
137 def draw_triserif(suffix $)(expr tj)=
138 pen oldpen; oldpen:=currentpen;
139 pickup quill;
140 x$ts1'=lft x$; y$ts1'=bot y$;
141 pickup stylus;
142 lft x$ts1=x$ts1'; bot y$ts1=y$ts1';
143 x$ts2=x$ts1-tj; z$ts2=whatever[z$,z$ts1];
144 x$ts3=x$ts1; y$ts3=y$ts2-tj;
145 pickup stylus;
146 %% filldraw z$ts1--z$ts2--z$ts3--cycle;
147 filldraw z$--z$ts2--z$ts3--cycle;
148 pickup oldpen;
149 labels($ts1,$ts2,$ts3);
150 enddef; % end of draw_triserif
151
152
153 def draw_istem(suffix $, $$)(expr fr)=
154 draw_serif($, $$, fr); % top serif
155 draw_serif($$, $, fr); % bottom serif
156 draw z$a--z$$a; % the stem
157 enddef; % end of draw_istem
158
159
160 def draw_tstem(suffix $, $$)(expr fr)=
161 %% draw_serif($$, $, fr); % the serif
162 %% draw z$--z$$a; % the stem
163 draw z$--z$$;
164 enddef; % end of draw_tstem
165
166
167 def draw_tlserif(suffix $, $$)(expr fr)=
168 draw_serif($, $$, fr); % the serif
169 draw z$a--z$$; % the stem
170 enddef; % end of draw_tlserif
171
172
173 def draw_flick(suffix $)(expr rise, fall, fjut)=
174 rt x$b = x1+fjut; top y$b=y$-fall;
175 x$a=0.5[x$,x$b]; top y$a=y$+rise;
176 draw z$..z$a..z$b;
177 labels($a,$b);
178 enddef; % end of draw_flick
179
180
181 def draw_wave(suffix $,$$)(expr f)=
182 x$wl=x$; y$wl=y$-f;
183 x$wr=x$$; y$wr=y$$+f;
184 z$wc=0.5[z$wl,z$wr];
185 draw z$wl{pdir}..z$wc{right}..{pdir}z$wr;
186 labels($wl,$wc,$wr);
187 enddef; % end of draw_wave
188
189 def draw_tail(suffix $)(expr fj)=
190 pen oldpen; oldpen:=currentpen;
191 pickup quill;
192 x$tl' = lft x$; y$tl=bot y$;
193 pickup stylus;
194 lft x$tl=x$tl';
195 x$tb=x$tl-fj; bot y$tb=y$tl-1/2desc_depth;
196 filldraw z${down}..{-pdir}z$tb & z$tb{pdir}..{up}z$tl--cycle;
197 pickup oldpen;
198 labels($tb,$tl);
199 enddef; % end of draw_tail
200
201 def draw_triangle(suffix $)(expr sz)=
202 pen oldpen; oldpen:=currentpen;
203 pickup stylus;
204 x$t1=x$-sz/2; x$t3=x$+sz/2;
205 y$t1=y$t3=y$;
206 x$t2=x$; y$t2=y$-0.9sz; % approx sqrt(3)/2
207 filldraw z$t1--z$t2--z$t3--cycle;
208 pickup oldpen;
209 labels($t1,$t2,$t3);
210 enddef; % end of draw_triangle
211
212 def draw_utriangle(suffix $)(expr sz)=
213 pen oldpen; oldpen:=currentpen;
214 pickup stylus;
215 x$t1=x$-sz/2; x$t3=x$+sz/2;
216 y$t1=y$t3=y$;
217 x$t2=x$; y$t2=y$+0.9sz; % approx sqrt(3)/2
218 filldraw z$t1--z$t2--z$t3--cycle;
219 pickup oldpen;
220 labels($t1,$t2,$t3);
221 enddef; % end of draw_utriangle
222
223 def draw_rtriangle(suffix $)(expr sz)=
224 pen oldpen; oldpen:=currentpen;
225 pickup stylus;
226 x$t1=x$-sz; rt x$t3=x$;
227 y$t1=y$t3=y$;
228 x$t2=x$t3; y$t2=y$-sz;
229 filldraw z$t1--z$t2--z$t3--cycle;
230 pickup oldpen;
231 labels($t1,$t2,$t3);
232 enddef; % end of draw_rtriangle
233
234 def draw_rutriangle(suffix $)(expr sz)=
235 pen oldpen; oldpen:=currentpen;
236 pickup stylus;
237 x$t1=x$-sz; rt x$t3=x$;
238 y$t1=y$t3=y$;
239 x$t2=x$t3; y$t2=y$+sz;
240 filldraw z$t1--z$t2--z$t3--cycle;
241 pickup oldpen;
242 labels($t1,$t2,$t3);
243 enddef; % end of draw_rutriangle
244
245 def draw_fork(suffix $, $$)(expr sz)=
246 pen oldpen; oldpen:=currentpen;
247 pickup quill;
248 x$f1'=lft x$; y$f1'=bot y$;
249 x$f3'=rt x$; y$f3'=top y$;
250 pickup stylus;
251 lft x$f1=x$f1'; bot y$f1=y$f1';
252 rt x$f3=x$f3'; y$f3-y$=2*(y$-y$f1);
253 rt x$f2=x$$-sz; bot y$f2=y$$;
254 rt x$f4= rt x$f5=x$$;
255 bot y$f5=y$$-sz; top y$f4=y$$+1/2sz;
256 filldraw z$f1--z$f2--z$f3--cycle; % the line
257 draw z$f2{right}..z$f4; % upper fork
258 draw z$f2{right}..z$f5; % lower fork
259 pickup oldpen;
260 labels($f1,$f2,$f3,$f4,$f5);
261 enddef; % end of draw_fork
262
263 def draw_urswish(suffix $, $$)=
264 pen oldpen; oldpen:=currentpen;
265 pickup quill;
266 rt x$$s1=x$$-thick; top y$$s1=y$$;
267 rt x$$s2=x$$;
268 %% x$$s3=x$$-thick;
269 lft x$$s3=x$$s1;
270 bot y$$s3=y$$-thick; y$$s2=0.5[y$$s1,y$$s3];
271 %% draw z$---z$$s1{right}..z$$s2{down}..{-pdir}z$$s3;
272 draw z$..z$$s1{pdir}..z$$s2{down};
273 labels($$s1,$$s2,$$s3);
274 enddef; % end of draw_urswish
275
276 def bowl_stem(suffix $, $$)=
277 x$'=0.5[x$,x$$]; y$'=y$; % the mid-point
278 z$''=z$' shifted (thick*pdir);
279 x$i=x$$; z$i=whatever[z$',z$''];
280 labels($',$i);
281 enddef; % end of bowl_stem
282
283 def draw_clubbase(suffix $, $$)(expr st, lft, rt)=
284 z$$l = z$$ shifted (lft*thick*(-pdir));
285 z$$r = z$$ shifted (rt*thick*(pdir));
286 z$$t = st[z$$,z$];
287 draw z$$t{z$$-z$}..z$$l--z$$r..{z$-z$$}z$$t;
288 labels($$t,$$l,$$r);
289 enddef; % end of draw_clubbase
290
291
292 def draw_pdot(suffix $)(expr sz)=
293 z$s = z$ shifted (0.5sz*left);
294 z$t = z$ shifted (0.5sz*up);
295 z$u = z$s shifted (sz*right);
296 z$v = z$t shifted (sz*down);
297 pickup stylus;
298 filldraw z$s--z$t--z$u--z$v--cycle;
299 labels($s,$t,$u,$v);
300 enddef; % end of draw_pdot
301
302
303 def draw_pcomma(suffix $)(expr sz, ar)=
304 z$s = z$ shifted (0.5sz*left);
305 z$t = z$s shifted (sz*right);
306 x$v=x$s-ar; y$v=y$s-ar;
307 z$u = z$v shifted (sz*right);
308 pickup stylus;
309 filldraw z$s--z$t--z$u--z$v--cycle;
310 %% filldraw z$s--z$t--z$u--cycle;
311 labels($s,$t,$u,$v);
312 enddef; % end of draw_pcomma
313
314
315 def draw_plq(suffix $)(expr sz, ar)=
316 z$s = z$ shifted (0.5sz*left);
317 z$t = z$s shifted (sz*right);
318 x$v=x$s+ar; y$v=y$s-ar;
319 z$u = z$v shifted (sz*right);
320 pickup stylus;
321 filldraw z$s--z$t--z$u--z$v--cycle;
322 %% filldraw z$s--z$t--z$v--cycle;
323 labels($s,$t,$u,$v);
324 enddef; % end of draw_plq
325
326
327 path obouter, obinner, obfirst, obsecond;
328 def offsetbowl(suffix $)(expr sx, sy, fx, fy)=
329 numeric inx, iny, cx, cy;
330 pair pt[];
331 path pth[];
332 inx := 1/2thick*cosd(pangle); iny := 1/2thick*sind(pangle);
333 cx := x$+fx*sx; cy := y$+fy*sy;
334 z$obc = (cx,cy);
335 if pangle = 90:
336 z$wt=(x$+1/2thin, cy);
337 z$et=(x$+sx-1/2thin, cy);
338 else:
339 z$wt=(x$+inx, cy);
340 z$et=(x$+sx-inx, cy);
341 penpos$wt(thick,pangle);
342 penpos$et(thick,pangle);
343 fi
344 if pangle = 0:
345 z$nh=(cx, y$+sy-1/2thin);
346 z$sh=(cx, y$+1/2thin);
347 else:
348 z$nh=(cx, y$+sy-iny);
349 z$sh=(cx, y$+iny);
350 penpos$nh(thick,pangle);
351 penpos$sh(thick,pangle);
352 fi
353 obfirst := z$nh{right}..z$et{down}..z$sh{left}..z$wt{up}..cycle;
354 if pangle = 90:
355 z$minl = z$wt; z$maxr = z$nh; z$minr = z$et; z$maxl = z$sh;
356 else:
357 if pangle = 0:
358 z$minl = z$nh; z$maxr = z$et; z$minr = z$sh; z$maxl = z$wt;
359 else:
360 z$minl = directionpoint dir(pangle) of obfirst;
361 z$minr = directionpoint -dir(pangle) of obfirst;
362 pt1 := z$minr - z$minl; % direction
363 pt2 := (- ypart pt1, xpart pt1); % perpendicular
364 pt3 := 1/2[z$minl, z$minr];
365 pt4 := pt3 shifted pt2;
366 pt5 := pt3 shifted -pt2;
367 pth1 := pt3--pt4;
368 pth2 := pt3--pt5;
369 z$maxr = pth1 intersectionpoint obfirst;
370 z$maxl = pth2 intersectionpoint obfirst;
371 \fi
372 \fi
373 penpos$minl(thin,pangle+90);
374 penpos$maxr(thick,pangle);
375 penpos$minr(thin,pangle+90);
376 penpos$maxl(thick,pangle);
377 obsecond := z$minl..z$maxr..z$minr..z$maxl..cycle;
378 z$minlo = z$minl.r; z$maxro = z$maxr.r;
379 z$minro = z$minr.l; z$maxlo = z$maxl.l;
380 obouter := z$minlo{dir(pangle)}...z$maxro...z$minro{-dir(pangle)}...z$maxlo...cycle;
381 z$minli = z$minl.l; z$maxri = z$maxr.l;
382 z$minri = z$minr.r; z$maxli = z$maxl.r;
383 obinner := z$minli...z$maxri...z$minri...z$maxli...cycle;
384 labels($obc, $nh, $et, $sh, $wt);
385 labels($minl, $maxr, $minr, $maxl);
386 labels($minlo, $maxro, $minro, $maxlo);
387 labels($minli, $maxri, $minri, $maxli);
388 enddef;
389
390
391 def obowl(suffix $)(expr sx, sy)=
392 offsetbowl($, sx, sy, 1/2, 1/2);
393 enddef;
394
395
396 primarydef v scalarprod w =
397 (xpart v * ypart w - ypart v * xpart w)
398 enddef;
399
400
401 def tangentpoint(suffix $)(expr pth)=
402 pair vecll, veclr, veclm; % "tangent" line directions
403 numeric pl, pr, pm; % path parameter values
404 pair vecpl, vecpr, vecpm; % path directions
405 pair ptl, ptr, ptm; % path points
406 numeric sl, sr, sm; % scalar products of path/line directions
407 numeric stpsize; % size of current binary step
408 numeric tantol; % tolerance
409 boolean wtest; % a boolean
410
411 tantol := eps;
412 pl:=0; pr:=length pth; pm:=0.5(pl+pr); stpsize:=pr-pl;
413 ptl := point pl of pth;
414 ptm := point pm of pth;
415 ptr := point pr of pth;
416 vecll := unitvector (z$-ptl);
417 veclm := unitvector (z$-ptm);
418 veclr := unitvector (z$-ptr);
419 vecpl := unitvector (direction pl of pth);
420 vecpm := unitvector (direction pm of pth);
421 vecpr := unitvector (direction pr of pth);
422 sl := vecll scalarprod vecpl;
423 sm := veclm scalarprod vecpm;
424 sr := veclr scalarprod vecpr;
425 wtest := (stpsize < tantol) or (sl*sr > 0) or
426 (abs sl < tantol) or (abs sm < tantol) or (abs sr < tantol);
427 if wtest:
428 if (stpsize < tantol):
429 z$tan=(0,0);
430 errmessage("No tangent; path too short");
431 else:
432 if (sl*sr > 0):
433 z$tan=(0,0);
434 errmessage("No tangent; end products have the same sign");
435 else:
436 if (abs sl < tantol):
437 z$tan=ptl;
438 else:
439 if (abs sm < tantol):
440 z$tan=ptm;
441 else:
442 z$tan=ptr;
443 fi
444 fi
445 fi
446 fi
447 else:
448 forever:
449 if (sl*sm < 0): % opposite signs, look between pl & pm
450 pr:=pm; pm:=0.5(pr+pl);
451 vecpr := vecpm; veclr := veclm; sr:=sm;
452 else:
453 pl:=pm; pm:=0.5(pr+pl);
454 vecpl:=vecpm; vecll:=veclm; sl:=sm;
455 fi
456 stpsize:=pr-pl;
457 ptm := point pm of pth;
458 veclm := unitvector (z$-ptm);
459 vecpm := unitvector (direction pm of pth);
460 sm := veclm scalarprod vecpm;
461 wtest := (stpsize < tantol) or (abs sm < tantol);
462 if wtest:
463 if (abs sm < tantol):
464 z$tan = ptm;
465 else:
466 z$tan = ptm;
467 %%%%%% errmessage("Warning: tangent approximated");
468 fi
469 fi
470 exitif wtest;
471 endfor
472 fi
473 enddef;
474
475
476 font_coding_scheme:="ASCII minuscules and punctuation";
477 mode_setup;
478 inslrmin_font_setup;
479
480
481 input iminl; % lower case
482 input iminu; % capitals
483 input iminpunct; % punctuation
484 input iminlig; % the several dashes
485 input imindig; % arabic digits
486
487
488 font_slant slant; font_x_height x_height#;
489 if monospace:
490 font_normal_space vstretch*9u#; % no stretching or shrinking
491 font_quad vstretch*18u#;
492 font_extra_space vstretch*9u#;
493 else:
494 font_normal_space vstretch*6u#+2letter_fit#;
495 font_normal_stretch vstretch*3u#; font_normal_shrink vstretch*2u#;
496 font_quad vstretch*18u#+4letter_fit#;
497 font_extra_space vstretch*2u#;
498
499 fi
500
501 bye.
502
503 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
504 kks#:=-4u#; kkx#:=-1.5u#; kkj#:=-2u#; kkr#:=-5u#; kkrs#:=-2u#; kkrl#:=-8u#;
505 ligtable "s":
506 "a" kern kks#, "A" kern kks#,
507 "c" kern kks#, "C" kern kks#,
508 "d" kern kks#, "D" kern kks#,
509 "e" kern kks#, "E" kern kks#,
510 "f" kern kks#, "F" kern kks#,
511 "g" kern kks#, "G" kern kks#,
512 "i" kern kks#, "I" kern kks#,
513 "j" kern kks#, "J" kern kks#,
514 "k" kern kks#, "K" kern kks#,
515 "m" kern kks#, "M" kern kks#,
516 "n" kern kks#, "N" kern kks#,
517 "o" kern kks#, "O" kern kks#,
518 "p" kern kks#, "P" kern kks#,
519 "q" kern kks#, "Q" kern kks#,
520 "r" kern kks#, "R" kern kks#,
521 "t" kern kks#, "T" kern kks#,
522 "u" kern kks#, "U" kern kks#,
523 "v" kern kks#, "V" kern kks#,
524 "w" kern kks#, "W" kern kks#,
525 "x" kern kks#, "X" kern kks#,
526 "y" kern kks#, "Y" kern kks#,
527 "z" kern kks#, "Z" kern kks#;
528
529 ligtable "S":
530 "a" kern kks#, "A" kern kks#,
531 "c" kern kks#, "C" kern kks#,
532 "d" kern kks#, "D" kern kks#,
533 "e" kern kks#, "E" kern kks#,
534 "f" kern kks#, "F" kern kks#,
535 "g" kern kks#, "G" kern kks#,
536 "i" kern kks#, "I" kern kks#,
537 "j" kern kks#, "J" kern kks#,
538 "k" kern kks#, "K" kern kks#,
539 "m" kern kks#, "M" kern kks#,
540 "n" kern kks#, "N" kern kks#,
541 "o" kern kks#, "O" kern kks#,
542 "p" kern kks#, "P" kern kks#,
543 "q" kern kks#, "Q" kern kks#,
544 "r" kern kks#, "R" kern kks#,
545 "t" kern kks#, "T" kern kks#,
546 "u" kern kks#, "U" kern kks#,
547 "v" kern kks#, "V" kern kks#,
548 "w" kern kks#, "W" kern kks#,
549 "x" kern kks#, "X" kern kks#,
550 "y" kern kks#, "Y" kern kks#,
551 "z" kern kks#, "Z" kern kks#;
552
553 ligtable "x":
554 "a" kern kkx#, "A" kern kkx#,
555 "b" kern kkx#, "B" kern kkx#,
556 "c" kern kkx#, "C" kern kkx#,
557 "d" kern kkx#, "D" kern kkx#,
558 "e" kern kkx#, "E" kern kkx#,
559 "g" kern kkx#, "G" kern kkx#,
560 "j" kern kkx#, "J" kern kkx#,
561 "l" kern kkx#, "L" kern kkx#,
562 "o" kern kkx#, "O" kern kkx#,
563 "q" kern kkx#, "Q" kern kkx#,
564 "t" kern kkx#, "T" kern kkx#,
565 "u" kern kkx#, "U" kern kkx#,
566 "v" kern kkx#, "V" kern kkx#,
567 "w" kern kkx#, "W" kern kkx#,
568 "y" kern kkx#, "Y" kern kkx#;
569
570 ligtable "X":
571 "a" kern kkx#, "A" kern kkx#,
572 "b" kern kkx#, "B" kern kkx#,
573 "c" kern kkx#, "C" kern kkx#,
574 "d" kern kkx#, "D" kern kkx#,
575 "e" kern kkx#, "E" kern kkx#,
576 "g" kern kkx#, "G" kern kkx#,
577 "j" kern kkx#, "J" kern kkx#,
578 "l" kern kkx#, "L" kern kkx#,
579 "o" kern kkx#, "O" kern kkx#,
580 "q" kern kkx#, "Q" kern kkx#,
581 "t" kern kkx#, "T" kern kkx#,
582 "u" kern kkx#, "U" kern kkx#,
583 "v" kern kkx#, "V" kern kkx#,
584 "w" kern kkx#, "W" kern kkx#,
585 "y" kern kkx#, "Y" kern kkx#;
586
587 ligtable "a": "A":
588 "b": "B":
589 "c": "C":
590 "d": "D":
591 "e": "E":
592 "h": "H":
593 "i": "I":
594 "k": "K":
595 "l": "L":
596 "m": "M":
597 "n": "N":
598 "o": "O":
599 "p": "P":
600 "t": "T":
601 "u": "U":
602 "v": "V":
603 "w": "W":
604 "z": "Z":
605 "j" kern kkj#, "J" kern kkj#;
606
607 ligtable "r":
608 "a" kern kkr#, "A" kern kkr#,
609 "b" kern kkr#, "B" kern kkr#,
610 "c" kern kkr#, "C" kern kkr#,
611 "d" kern kkr#, "D" kern kkr#,
612 "e" kern kkr#, "E" kern kkr#,
613 "f" kern kkrs#, "F" kern kkrs#,
614 "g" kern kkrs#, "G" kern kkrs#,
615 "h" kern kkr#, "H" kern kkr#,
616 "i" kern kkr#, "I" kern kkr#,
617 "j" kern kkj#, "J" kern kkj#,
618 "k" kern kkrs#, "K" kern kkrs#,
619 "l" kern kkr#, "L" kern kkr#,
620 "m" kern kkr#, "M" kern kkr#,
621 "n" kern kkrs#, "N" kern kkrs#,
622 "o" kern kkr#, "O" kern kkr#,
623 "p" kern kkrs#, "P" kern kkrs#,
624 "q" kern kkr#, "Q" kern kkr#,
625 "r" kern kkrs#, "R" kern kkrs#,
626 "s" kern kkr#, "S" kern kkr#,
627 "t" kern kkr#, "T" kern kkr#,
628 "u" kern kkr#, "U" kern kkr#,
629 "v" kern kkr#, "V" kern kkr#,
630 "w" kern kkr#, "W" kern kkr#,
631 "x" kern kkx#, "X" kern kkx#,
632 "y" kern kkr#, "Y" kern kkr#,
633 "z" kern kkr#, "Z" kern kkr#;
634
635 ligtable "R":
636 "a" kern kkr#, "A" kern kkr#,
637 "b" kern kkr#, "B" kern kkr#,
638 "c" kern kkr#, "C" kern kkr#,
639 "d" kern kkr#, "D" kern kkr#,
640 "e" kern kkr#, "E" kern kkr#,
641 "f" kern kkrs#, "F" kern kkrs#,
642 "g" kern kkrs#, "G" kern kkrs#,
643 "h" kern kkr#, "H" kern kkr#,
644 "i" kern kkr#, "I" kern kkr#,
645 "j" kern kkj#, "J" kern kkj#,
646 "k" kern kkrs#, "K" kern kkrs#,
647 "l" kern kkr#, "L" kern kkr#,
648 "m" kern kkr#, "M" kern kkr#,
649 "n" kern kkrs#, "N" kern kkrs#,
650 "o" kern kkr#, "O" kern kkr#,
651 "p" kern kkrs#, "P" kern kkrs#,
652 "q" kern kkr#, "Q" kern kkr#,
653 "r" kern kkrs#, "R" kern kkrs#,
654 "s" kern kkr#, "S" kern kkr#,
655 "t" kern kkr#, "T" kern kkr#,
656 "u" kern kkr#, "U" kern kkr#,
657 "v" kern kkr#, "V" kern kkr#,
658 "w" kern kkr#, "W" kern kkr#,
659 "x" kern kkx#, "X" kern kkx#,
660 "y" kern kkr#, "Y" kern kkr#,
661 "z" kern kkr#, "Z" kern kkr#;
662
663 fi
664
665 bye.
666