Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/imajl.mf

raw
1 %%
2 %% This is file `imajl.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% inslrmaj.dtx (with options: `min')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18
19 cmchar "IMAJ letter a";
20 beginchar("a", 2sb#+hstretch*(5/3x_height#),
21 x_height#, 0);
22 adjust_fit(0,0);
23 pcshiftx := sb;
24 numeric n[];
25 path pth[];
26 pickup quill;
27 %% left bowl
28 n1 := w-2pcshiftx; % actual letter width
29 n2 := 7/10n1; % width of left bowl
30 z1=(pcshiftx,0);
31 obowl(1, n2, h);
32 pth1:=obouter; pth2:=obinner;
33 pth10:=obfirst; pth20:=obsecond;
34 %% right bowl
35 n3:=x1+n2-16/12thick; % leftmost point of "stem"
36 n4:=2(n1-n3); % total width of right stem bowl
37 z2=(n3,0);
38 offsetbowl(2, n4, h, 6/12, 1/2);
39 pth3:=obouter; pth4:=obinner;
40 pth30:=obfirst; pth40:=obsecond;
41 %% intersect left bowl with outer of right bowl
42 z1tout = (subpath (0,1) of pth1) intersectionpoint (subpath (4,2) of pth3);
43 z1tinn = (subpath (0,1) of pth2) intersectionpoint (subpath (4,2) of pth3);
44 z1lout = (subpath (1,2) of pth1) intersectionpoint (subpath (4,2) of pth3);
45 z1linn = (subpath (1,2) of pth2) intersectionpoint (subpath (4,2) of pth3);
46
47 %%ductus:=true;
48 if ductus:
49 pickup stylus;
50 % draw the control paths
51 draw pth10; draw pth20;
52 draw pth30; draw pth40;
53 else:
54 %% draw left bowl
55 fill z1lout..z1minro{-pdir}..z1maxlo{ppdir}..z1minlo{pdir}..z1tout--
56 z1tinn..z1minli{-pdir}..z1maxli{-ppdir}..z1minri{pdir}..z1linn--
57 cycle;
58 %% draw right stem/bowl
59 fill z2minro{-pdir}..z2maxlo{ppdir}..{pdir}z2minlo--
60 z2minli{-pdir}..z2maxli{-ppdir}..{pdir}z2minri--cycle;
61 fi
62 ductus:=false;
63 penlabels(1,2,3,4,5,6,7,8,100);
64 endchar; % end "a"
65
66 cmchar "IMAJ letter b";
67 beginchar("b", 2sb#+hstretch*(7/6x_height#),
68 asc_height#, 0);
69 adjust_fit(0,0);
70 numeric n[];
71 pcshiftx := sb;
72 pickup quill;
73 n1:=w-2pcshiftx; % actual letter width
74 n2:=h/ascratio; % top of bowl
75 z1=(pcshiftx, -o);
76 obowl(1, n1, n2+o);
77 %% draw bowl
78 fill obouter; unfill obinner;
79 %% top of stem
80 x2=x1wt+1/3n1; top y2=h;
81 tangentpoint(2, subpath (3,4) of obsecond);
82 %%ductus:=true;
83 if ductus:
84 pickup stylus;
85 fi
86 draw z2tan--z2;
87 draw_triserif(2,trijut);
88 ductus:=false;
89 penlabels(1,2,3,4,5,6,7,8,9,100);
90 endchar; % end "b"
91
92 cmchar "IMAJ letter c";
93 beginchar("c", 2sb#+hstretch*(5/6x_height#),
94 x_height#, 0);
95 adjust_fit(0,0);
96 numeric n[];
97 pcshiftx := sb;
98 pickup quill;
99 n1:=w-2pcshiftx; % actual letter width
100 n2:=6/5w-2pcshiftx; % width of full bowl
101 z1=(pcshiftx,0);
102 obowl(1, n2, h);
103 z3=(x1+n1, h); % top RH corner
104 z4=(x1obc,1/6h); z5=(3/2w,y4); % for horizontal line
105 %% top intersection points
106 z10i = (z1obc--z3) intersectionpoint obinner;
107 z10o = (z1obc--z3) intersectionpoint obouter;
108 %% bottom intersection points
109 z20i = (z4--z5) intersectionpoint obinner;
110 z20o = (z4--z5) intersectionpoint obouter;
111 %%ductus:=true;
112 if ductus:
113 pickup stylus;
114 fi
115 fill z20o..z1minro{-pdir}..z1maxlo{ppdir}..z1minlo{pdir}..z10o--
116 z10i..z1minli{-pdir}..z1maxli{-ppdir}..z1minri{pdir}..z20i--
117 cycle;
118 ductus:=false;
119 penlabels(1,2,3,4,5,6,16,17,18,100);
120 endchar; % end "c"
121
122 cmchar "IMAJ letter d";
123 beginchar("d", 2sb#+hstretch*(x_height#+1/2thick#),
124 x_height#, 0);
125 adjust_fit(0,0);
126 numeric n[];
127 pcshiftx := sb;
128 pickup quill;
129 %% bowl
130 n1 := w-2pcshiftx; % actual letter width
131 n2 := n1-1/2thick; % width of bowl
132 n3 := h; % top of bowl
133 z1=(w-pcshiftx-n2, 0);
134 obowl(1, n2, n3);
135 %% top bar
136 lft x3=pcshiftx; y3=h;
137 z3i=(pcshiftx, y3-1/2thin); z3o=(x3i,y3i+thin);
138 z2i=(x1nh,y3i);
139 z2o=(x2i,y3o);
140 %%ductus:=true;
141 if ductus:
142 pickup stylus;
143 fi
144 fill z1minlo{-pdir}..z1maxlo{-ppdir}..z1minro{pdir}..z1maxro{ppdir}..{left}z2o--
145 z3o--z3i--
146 z2i{right}..z1maxri{-ppdir}..z1minri{-pdir}..z1maxli{ppdir}..{pdir}z1minli--
147 cycle;
148 draw_utriangle(3, thick);
149 ductus:=false;
150 penlabels(0,1,2,3,4,5,6,7,8,100);
151 endchar; % end "d"
152
153 cmchar "IMAJ letter e";
154 beginchar("e", sb#+hstretch*(x_height#+3/2thick#),
155 x_height#, 0);
156 adjust_fit(0,0);
157 pcshiftx := sb;
158 numeric n[];
159 pickup quill;
160 n1 := w-pcshiftx; % actual letter width
161 n2 := n1-3/2thick; % width of bowl
162 z1=(pcshiftx,0);
163 obowl(1, n2, h);
164 %% for crossbar
165 z2=(0,2/3h); rt x3=w; y3=y2; z3'=(x1obc,y2);
166 z4 = (z2--z3') intersectionpoint subpath (3,4) of obsecond;
167 z10tout = (z3'--z3) intersectionpoint subpath (0,3) of obouter;
168 z10tinn = (z3'--z3) intersectionpoint subpath (0,3) of obinner;
169 %% bottom cutoff
170 z5=(x1obc,1/6h); z6=(w,y5);
171 z20bout = (z5--z6) intersectionpoint subpath (0,3) of obouter;
172 z20binn = (z5--z6) intersectionpoint subpath (0,3) of obinner;
173 %%ductus:=true;
174 if ductus:
175 pickup stylus;
176 fi
177 fill z20bout..z1minro{-pdir}..z1maxlo{ppdir}..z1minlo{pdir}..z10tout--
178 z10tinn..z1minli{-pdir}..z1maxli{-ppdir}..z1minri{pdir}..z20binn--
179 cycle;
180 draw z4--z3; % crossbar & decoration
181 draw_triangle(3,thick);
182 ductus:=false;
183 penlabels(1,2,3,4,5,6,7,8,9,100);
184 endchar; % end "e"
185
186 cmchar "IMAJ letter f";
187 beginchar("f", 2sb#+hstretch*(x_height#+trijut#),
188 (x_height#), desc_depth#);
189 adjust_fit(0,0);
190 pcshiftx := sb;
191 pickup quill;
192 %% stem
193 lft x1=lft x2=pcshiftx+trijut;
194 top y1=h; bot y2=-d;
195 %% bottom bar
196 z4=(rt x1,-thin); rt x6=w-pcshiftx; y6=y4+2thin; z5=1/2[z4,z6];
197 %% top bar
198 z7=(rt x1, bot y1);
199 %%ductus:=true;
200 if ductus:
201 pickup stylus;
202 fi
203 draw_tstem(1,2,srad); % stem
204 draw_triserif(1,trijut);
205 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
206 draw z4{dir(45)}..z5{right}..z6{dir(45)}; % bottom bar
207 draw_flick(7, 2thin, thin, (w-pcshiftx-x7+1/2thick)); % top bar
208 ductus:=false;
209 penlabels(1,2,3,4,5,6,7,100);
210 endchar; % end "f"
211
212 cmchar "IMAJ letter g";
213 beginchar("g", 2sb#+hstretch*(5/3x_height#),
214 x_height#, desc_depth#);
215 adjust_fit(0,0);
216 path pth[];
217 pair vec[];
218 pcshiftx := sb;
219 pickup quill;
220 %% top bar
221 lft x1=pcshiftx; y1=h; rt x2=w-pcshiftx; y2=h;
222 %% curves
223 z3=2/5[z1,z2];
224 x5=4/5[x1,x2]; y5=-1/2d;
225 x4=(x3-thick); y4=1/2[y5,y3];
226 x7=1/2[x1,x4]; y7=y5;
227 x6=2/3[x7,x5]; bot y6=-d;
228 pth1 := z3..z4{down}..z5;
229 pth2 := z5--z6{left}..z7;
230 %% diagonal to close bottom bowl
231 vec1 := direction 2 of pth2;
232 vec2 := (z5-z6);
233 z7'=(lft x7, bot y7); z7''=(rt x7, y7);
234 pickup thickstylus;
235 lft x8 = x7'; bot y8 = y7';
236 z9' = z8 shifted 2vec2;
237 z9 = (z8--z9') intersectionpoint pth1;
238 z7''' = z7'' shifted 2vec1;
239 z8' = whatever[z7'',z7'''] = whatever[z8,z9'];
240 %%ductus:=true;
241 if ductus:
242 pickup stylus;
243 draw z1--z2; % top bar
244 draw pth1; draw pth2; % curves
245 draw rt z8--z9; % diagonal
246 else:
247 pickup quill;
248 draw z1--z2; % top bar
249 draw_triangle(2,thick);
250 draw_utriangle(1,thick);
251 draw pth1; draw pth2; % curves
252 pickup thickstylus;
253 draw rt z8--z9; % diagonal
254 fill z7''--z8'--z8--cycle;
255 fi
256 ductus:=false;
257 penlabels(1,2,3,4,5,6,7,8,9,100);
258 endchar; % end "g"
259
260 cmchar "IMAJ letter h";
261 beginchar("h", 2sb#+hstretch*(x_height#+trijut#),
262 asc_height#, 0);
263 adjust_fit(0,0);
264 pcshiftx := sb;
265 pickup quill;
266 numeric n[];
267 %% stem
268 lft x1=lft x2=pcshiftx+trijut;
269 top y1=h; bot y2=0;
270 %% bowl
271 rt x3 = lft x1; y3=0;
272 n1 := w-pcshiftx-x3; % bowl width
273 n2 := h/ascratio; % bowl height
274 obowl(3, n1, n2);
275 z1'=(rt x1, y1); z2'=(x1',y2); %% right hand side of stem
276 z10tout = (z1'--z2') intersectionpoint subpath (3,4) of obouter;
277 z10tinn = (z1'--z2') intersectionpoint subpath (3,4) of obinner;
278 z10toth = (x1, y10tinn); % avoids 180 turn in path
279 z6 = directionpoint down of obsecond; % top of right leg
280 z6i=(lft x6, bot y6); z6o=(rt x6, bot y6);
281 z8=(x6,0);
282 %%ductus:=true;
283 if ductus:
284 pickup stylus;
285 fi
286 draw_tstem(1,2,srad); % stem
287 draw_triserif(1,trijut);
288 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
289 draw_tstem(6,8,srad); % right leg
290 draw_clubbase(6, 8, 1/3, 0, 1/2clubjut);
291 fill z6i{up}..z3minli{-pdir}..z10tinn--z10toth-- % top of bowl
292 z10tout..z3minlo{pdir}..{down}z6o--cycle;
293 ductus:=false;
294 penlabels(1,2,3,4,5,6,100);
295 endchar; % end "h"
296
297 cmchar "IMAJ letter i";
298 beginchar("i", 2sb#+hstretch*(thick#+trijut#+jut#),
299 x_height#, 0);
300 adjust_fit(0,0);
301 pcshiftx := sb;
302 pickup quill;
303 lft x1=lft x2=pcshiftx+trijut;
304 top y1=h; bot y2=0;
305 %%ductus:=true;
306 draw_tstem(1,2,srad);
307 draw_triserif(1,trijut);
308 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
309 ductus:=false;
310 penlabels(1,2,100);
311 endchar; % end "i"
312
313 cmchar "IMAJ letter j";
314 beginchar("j", sb#+hstretch*(2/3x_height#),
315 x_height#, desc_depth#);
316 adjust_fit(0,0);
317 pcshiftx := sb;
318 numeric n[];
319 pickup quill;
320 %% stem
321 rt x1 = w-pcshiftx; top y1 = h;
322 x2=x1; y2=-1/2d;
323 %% bottom hook
324 lft x3 = 0; bot y3 = -d;
325 %% triangle
326 n1 := thick; % side length
327 z6=(lft x3, bot y3);
328 x7=x6+n1; z7=whatever[z6,z2];
329 z8=1/2[z6,z7];
330 z9=(x8, y8+0.9n1);
331 %%ductus:=true;
332 if ductus:
333 pickup stylus;
334 fi
335 draw z1--z2; % stem
336 draw_triserif(1,trijut);
337 draw z2--z3; % hook
338 fill z6--z7--z9--cycle; % triangle
339 ductus:=false;
340 penlabels(1,2,3,100);
341 endchar; % end "j"
342
343 cmchar "IMAJ letter k";
344 beginchar("k", 2sb#+hstretch*(x_height#+trijut#),
345 x_height#, desc_depth#);
346 adjust_fit(0,0);
347 pcshiftx := sb;
348 pickup quill;
349 %% stem
350 lft x1=lft x2=pcshiftx+trijut;
351 top y1=h; bot y2=-d;
352 %% top arm
353 z3=(x1,5/6h);
354 rt x5=w-pcshiftx; y5=2/3h;
355 x4=1/2[x3,x5]; top y4=h;
356 %% lower arm
357 x7=x5; bot y7=0;
358 %%ductus:=true;
359 if ductus:
360 pickup stylus;
361 fi
362 draw_tstem(1,2,srad); % stem
363 draw_triserif(1,trijut);
364 draw_clubbase(1,2,1/3, clubjut, clubjut);
365 draw z3..z4{right}..z5; % upper arm
366 draw z3..{right}z7; % lower arm
367 ductus:=false;
368 penlabels(1,2,3,4,5,100);
369 endchar; % end "k"
370
371 cmchar "IMAJ letter l";
372 beginchar("l", 2sb#+hstretch*(7/6x_height#),
373 asc_height#, 0);
374 adjust_fit(0,0);
375 pcshiftx := sb;
376 pickup quill;
377 lft x2=pcshiftx; y2=1/5h;
378 x1=x2+trijut; top y1=h;
379 rt x4=w-pcshiftx; y4=1/5h;
380 x3=1/2[x2,x4]; bot y3=0;
381 %%ductus:=true;
382 if ductus:
383 pickup stylus;
384 fi
385 draw z1{down}..z2..z3{right}..z4;
386 draw_triserif(1,trijut);
387 ductus:=false;
388 penlabels(1,2,3,4,100);
389 endchar; % end "l"
390
391 cmchar "IMAJ letter m";
392 beginchar("m", 2sb#+hstretch*(5/3x_height#+trijut#),
393 x_height#, 0);
394 adjust_fit(0,0);
395 pcshiftx := sb;
396 numeric n[];
397 path pth[];
398 pickup quill;
399 %% left stem
400 lft x1=pcshiftx+trijut; top y1=h;
401 x2=x1; bot y2=0;
402 z1'=(rt x1, y1+h); z2'=(rt x2, y2-h);
403 %% right stem
404 rt x5=w-pcshiftx; y5=y1;
405 z6=(x5,0);
406 %% middle stem
407 z3=1/2[z1,z5]; z4=1/2[z2,z6];
408 z3'=(rt x3, y3); z4'=(rt x4, y4);
409 n1 := x4-x2+3/2thick; % width of bowl
410 n2 := 2/3h; % height of bowl
411 %% left bowl
412 z7=(rt x4 - n1, h-n2);
413 obowl(7, n1, n2);
414 pth1 := obouter; pth2 := obinner; pth3 := obsecond;
415 z17tout = (z1'--z2') intersectionpoint subpath (3,4) of obouter;
416 z17tinn = (z1'--z2') intersectionpoint subpath (3,4) of obinner;
417 z17toth = (x2, y17tinn);
418 %% right bowl
419 z8=(rt x6 - n1, y7);
420 obowl(8, n1, n2);
421 pth5 := obouter; pth6 := obinner; pth7 := obsecond;
422 z18tout = pth5 intersectionpoint subpath (0,1) of pth1;
423 z18tinn = pth6 intersectionpoint subpath (0,1) of pth1;
424 z13 = directionpoint down of pth3;
425 z15 = directionpoint down of pth7;
426 %%ductus:=true;
427 if ductus:
428 pickup stylus;
429 fi
430 draw_tstem(1,2,srad); % left half
431 draw_triserif(1,trijut);
432 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
433 fill z17tout..z7minlo{pdir}..{down}(rt x13, y13)--
434 (lft x13, y13){up}..z7minli{-pdir}..z17tinn--z17toth--cycle;
435 draw_tstem(13,4,srad); % right half
436 fill z18tout..z8minlo{pdir}..{down}(rt x15, y15)--
437 (lft x15, y15){up}..z8minli{-pdir}..z18tinn--cycle;
438 draw_tstem(15,6,srad);
439 ductus:=false;
440 penlabels(1,2,3,4,5,6,7,8,9,14,100);
441 endchar; % end "m"
442
443 cmchar "IMAJ letter n";
444 beginchar("n", 2sb#+hstretch*(7/6x_height#+trijut#),
445 x_height#, 1/2desc_depth#);
446 adjust_fit(0,0);
447 pcshiftx := sb;
448 pickup quill;
449 %% left stem
450 lft x1=pcshiftx+trijut; top y1=h;
451 x2=x1; bot y2=-d;
452 %% right stem
453 rt x3=w-pcshiftx; y3=y1;
454 z4=(x3,0);
455 %% bar
456 z5=(x1,1/3h); z6=(x4,1/6h);
457 %%ductus:=true;
458 if ductus:
459 pickup stylus;
460 fi
461 draw_tstem(1,2,srad); % left stem
462 draw_triserif(1,trijut);
463 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
464 draw_tstem(3,4,srad); % right stem
465 draw_clubbase(3, 4, 1/3, clubjut, clubjut);
466 draw z5--z6; % bar
467 ductus:=false;
468 penlabels(1,2,3,4,5,6,100);
469 endchar; % end "n"
470
471 cmchar "IMAJ letter o";
472 beginchar("o", 2sb#+hstretch*(7/6x_height#),
473 x_height#, 0);
474 adjust_fit(0,0);
475 pcshiftx := sb;
476 pickup quill;
477 lft x1=pcshiftx; rt x3=w-pcshiftx; y1=y3=h/2;
478 x2=x4=w/2; top y2=h+o; bot y4=-o;
479 %%ductus:=true;
480 if ductus:
481 pickup stylus;
482 fi
483 %%%draw z1..z2..z3..z4..cycle;
484 z5=(pcshiftx,-o);
485 obowl(5, w-2pcshiftx, h+2o);
486 fill obouter; unfill obinner;
487 ductus:=false;
488 penlabels(1,2,3,4,5,100);
489 endchar; % end "o"
490
491 cmchar "IMAJ letter p";
492 beginchar("p", 2sb#+hstretch*(8/6x_height#+trijut#),
493 x_height#, desc_depth#);
494 adjust_fit(0,0);
495 pcshiftx := sb;
496 numeric n[];
497 pickup quill;
498 %% stem
499 lft x1=lft x2=pcshiftx+trijut;
500 top y1=1/3h; bot y2=-d;
501 n1 := w - pcshiftx - lft x1; % width of bowl
502 n2 := h+1/4d; % height of bowl
503 z3=(lft x1, -1/4d);
504 obowl(3, n1, n2);
505 %%ductus:=true;
506 if ductus:
507 pickup stylus;
508 fi
509 draw_tstem(1,2,srad); % stem
510 draw_triserif(1,trijut);
511 draw_clubbase(1, 2, 1/3, clubjut, 0);
512 fill lft z1{up}..z3minlo{pdir}..z3maxro{-ppdir}..{-pdir}z3minro--
513 z3minri{pdir}..z3maxri{ppdir}..z3minli{-pdir}..{down}rt z1--
514 cycle;
515 ductus:=false;
516 penlabels(1,2,3,4,5,6,7,8,100);
517 endchar; % end "p"
518
519 cmchar "IMAJ letter q";
520 beginchar("q", 2sb#+hstretch*(x_height#+1/2trijut#),
521 x_height#, 1/2desc_depth#);
522 adjust_fit(0,0);
523 pcshiftx := sb;
524 numeric n[];
525 pickup quill;
526 %% right stem
527 rt x1=w-pcshiftx-1/2trijut; top y1=h;
528 x2=x1; bot y2=-d;
529 z3=(pcshiftx,0);
530 n1 := w; % width of bowl
531 n2 := h; % height of bowl
532 obowl(3, n1, n2);
533 z10o = (rt z1--rt z2) intersectionpoint subpath (0,1) of obouter;
534 z10i = (lft z1--lft z2) intersectionpoint subpath (0,1) of obinner;
535 z20o = (rt z1--rt z2) intersectionpoint subpath (1,2) of obouter;
536 z20i = (lft z1--lft z2) intersectionpoint subpath (1,2) of obinner;
537 %%ductus:=true;
538 if ductus:
539 pickup stylus;
540 fi
541 draw_tstem(1,2,srad); % stem
542 draw_triserif(1,trijut);
543 draw_clubbase(1, 2, 1/3, 0, clubjut);
544 fill z10o..z3minlo{-pdir}..z3maxlo{-ppdir}..z3minro{right}..z20o--
545 z20i..z3minri{-pdir}..z3maxli{ppdir}..z3minli{pdir}..z10i--
546 cycle;
547 ductus:=false;
548 penlabels(0,1,2,3,4,5,6,7,8,100);
549 endchar; % end "q"
550
551 cmchar "IMAJ letter r";
552 beginchar("r", sb#+hstretch*(11/6x_height#+trijut#),
553 x_height#, 1/2desc_depth#);
554 adjust_fit(0,0);
555 pcshiftx := sb;
556 numeric n[];
557 pickup quill;
558 %% stem
559 lft x1=lft x2=pcshiftx+trijut; top y1=h; bot y2=-d;
560 n1 := w-pcshiftx; % width of bowl
561 n2 := 5/6h; % height of bowl
562 z3=(x1-1/2n1, h-n2);
563 obowl(3, n1, n2);
564 z10o=(x1,h); z10i=(x1, y10o-thin);
565 z20o=(x1,y3); z20i=(x20o, y20o+thin);
566 %% arm
567 x4=x1; bot y4=y3;
568 x5=x3maxro; top y5=0;
569 %%rt x6=w; y6=y4;
570 rt x6=w; y6=y2;
571 %%ductus:=true;
572 if ductus:
573 pickup stylus;
574 fi
575 draw_tstem(1,2,srad); % stem
576 draw_triserif(1,trijut);
577 draw_clubbase(1, 2, 1/3, clubjut, 0);
578 fill z10o{right}..z3maxro{-ppdir}..{left}z20o--
579 z20i{right}..z3maxri{ppdir}..{left}z10i--cycle;
580 %%draw z4{right}..z5{right}..{right}z6; % arm
581 draw z4{right}..{right}z6;
582 ductus:=false;
583 penlabels(1,2,3,4,5,6,7,8,9,100);
584 endchar; % end "r"
585
586 cmchar "IMAJ letter s";
587 beginchar("s", 2sb#+hstretch*(x_height#+trijut#),
588 asc_height#, 0);
589 adjust_fit(0,0);
590 numeric n[];
591 pcshiftx := sb;
592 pickup quill;
593 %% stem
594 lft x1=lft x2=pcshiftx+trijut; top y1=h/ascratio; bot y2=0;
595 n1 := w; % width of bowl
596 n2 := 2(h-y1); % height of bowl
597 z3=(lft x1, y1-1/2n2);
598 obowl(3, n1, n2);
599 z4=(2w,2h);
600 z10o = (z3--z4) intersectionpoint subpath (0,1) of obouter;
601 z10i = (z3--z4) intersectionpoint subpath (0,1) of obinner;
602 %%ductus:=true;
603 if ductus:
604 pickup stylus;
605 fi
606 draw_tstem(1,2,srad); % stem
607 draw_triserif(1,trijut);
608 draw_clubbase(1, 2, 1/3, clubjut, clubjut);
609 fill rt z1{up}..z3minli{pdir}..z10i--
610 z10o..z3minlo{-pdir}..{down}lft z1--cycle;
611 ductus:=false;
612 penlabels(1,2,3,4,5,6,7,11,17,26,27,28,100);
613 endchar; % end "s"
614
615 cmchar "IMAJ letter t";
616 beginchar("t", 2sb#+hstretch*(4/3x_height#),
617 x_height#, 0);
618 adjust_fit(0,0);
619 pcshiftx := sb;
620 numeric n[];
621 pickup quill;
622 %% bar
623 lft x1 = pcshiftx; y1=h; rt x2=w-pcshiftx; y2=y1;
624 n1 := w; % width of bowl
625 n2 := h; % height of bowl
626 z3=(pcshiftx+thick,0);
627 obowl(3, n1, n2);
628 z5=(x1+w, 0);
629 z20o = (z1--z5) intersectionpoint subpath (1,2) of obouter;
630 z20i = (z1--z5) intersectionpoint subpath (1,2) of obinner;
631 z10o = (x3minlo, top y1);
632 z10i = (x3minlo, bot y1);
633 %%ductus:=true;
634 if ductus:
635 pickup stylus;
636 fi
637 draw z1--z2; % bar
638 draw_utriangle(1, thick);
639 draw_triangle(2, thick);
640 fill z10o{left}..z3maxlo{-ppdir}..z3minro{pdir}..z20o--
641 z20i..z3minri{-pdir}..z3maxli{ppdir}..z10i{right}--cycle;
642 ductus:=false;
643 penlabels(1,2,3,4,5,6,11,12,100);
644 endchar; % end "t"
645
646 cmchar "IMAJ letter u";
647 beginchar("u", 2sb#+hstretch*(7/6x_height#+1/2trijut#),
648 x_height#, 0);
649 adjust_fit(0,0);
650 pcshiftx := sb;
651 numeric n[];
652 pickup quill;
653 %% right stem
654 rt x1 = rt x2 = w-pcshiftx-1/2trijut;
655 y1=h; y2=0;
656 z1'=(x1-1/2thick,2h); z2'=(x1',-h);
657 %% bowl
658 n1 := w; % width of bowl
659 n2 := 4/3h; % height of bowl
660 z3=(pcshiftx,0);
661 obowl(3, n1, n2);
662 z4=(pcshiftx,h); z5=(w,y4);
663 z10o = (z4--z5) intersectionpoint subpath (3,4) of obouter;
664 z10i = (z4--z5) intersectionpoint subpath (3,4) of obinner;
665 z10'=1/2[z10o,z10i];
666 z10=(x10i,y1);
667 z20o = (z1'--z2') intersectionpoint subpath (1,3) of obouter;
668 z20i = (z1'--z2') intersectionpoint subpath (1,3) of obinner;
669 %%ductus:=true;
670 if ductus:
671 pickup stylus;
672 fi
673 draw_tstem(1,2,srad); % stem
674 draw_triserif(1,trijut);
675 draw_clubbase(1, 2, 1/3, 0, clubjut);
676 fill z10o..z3maxlo{-ppdir}..z3minro{pdir}..z20o--
677 z20i..z3minri{-pdir}..z3maxli{ppdir}..z10i--cycle;
678 draw_triserif(10,trijut); % serif on bowl
679 ductus:=false;
680 penlabels(1,2,3,4,5,6,7,8,9,11,16,100);
681 endchar; % end "u"
682
683 cmchar "IMAJ letter v";
684 beginchar("v", 2sb#+hstretch*(x_height#+trijut#),
685 x_height#, 0);
686 adjust_fit(0,0);
687 pcshiftx := sb;
688 pickup quill;
689 numeric midx; midx:= pcshiftx;
690 lft x1=midx+trijut; top y1=h;
691 x2=x1; y2=h/2;
692 rt x4=w-pcshiftx; y4=y2;
693 x3=0.5[x2,x4]; bot y3=0;
694 x5=x4-trijut; y5=y1;
695 %%ductus:=true;
696 if ductus:
697 pickup stylus;
698 fi
699 draw_triserif(1,trijut);
700 %%draw_triserif(5,trijut);
701 draw z1--z2{down}..z3{right}..z4{up}..z5;
702 ductus:=false;
703 penlabels(1,2,3,4,5,11,100);
704 endchar; % end "v"
705
706 cmchar "IMAJ letter w";
707 beginchar("w", 2sb#+hstretch*(5/3x_height#+trijut#),
708 x_height#, 0);
709 adjust_fit(0,0);
710 pcshiftx := sb;
711 pickup quill;
712 numeric midx; midx:= w/2-trijut;
713 lft x1=midx+trijut; top y1=h;
714 x2=x1; y2=h/2;
715 rt x4=w-pcshiftx; y4=y2;
716 x3=0.5[x2,x4]; bot y3=0;
717 x5=x4-trijut; y5=y1;
718 lft x6=pcshiftx+trijut;
719 top y6=h;
720 %%lft x7=pcshiftx; y7=y2;
721 x7=x6; y7=y2;
722 x8=0.5[x7,x1]; y8=y3;
723 x15=0.5[x8,x1]; y15=y8;
724 z15'=z15 shifted (w*pdir);
725 x2'=x2; y2'=y15;
726 path p[];
727 p1=z1--z2';
728 p2=z15--z15';
729 z9= p2 intersectionpoint p1;
730 pair vec[];
731 p3=z6..z7{down}..{right}z8;
732 vec3 = direction 0 of p3;
733 z16=z6 shifted vec3;
734 %%ductus:=true;
735 if ductus:
736 pickup stylus;
737 fi
738 draw_triserif(1,trijut); % right half
739 draw z1--z2{down}..z3{right}..z4{up}..z5;
740 draw_triserif(6,trijut); % left half
741 draw z6--z7{down}..z8{right}..z9;
742 ductus:=false;
743 penlabels(1,2,3,4,5,6,7,8,9,11,16,100);
744 endchar; % end "w"
745
746 cmchar "IMAJ letter x";
747 beginchar("x", 2sb#+hstretch*(16/6x_height#),
748 x_height#, desc_depth#);
749 adjust_fit(0,0);
750 numeric n[];
751 pcshiftx := sb;
752 pickup quill;
753 n1 := w-2pcshiftx; % total width
754 n2 := thick; % triangle side
755 %% diag top left to bottom right
756 lft x1=pcshiftx; bot y1=2/3h;
757 x2=pcshiftx+1/7n1; top y2=h;
758 x5=pcshiftx+11/14n1; bot y5=-1/4d;
759 rt x6=pcshiftx+n1; top y6=1/6h;
760 %% diag bottom left to top right
761 x10=x1; bot y10=-d;
762 x50=pcshiftx+9/14n1; top y50=h;
763 rt x60=x5; bot y60=2/3h;
764 x40=pcshiftx+8/14n1; y40=h;
765 %% triangle
766 z100=(lft x10, bot y10);
767 x101=x100+n2; z101=whatever[z100,z40];
768 x102=x100; y102=1/2[y100,y101]+n2;
769 %%ductus:=true;
770 if ductus:
771 pickup stylus;
772 fi
773 draw z1..z2{right}..z5{right}..z6; % top left to bottom right
774 draw z10{z40-z10}..z50{right}..z60; % bottom left to top right
775 fill z100--z101--z102--cycle; % triangle
776 ductus:=false;
777 penlabels(1,2,3,4,5,6,7,8,100);
778 endchar; % end "x"
779
780 cmchar "IMAJ letter y";
781 beginchar("y", 2sb#+hstretch*(x_height#),
782 x_height#, desc_depth#);
783 adjust_fit(0,0);
784 pcshiftx := u;
785 pickup quill;
786 %% main stroke
787 rt x1=w-pcshiftx; top y1=h;
788 lft x3=pcshiftx; y3=1/2h;
789 x4=x1; y4=0;
790 x2=2/3[x3,x1]; bot y2=h;
791 lft x5=1/2[x3,x4]; bot y5=-d;
792 %% arm
793 z101=1/2[z3,z4];
794 z103=(x1,y3);
795 %%ductus:=true;
796 if ductus:
797 pickup stylus;
798 fi
799 draw z1..z2{left}..z3{down}..z4{down}..z5; % main stroke
800 draw z101..z103{right}; % arm
801 ductus:=false;
802 penlabels(1,2,3,4,5,6,7,8,9,10,100);
803 endchar; % end "y"
804
805 cmchar "IMAJ letter z";
806 beginchar("z", 2sb#+hstretch*(9/6x_height#),
807 x_height#, 0);
808 adjust_fit(0,0);
809 numeric n[];
810 pcshiftx := sb;
811 pickup quill;
812 %% top bar
813 n10 := w-2pcshiftx; % letter width
814 lft x1=pcshiftx; y1=h;
815 rt x2=pcshiftx+2/3n10; y2=y1;
816 %% diagonal
817 x3=x1; bot y3=0;
818 %% bowl
819 n1 := 2/3n10; % width of bowl
820 n2 := 5/6h; % height of bowl
821 z4=(w-pcshiftx-n1, 0);
822 obowl(4, n1, n2);
823 z5'=(0,1/4n2); z6'=(x4obc,y5');
824 z20o = (z5'--z6') intersectionpoint obouter;
825 z20i = (z5'--z6') intersectionpoint obinner;
826 z7'=(0,2/3n2); z8'=(x6',y7');
827 z10o = whatever[lft z3, lft z2] = whatever[z7',z8'];
828 z10i = whatever[rt z3, rt z2] = whatever[z7',z8'];
829 %%ductus:=true;
830 if ductus:
831 pickup stylus;
832 fi
833 draw z1--z2; % top bar
834 draw_utriangle(1,thick);
835 draw z2--z3; % diagonal
836 fill z20o..z4minro{pdir}..z4maxro{ppdir}..z4minlo{-pdir}..{z3-z2}z10o--
837 z10i{z2-z3}..z4minli{pdir}..z4maxri{-ppdir}..z4minri{-pdir}..z20i--
838 cycle;
839 ductus:=false;
840 penlabels(1,2,3,4,5,6,10o,10i,20o,20i,100);
841 endchar; % end "z"
842