Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/hmintitle.mf

raw
1 %%
2 %% This is file `hmintitle.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% humanist.dtx (with options: `mfd')
8 %%
9 %% Author: Peter Wilson (CUA) now at [email protected]
10 %% (or [email protected])
11 %% Copyright 2002, 2003 Peter R. Wilson
12 %%
13 %% This work may be distributed and/or modified under the
14 %% conditions of the LaTeX Project Public License, either
15 %% version 1.3 of this license or (at your option) any
16 %% later version.
17 %% The latest version of the license is in
18 %% http://www.latex-project.org/lppl.txt
19 %% and version 1.3 or later is part of all distributions of
20 %% LaTeX version 2003/06/01 or later.
21 %%
22 %% This work has the LPPL maintenance status "author-maintained".
23 %%
24 %% This work consists of the files listed in the README file.
25 %%
26 def makebox(text rule) =
27 for y=0,half_height,cap_height,body_height,x_height,-desc_depth,-body_depth:
28 rule((l,y)t_,(r,y)t_); endfor % horizontals
29 for x=l,r: rule((x,-body_depth)t_,(x,body_height)t_); endfor % verticals
30 for x=u*(1+floor(1/u)) step u until r-1:
31 rule((x,-body_depth)t_,(x,body_height)t_); endfor % more verticals
32 if charic<>0:
33 rule((r+charic*pt,h.o_),(r+charic*pt,.5h.o_)); fi % italic correction
34 enddef;
35
36
37 def proofpcbb(suffix $)(expr xoff, yoff) =
38 if proofing > 0:
39 x$bl = x$ - xoff; y$bl = y$ - yoff; % Bottom Left Hand Corner
40 z$br = (x$bl+side, y$bl); % BRHC
41 z$tr = (x$bl+side, y$bl+side); % TRHC
42 z$tl = (x$bl, y$bl+side); % TLHC
43 z$bc = 1/2[z$bl,z$br]; z$tc = 1/2[z$tl,z$tr]; % horizontal mid points
44 pair hc, vc;
45 hc = (2u,0); vc = (0,2u);
46 pickup pensquare scaled 2;
47 for s = z$bl, z$br, z$tr, z$tl, z$bc, z$tc:
48 draw s-hc--s+hc;
49 draw s-vc--s+vc;
50 endfor
51 fi
52 enddef;
53
54
55 def humanist_font_setup= % contains special stuff for humanist fonts
56 define_pixels(side,half_height,carol_height,comma_width);
57 define_pixels(u,dot_size,letter_size,cap_height,width_adj,serif_fit,
58 cap_serif_fit,jut,clubjut,cap_jut,trijut);
59 define_pixels(fig_width);
60 define_whole_pixels(letter_fit,sb);
61 define_whole_vertical_pixels(body_height,asc_height,cap_height,x_height,
62 desc_depth,body_depth,fig_height);
63 define_corrected_pixels(o);
64 define_blacker_pixels(thick,thin);
65 let adjust_fit = normal_adjust_fit;
66 pickup pencircle scaled thin;
67 stylus:=savepen;
68 pickup pencircle scaled (1.5thin);
69 thickstylus:=savepen;
70 pickup pencircle xscaled thick yscaled thin rotated pangle;
71 quill:=savepen;
72
73 pickup pencircle xscaled 3/4thick yscaled thin rotated pangle;
74 threequarterquill := savepen;
75
76 pickup pencircle xscaled 1/2thick yscaled thin rotated pangle;
77 halfquill := savepen;
78
79 pickup pencircle xscaled 1/4thick yscaled thin rotated pangle;
80 quarterquill := savepen;
81
82 numeric pcshiftx#; % x value of LHS of box wrt origin of char box
83 define_pixels(pcshiftx);
84 numeric sqxside#; % x size of the square
85 numeric sqyside#; % y size of the square
86 define_pixels(sqxside,sqyside);
87
88 enddef; % end of humanist_font_setup
89
90 boolean ductus;
91 ductus:=false;
92 numeric qhor, qvert;
93 qhor:=cosd(pangle); qvert:=sind(pangle);
94 pair pdir; pdir=dir(pangle);
95 pair ppdir; ppdir=dir(pangle+90);
96
97 def draw_serif(suffix $, $$)(expr fr)=
98 numeric beta, ajut, bjut;
99 beta=1-fr;
100 ajut=fr*jut; bjut=beta*jut;
101 pair vec[]; vec1=unitvector(z$$-z$);
102 vec2=ajut*vec1;
103 z$a=z$ shifted vec2;
104 z$b=z$a rotatedaround (z$,-90);
105 boolean top_serif;
106 if y$>y$$:
107 top_serif := true;
108 z$c=z$b shifted (-bjut*pdir);
109 else:
110 top_serif:=false;
111 z$c=z$b shifted (bjut*pdir);
112 fi
113 if top_serif:
114 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
115 else:
116 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
117 fi
118 labels($a,$b,$c);
119 enddef; % end of draw_serif
120
121
122 def draw_roundserif(suffix $, $$)(expr fr)=
123 draw_serif($, $$, fr);
124 undraw z$--z$a;
125 enddef; % end of draw_roundserif
126
127
128 def draw_flatserif(suffix $, $$)(expr fr)=
129 numeric beta, ajut, bjut;
130 beta=1-fr;
131 ajut=fr*jut; bjut=beta*jut;
132 pair vec[]; vec1=unitvector(z$$-z$);
133 vec2=ajut*vec1;
134 z$a=z$ shifted vec2;
135 %%% z$b=z$a rotatedaround (z$,-90);
136 boolean top_serif;
137 if y$>y$$:
138 top_serif := true;
139 z$c=z$ shifted (-jut*pdir);
140 else:
141 top_serif:=false;
142 z$c=z$ shifted (jut*pdir);
143 fi
144 z$b = fr[z$,z$c];
145 draw z$a--z$;
146 if top_serif:
147 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
148 else:
149 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
150 fi
151 labels($a,$b,$c);
152 enddef; % end of draw_flatserif
153
154
155 def draw_clubserif(suffix $, $$)(expr fr)=
156 numeric beta, ajut, bjut;
157 %% beta=1-fr;
158 ajut=clubjut; bjut=beta*jut;
159 pair vec[]; vec1=unitvector(z$$-z$);
160 %% vec2=ajut*vec1;
161 %% z$a=z$ shifted vec2;
162 boolean top_serif;
163 if y$>y$$:
164 top_serif := true;
165 z$c=z$ shifted (-clubjut*pdir);
166 else:
167 top_serif:=false;
168 z$c=z$ shifted (clubjut*pdir);
169 fi
170 z$a = fr[z$,z$$];
171 draw z$c..z$a{vec1};
172 labels($a,$b,$c);
173 enddef; % end of draw_clubserif
174
175
176 def draw_triserif(suffix $)(expr tj)=
177 pen oldpen; oldpen:=currentpen;
178 pickup quill;
179 x$ts1'=lft x$; y$ts1'=bot y$;
180 pickup stylus;
181 lft x$ts1=x$ts1'; bot y$ts1=y$ts1';
182 x$ts2=x$ts1-tj; z$ts2=whatever[z$,z$ts1];
183 x$ts3=x$ts1; y$ts3=y$ts2-tj;
184 pickup stylus;
185 %% filldraw z$ts1--z$ts2--z$ts3--cycle;
186 filldraw z$--z$ts2--z$ts3--cycle;
187 pickup oldpen;
188 labels($ts1,$ts2,$ts3);
189 enddef; % end of draw_triserif
190
191
192 def draw_istem(suffix $, $$)(expr fr)=
193 draw_serif($, $$, fr); % top serif
194 draw_serif($$, $, fr); % bottom serif
195 draw z$a--z$$a; % the stem
196 enddef; % end of draw_istem
197
198
199 def draw_tstem(suffix $, $$)(expr fr)=
200 %% draw_serif($$, $, fr); % the serif
201 %% draw z$--z$$a; % the stem
202 draw z$--z$$;
203 enddef; % end of draw_tstem
204
205
206 def draw_tlserif(suffix $, $$)(expr fr)=
207 draw_serif($, $$, fr); % the serif
208 draw z$a--z$$; % the stem
209 enddef; % end of draw_tlserif
210
211
212 def draw_flick(suffix $)(expr rise, fall, fjut)=
213 rt x$b = x1+fjut; top y$b=y$-fall;
214 x$a=0.5[x$,x$b]; top y$a=y$+rise;
215 draw z$..z$a..z$b;
216 labels($a,$b);
217 enddef; % end of draw_flick
218
219
220 def draw_wave(suffix $,$$)(expr f)=
221 x$wl=x$; y$wl=y$-f;
222 x$wr=x$$; y$wr=y$$+f;
223 z$wc=0.5[z$wl,z$wr];
224 draw z$wl{pdir}..z$wc{right}..{pdir}z$wr;
225 labels($wl,$wc,$wr);
226 enddef; % end of draw_wave
227
228 def draw_tail(suffix $)(expr fj)=
229 pen oldpen; oldpen:=currentpen;
230 pickup quill;
231 x$tl' = lft x$; y$tl=bot y$;
232 pickup stylus;
233 lft x$tl=x$tl';
234 x$tb=x$tl-fj; bot y$tb=y$tl-1/2desc_depth;
235 filldraw z${down}..{-pdir}z$tb & z$tb{pdir}..{up}z$tl--cycle;
236 pickup oldpen;
237 labels($tb,$tl);
238 enddef; % end of draw_tail
239
240 def draw_triangle(suffix $)(expr sz)=
241 pen oldpen; oldpen:=currentpen;
242 pickup stylus;
243 x$t1=x$-sz/2; x$t3=x$+sz/2;
244 y$t1=y$t3=y$;
245 x$t2=x$; y$t2=y$-0.9sz; % approx sqrt(3)/2
246 filldraw z$t1--z$t2--z$t3--cycle;
247 pickup oldpen;
248 labels($t1,$t2,$t3);
249 enddef; % end of draw_triangle
250
251 def draw_utriangle(suffix $)(expr sz)=
252 pen oldpen; oldpen:=currentpen;
253 pickup stylus;
254 x$t1=x$-sz/2; x$t3=x$+sz/2;
255 y$t1=y$t3=y$;
256 x$t2=x$; y$t2=y$+0.9sz; % approx sqrt(3)/2
257 filldraw z$t1--z$t2--z$t3--cycle;
258 pickup oldpen;
259 labels($t1,$t2,$t3);
260 enddef; % end of draw_utriangle
261
262 def draw_rtriangle(suffix $)(expr sz)=
263 pen oldpen; oldpen:=currentpen;
264 pickup stylus;
265 x$t1=x$-sz; rt x$t3=x$;
266 y$t1=y$t3=y$;
267 x$t2=x$t3; y$t2=y$-sz;
268 filldraw z$t1--z$t2--z$t3--cycle;
269 pickup oldpen;
270 labels($t1,$t2,$t3);
271 enddef; % end of draw_rtriangle
272
273 def draw_rutriangle(suffix $)(expr sz)=
274 pen oldpen; oldpen:=currentpen;
275 pickup stylus;
276 x$t1=x$-sz; rt x$t3=x$;
277 y$t1=y$t3=y$;
278 x$t2=x$t3; y$t2=y$+sz;
279 filldraw z$t1--z$t2--z$t3--cycle;
280 pickup oldpen;
281 labels($t1,$t2,$t3);
282 enddef; % end of draw_rutriangle
283
284 def draw_fork(suffix $, $$)(expr sz)=
285 pen oldpen; oldpen:=currentpen;
286 pickup quill;
287 x$f1'=lft x$; y$f1'=bot y$;
288 x$f3'=rt x$; y$f3'=top y$;
289 pickup stylus;
290 lft x$f1=x$f1'; bot y$f1=y$f1';
291 rt x$f3=x$f3'; y$f3-y$=2*(y$-y$f1);
292 rt x$f2=x$$-sz; bot y$f2=y$$;
293 rt x$f4= rt x$f5=x$$;
294 bot y$f5=y$$-sz; top y$f4=y$$+1/2sz;
295 filldraw z$f1--z$f2--z$f3--cycle; % the line
296 draw z$f2{right}..z$f4; % upper fork
297 draw z$f2{right}..z$f5; % lower fork
298 pickup oldpen;
299 labels($f1,$f2,$f3,$f4,$f5);
300 enddef; % end of draw_fork
301
302 def draw_urswish(suffix $, $$)=
303 pen oldpen; oldpen:=currentpen;
304 pickup quill;
305 rt x$$s1=x$$-thick; top y$$s1=y$$;
306 rt x$$s2=x$$;
307 %% x$$s3=x$$-thick;
308 lft x$$s3=x$$s1;
309 bot y$$s3=y$$-thick; y$$s2=0.5[y$$s1,y$$s3];
310 %% draw z$---z$$s1{right}..z$$s2{down}..{-pdir}z$$s3;
311 draw z$..z$$s1{pdir}..z$$s2{down};
312 labels($$s1,$$s2,$$s3);
313 enddef; % end of draw_urswish
314
315 def bowl_stem(suffix $, $$)=
316 x$'=0.5[x$,x$$]; y$'=y$; % the mid-point
317 z$''=z$' shifted (thick*pdir);
318 x$i=x$$; z$i=whatever[z$',z$''];
319 labels($',$i);
320 enddef; % end of bowl_stem
321
322 def draw_clubbase(suffix $, $$)(expr st, lft, rt)=
323 z$$l = z$$ shifted (lft*thick*(-pdir));
324 z$$r = z$$ shifted (rt*thick*(pdir));
325 z$$t = st[z$$,z$];
326 draw z$$t{z$$-z$}..z$$l--z$$r..{z$-z$$}z$$t;
327 labels($$t,$$l,$$r);
328 enddef; % end of draw_clubbase
329
330
331 def draw_pdot(suffix $)(expr sz)=
332 z$s = z$ shifted (0.5sz*left);
333 z$t = z$ shifted (0.5sz*up);
334 z$u = z$s shifted (sz*right);
335 z$v = z$t shifted (sz*down);
336 pickup stylus;
337 filldraw z$s--z$t--z$u--z$v--cycle;
338 labels($s,$t,$u,$v);
339 enddef; % end of draw_pdot
340
341
342 def draw_pcomma(suffix $)(expr sz, ar)=
343 z$s = z$ shifted (0.5sz*left);
344 z$t = z$s shifted (sz*right);
345 x$v=x$s-ar; y$v=y$s-2ar;
346 z$u = z$v shifted (sz*right);
347 z$sv = (x$s, 1/3[y$s,y$v]);
348 z$tu = (x$t, y$sv);
349 z$uv = 1/3[z$u,z$v];
350 z$vu = 1/3[z$v,z$u];
351 pickup stylus;
352 %% filldraw z$s--z$t--z$u--z$v--cycle;
353 filldraw z$s--z$t--z$tu{down}..{left}z$uv--z$vu{right}..{up}z$sv--cycle;
354 labels($s,$t,$u,$v);
355 enddef; % end of draw_pcomma
356
357
358 def draw_plq(suffix $)(expr sz, ar)=
359 z$s = z$ shifted (0.5sz*left);
360 z$t = z$s shifted (sz*right);
361 x$v=x$s+ar; y$v=y$s-2ar;
362 z$u = z$v shifted (sz*right);
363 z$sv = (x$s, 1/3[y$s,y$v]);
364 z$tu = (x$t, y$sv);
365 z$uv = 1/3[z$u,z$v];
366 z$vu = 1/3[z$v,z$u];
367 pickup stylus;
368 %% filldraw z$s--z$t--z$u--z$v--cycle;
369 filldraw z$s--z$t--z$tu{down}..{right}z$uv--z$vu{left}..{up}z$sv--cycle;
370 labels($s,$t,$u,$v);
371 enddef; % end of draw_plq
372
373
374 path obouter, obinner, obfirst, obsecond;
375 def offsetbowl(suffix $)(expr sx, sy, fx, fy)=
376 numeric inx, iny, cx, cy;
377 pair pt[];
378 path pth[];
379 inx := 1/2thick*cosd(pangle); iny := 1/2thick*sind(pangle);
380 cx := x$+fx*sx; cy := y$+fy*sy;
381 z$obc = (cx,cy);
382 if pangle = 90:
383 z$wt=(x$+1/2thin, cy);
384 z$et=(x$+sx-1/2thin, cy);
385 else:
386 z$wt=(x$+inx, cy);
387 z$et=(x$+sx-inx, cy);
388 penpos$wt(thick,pangle);
389 penpos$et(thick,pangle);
390 fi
391 if pangle = 0:
392 z$nh=(cx, y$+sy-1/2thin);
393 z$sh=(cx, y$+1/2thin);
394 else:
395 z$nh=(cx, y$+sy-iny);
396 z$sh=(cx, y$+iny);
397 penpos$nh(thick,pangle);
398 penpos$sh(thick,pangle);
399 fi
400 obfirst := z$nh{right}..z$et{down}..z$sh{left}..z$wt{up}..cycle;
401 if pangle = 90:
402 z$minl = z$wt; z$maxr = z$nh; z$minr = z$et; z$maxl = z$sh;
403 else:
404 if pangle = 0:
405 z$minl = z$nh; z$maxr = z$et; z$minr = z$sh; z$maxl = z$wt;
406 else:
407 z$minl = directionpoint dir(pangle) of obfirst;
408 z$minr = directionpoint -dir(pangle) of obfirst;
409 pt1 := z$minr - z$minl; % direction
410 pt2 := (- ypart pt1, xpart pt1); % perpendicular
411 pt3 := 1/2[z$minl, z$minr];
412 pt4 := pt3 shifted pt2;
413 pt5 := pt3 shifted -pt2;
414 pth1 := pt3--pt4;
415 pth2 := pt3--pt5;
416 z$maxr = pth1 intersectionpoint obfirst;
417 z$maxl = pth2 intersectionpoint obfirst;
418 \fi
419 \fi
420 penpos$minl(thin,pangle+90);
421 penpos$maxr(thick,pangle);
422 penpos$minr(thin,pangle+90);
423 penpos$maxl(thick,pangle);
424 obsecond := z$minl..z$maxr..z$minr..z$maxl..cycle;
425 z$minlo = z$minl.r; z$maxro = z$maxr.r;
426 z$minro = z$minr.l; z$maxlo = z$maxl.l;
427 obouter := z$minlo{dir(pangle)}...z$maxro...z$minro{-dir(pangle)}...z$maxlo...cycle;
428 z$minli = z$minl.l; z$maxri = z$maxr.l;
429 z$minri = z$minr.r; z$maxli = z$maxl.r;
430 obinner := z$minli...z$maxri...z$minri...z$maxli...cycle;
431 labels($obc, $nh, $et, $sh, $wt);
432 labels($minl, $maxr, $minr, $maxl);
433 labels($minlo, $maxro, $minro, $maxlo);
434 labels($minli, $maxri, $minri, $maxli);
435 enddef;
436
437
438 def obowl(suffix $)(expr sx, sy)=
439 offsetbowl($, sx, sy, 1/2, 1/2);
440 enddef;
441
442
443 primarydef v scalarprod w =
444 (xpart v * ypart w - ypart v * xpart w)
445 enddef;
446
447
448 def tangentpoint(suffix $)(expr pth)=
449 pair vecll, veclr, veclm; % "tangent" line directions
450 numeric pl, pr, pm; % path parameter values
451 pair vecpl, vecpr, vecpm; % path directions
452 pair ptl, ptr, ptm; % path points
453 numeric sl, sr, sm; % scalar products of path/line directions
454 numeric stpsize; % size of current binary step
455 numeric tantol; % tolerance
456 boolean wtest; % a boolean
457
458 tantol := eps;
459 pl:=0; pr:=length pth; pm:=0.5(pl+pr); stpsize:=pr-pl;
460 ptl := point pl of pth;
461 ptm := point pm of pth;
462 ptr := point pr of pth;
463 vecll := unitvector (z$-ptl);
464 veclm := unitvector (z$-ptm);
465 veclr := unitvector (z$-ptr);
466 vecpl := unitvector (direction pl of pth);
467 vecpm := unitvector (direction pm of pth);
468 vecpr := unitvector (direction pr of pth);
469 sl := vecll scalarprod vecpl;
470 sm := veclm scalarprod vecpm;
471 sr := veclr scalarprod vecpr;
472 wtest := (stpsize < tantol) or (sl*sr > 0) or
473 (abs sl < tantol) or (abs sm < tantol) or (abs sr < tantol);
474 if wtest:
475 if (stpsize < tantol):
476 z$tan=(0,0);
477 errmessage("No tangent; path too short");
478 else:
479 if (sl*sr > 0):
480 z$tan=(0,0);
481 errmessage("No tangent; end products have the same sign");
482 else:
483 if (abs sl < tantol):
484 z$tan=ptl;
485 else:
486 if (abs sm < tantol):
487 z$tan=ptm;
488 else:
489 z$tan=ptr;
490 fi
491 fi
492 fi
493 fi
494 else:
495 forever:
496 if (sl*sm < 0): % opposite signs, look between pl & pm
497 pr:=pm; pm:=0.5(pr+pl);
498 vecpr := vecpm; veclr := veclm; sr:=sm;
499 else:
500 pl:=pm; pm:=0.5(pr+pl);
501 vecpl:=vecpm; vecll:=veclm; sl:=sm;
502 fi
503 stpsize:=pr-pl;
504 ptm := point pm of pth;
505 veclm := unitvector (z$-ptm);
506 vecpm := unitvector (direction pm of pth);
507 sm := veclm scalarprod vecpm;
508 wtest := (stpsize < tantol) or (abs sm < tantol);
509 if wtest:
510 if (abs sm < tantol):
511 z$tan = ptm;
512 else:
513 z$tan = ptm;
514 %%%%%% errmessage("Warning: tangent approximated");
515 fi
516 fi
517 exitif wtest;
518 endfor
519 fi
520 enddef;
521
522
523 font_coding_scheme:="ASCII minuscules and punctuation";
524 mode_setup;
525 humanist_font_setup;
526
527
528 input hminl; % lower case
529 input hminu; % capitals
530 input hminpunct; % punctuation
531 input hminlig; % the several dashes
532 input hmindig; % arabic digits
533
534
535 font_slant slant; font_x_height x_height#;
536 if monospace:
537 font_normal_space vstretch*9u#; % no stretching or shrinking
538 font_quad vstretch*18u#;
539 font_extra_space vstretch*9u#;
540 else:
541 font_normal_space vstretch*6u#+2letter_fit#;
542 font_normal_stretch vstretch*3u#; font_normal_shrink vstretch*2u#;
543 font_quad vstretch*18u#+4letter_fit#;
544 font_extra_space vstretch*2u#;
545
546
547 fi
548
549 bye.
550
551 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
552 kks#:=-4u#; kkx#:=-1.5u#; kkj#:=-2u#; kkr#:=-5u#; kkrs#:=-2u#; kkrl#:=-8u#;
553 ligtable "s":
554 "a" kern kks#, "A" kern kks#,
555 "c" kern kks#, "C" kern kks#,
556 "d" kern kks#, "D" kern kks#,
557 "e" kern kks#, "E" kern kks#,
558 "f" kern kks#, "F" kern kks#,
559 "g" kern kks#, "G" kern kks#,
560 "i" kern kks#, "I" kern kks#,
561 "j" kern kks#, "J" kern kks#,
562 "k" kern kks#, "K" kern kks#,
563 "m" kern kks#, "M" kern kks#,
564 "n" kern kks#, "N" kern kks#,
565 "o" kern kks#, "O" kern kks#,
566 "p" kern kks#, "P" kern kks#,
567 "q" kern kks#, "Q" kern kks#,
568 "r" kern kks#, "R" kern kks#,
569 "t" kern kks#, "T" kern kks#,
570 "u" kern kks#, "U" kern kks#,
571 "v" kern kks#, "V" kern kks#,
572 "w" kern kks#, "W" kern kks#,
573 "x" kern kks#, "X" kern kks#,
574 "y" kern kks#, "Y" kern kks#,
575 "z" kern kks#, "Z" kern kks#;
576
577 ligtable "S":
578 "a" kern kks#, "A" kern kks#,
579 "c" kern kks#, "C" kern kks#,
580 "d" kern kks#, "D" kern kks#,
581 "e" kern kks#, "E" kern kks#,
582 "f" kern kks#, "F" kern kks#,
583 "g" kern kks#, "G" kern kks#,
584 "i" kern kks#, "I" kern kks#,
585 "j" kern kks#, "J" kern kks#,
586 "k" kern kks#, "K" kern kks#,
587 "m" kern kks#, "M" kern kks#,
588 "n" kern kks#, "N" kern kks#,
589 "o" kern kks#, "O" kern kks#,
590 "p" kern kks#, "P" kern kks#,
591 "q" kern kks#, "Q" kern kks#,
592 "r" kern kks#, "R" kern kks#,
593 "t" kern kks#, "T" kern kks#,
594 "u" kern kks#, "U" kern kks#,
595 "v" kern kks#, "V" kern kks#,
596 "w" kern kks#, "W" kern kks#,
597 "x" kern kks#, "X" kern kks#,
598 "y" kern kks#, "Y" kern kks#,
599 "z" kern kks#, "Z" kern kks#;
600
601 ligtable "x":
602 "a" kern kkx#, "A" kern kkx#,
603 "b" kern kkx#, "B" kern kkx#,
604 "c" kern kkx#, "C" kern kkx#,
605 "d" kern kkx#, "D" kern kkx#,
606 "e" kern kkx#, "E" kern kkx#,
607 "g" kern kkx#, "G" kern kkx#,
608 "j" kern kkx#, "J" kern kkx#,
609 "l" kern kkx#, "L" kern kkx#,
610 "o" kern kkx#, "O" kern kkx#,
611 "q" kern kkx#, "Q" kern kkx#,
612 "t" kern kkx#, "T" kern kkx#,
613 "u" kern kkx#, "U" kern kkx#,
614 "v" kern kkx#, "V" kern kkx#,
615 "w" kern kkx#, "W" kern kkx#,
616 "y" kern kkx#, "Y" kern kkx#;
617
618 ligtable "X":
619 "a" kern kkx#, "A" kern kkx#,
620 "b" kern kkx#, "B" kern kkx#,
621 "c" kern kkx#, "C" kern kkx#,
622 "d" kern kkx#, "D" kern kkx#,
623 "e" kern kkx#, "E" kern kkx#,
624 "g" kern kkx#, "G" kern kkx#,
625 "j" kern kkx#, "J" kern kkx#,
626 "l" kern kkx#, "L" kern kkx#,
627 "o" kern kkx#, "O" kern kkx#,
628 "q" kern kkx#, "Q" kern kkx#,
629 "t" kern kkx#, "T" kern kkx#,
630 "u" kern kkx#, "U" kern kkx#,
631 "v" kern kkx#, "V" kern kkx#,
632 "w" kern kkx#, "W" kern kkx#,
633 "y" kern kkx#, "Y" kern kkx#;
634
635 ligtable "a": "A":
636 "b": "B":
637 "c": "C":
638 "d": "D":
639 "e": "E":
640 "h": "H":
641 "i": "I":
642 "k": "K":
643 "l": "L":
644 "m": "M":
645 "n": "N":
646 "o": "O":
647 "p": "P":
648 "t": "T":
649 "u": "U":
650 "v": "V":
651 "w": "W":
652 "z": "Z":
653 "j" kern kkj#, "J" kern kkj#;
654
655 ligtable "r":
656 "a" kern kkr#, "A" kern kkr#,
657 "b" kern kkr#, "B" kern kkr#,
658 "c" kern kkr#, "C" kern kkr#,
659 "d" kern kkr#, "D" kern kkr#,
660 "e" kern kkr#, "E" kern kkr#,
661 "f" kern kkrs#, "F" kern kkrs#,
662 "g" kern kkrs#, "G" kern kkrs#,
663 "h" kern kkr#, "H" kern kkr#,
664 "i" kern kkr#, "I" kern kkr#,
665 "j" kern kkj#, "J" kern kkj#,
666 "k" kern kkrs#, "K" kern kkrs#,
667 "l" kern kkr#, "L" kern kkr#,
668 "m" kern kkr#, "M" kern kkr#,
669 "n" kern kkrs#, "N" kern kkrs#,
670 "o" kern kkr#, "O" kern kkr#,
671 "p" kern kkrs#, "P" kern kkrs#,
672 "q" kern kkr#, "Q" kern kkr#,
673 "r" kern kkrs#, "R" kern kkrs#,
674 "s" kern kkr#, "S" kern kkr#,
675 "t" kern kkr#, "T" kern kkr#,
676 "u" kern kkr#, "U" kern kkr#,
677 "v" kern kkr#, "V" kern kkr#,
678 "w" kern kkr#, "W" kern kkr#,
679 "x" kern kkx#, "X" kern kkx#,
680 "y" kern kkr#, "Y" kern kkr#,
681 "z" kern kkr#, "Z" kern kkr#;
682
683 ligtable "R":
684 "a" kern kkr#, "A" kern kkr#,
685 "b" kern kkr#, "B" kern kkr#,
686 "c" kern kkr#, "C" kern kkr#,
687 "d" kern kkr#, "D" kern kkr#,
688 "e" kern kkr#, "E" kern kkr#,
689 "f" kern kkrs#, "F" kern kkrs#,
690 "g" kern kkrs#, "G" kern kkrs#,
691 "h" kern kkr#, "H" kern kkr#,
692 "i" kern kkr#, "I" kern kkr#,
693 "j" kern kkj#, "J" kern kkj#,
694 "k" kern kkrs#, "K" kern kkrs#,
695 "l" kern kkr#, "L" kern kkr#,
696 "m" kern kkr#, "M" kern kkr#,
697 "n" kern kkrs#, "N" kern kkrs#,
698 "o" kern kkr#, "O" kern kkr#,
699 "p" kern kkrs#, "P" kern kkrs#,
700 "q" kern kkr#, "Q" kern kkr#,
701 "r" kern kkrs#, "R" kern kkrs#,
702 "s" kern kkr#, "S" kern kkr#,
703 "t" kern kkr#, "T" kern kkr#,
704 "u" kern kkr#, "U" kern kkr#,
705 "v" kern kkr#, "V" kern kkr#,
706 "w" kern kkr#, "W" kern kkr#,
707 "x" kern kkx#, "X" kern kkx#,
708 "y" kern kkr#, "Y" kern kkr#,
709 "z" kern kkr#, "Z" kern kkr#;
710
711 fi
712
713 bye.
714