Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/huncltitle.mf

raw
1 %%
2 %% This is file `huncltitle.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% huncial.dtx (with options: `mfd')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18 def makebox(text rule) =
19 for y=0,half_height,cap_height,body_height,x_height,-desc_depth,-body_depth:
20 rule((l,y)t_,(r,y)t_); endfor % horizontals
21 for x=l,r: rule((x,-body_depth)t_,(x,body_height)t_); endfor % verticals
22 for x=u*(1+floor(1/u)) step u until r-1:
23 rule((x,-body_depth)t_,(x,body_height)t_); endfor % more verticals
24 if charic<>0:
25 rule((r+charic*pt,h.o_),(r+charic*pt,.5h.o_)); fi % italic correction
26 enddef;
27
28
29 def proofpcbb(suffix $)(expr xoff, yoff) =
30 if proofing > 0:
31 x$bl = x$ - xoff; y$bl = y$ - yoff; % Bottom Left Hand Corner
32 z$br = (x$bl+side, y$bl); % BRHC
33 z$tr = (x$bl+side, y$bl+side); % TRHC
34 z$tl = (x$bl, y$bl+side); % TLHC
35 z$bc = 1/2[z$bl,z$br]; z$tc = 1/2[z$tl,z$tr]; % horizontal mid points
36 pair hc, vc;
37 hc = (2u,0); vc = (0,2u);
38 pickup pensquare scaled 2;
39 for s = z$bl, z$br, z$tr, z$tl, z$bc, z$tc:
40 draw s-hc--s+hc;
41 draw s-vc--s+vc;
42 endfor
43 fi
44 enddef;
45
46
47 def huncial_font_setup= % contains special stuff for huncial fonts
48 define_pixels(side,half_height,carol_height,comma_width);
49 define_pixels(u,dot_size,letter_size,cap_height,width_adj,serif_fit,
50 cap_serif_fit,jut,cap_jut,trijut);
51 define_pixels(fig_width);
52 define_whole_pixels(letter_fit);
53 define_whole_vertical_pixels(body_height,asc_height,cap_height,x_height,
54 desc_depth,body_depth,fig_height);
55 define_corrected_pixels(o);
56 define_blacker_pixels(thick,thin);
57 let adjust_fit = normal_adjust_fit;
58 pickup pencircle scaled thin;
59 stylus:=savepen;
60 pickup pencircle scaled (1.5thin);
61 thickstylus:=savepen;
62 pickup pencircle xscaled thick yscaled thin rotated pangle;
63 quill:=savepen;
64 numeric pcshiftx#; % x value of LHS of box wrt origin of char box
65 define_pixels(pcshiftx);
66 numeric sqxside#; % x size of the square
67 numeric sqyside#; % y size of the square
68 define_pixels(sqxside,sqyside);
69
70 enddef; % end of huncial_font_setup
71
72 boolean ductus;
73 ductus:=false;
74 numeric qhor, qvert;
75 qhor:=cosd(pangle); qvert:=sind(pangle);
76 pair pdir; pdir=dir(pangle);
77 pair ppdir; ppdir=dir(pangle+90);
78
79 def draw_serif(suffix $, $$)(expr fr)=
80 numeric beta, ajut, bjut;
81 beta=1-fr;
82 ajut=fr*jut; bjut=beta*jut;
83 pair vec[]; vec1=unitvector(z$$-z$);
84 vec2=ajut*vec1;
85 z$a=z$ shifted vec2;
86 z$b=z$a rotatedaround (z$,-90);
87 boolean top_serif;
88 if y$>y$$:
89 top_serif := true;
90 z$c=z$b shifted (-bjut*pdir);
91 else:
92 top_serif:=false;
93 z$c=z$b shifted (bjut*pdir);
94 fi
95 if top_serif:
96 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
97 else:
98 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
99 fi
100 labels($a,$b,$c);
101 enddef; % end of draw_serif
102
103
104 def draw_triserif(suffix $)(expr tj)=
105 pen oldpen; oldpen:=currentpen;
106 pickup quill;
107 x$ts1'=lft x$; y$ts1'=bot y$;
108 pickup stylus;
109 lft x$ts1=x$ts1'; bot y$ts1=y$ts1';
110 x$ts2=x$ts1-tj; z$ts2=whatever[z$,z$ts1];
111 x$ts3=x$ts1; y$ts3=y$ts2-tj;
112 pickup stylus;
113 %% filldraw z$ts1--z$ts2--z$ts3--cycle;
114 filldraw z$--z$ts2--z$ts3--cycle;
115 pickup oldpen;
116 labels($ts1,$ts2,$ts3);
117 enddef; % end of draw_triserif
118
119
120 def draw_istem(suffix $, $$)(expr fr)=
121 draw_serif($, $$, fr); % top serif
122 draw_serif($$, $, fr); % bottom serif
123 draw z$a--z$$a; % the stem
124 enddef; % end of draw_istem
125
126
127 def draw_tstem(suffix $, $$)(expr fr)=
128 draw_serif($$, $, fr); % the serif
129 draw z$--z$$a; % the stem
130 enddef; % end of draw_tstem
131
132
133 def draw_tlserif(suffix $, $$)(expr fr)=
134 draw_serif($, $$, fr); % the serif
135 draw z$a--z$$; % the stem
136 enddef; % end of draw_tlserif
137
138
139 def draw_flick(suffix $)(expr rise, fall, fjut)=
140 rt x$b = x1+fjut; top y$b=y$-fall;
141 x$a=0.5[x$,x$b]; top y$a=y$+rise;
142 draw z$..z$a..z$b;
143 labels($a,$b);
144 enddef; % end of draw_flick
145
146
147 def draw_wave(suffix $,$$)(expr f)=
148 x$wl=x$; y$wl=y$-f;
149 x$wr=x$$; y$wr=y$$+f;
150 z$wc=0.5[z$wl,z$wr];
151 draw z$wl{pdir}..z$wc{right}..{pdir}z$wr;
152 labels($wl,$wc,$wr);
153 enddef; % end of draw_wave
154
155 def draw_tail(suffix $)(expr fj)=
156 pen oldpen; oldpen:=currentpen;
157 pickup quill;
158 x$tl' = lft x$; y$tl=bot y$;
159 pickup stylus;
160 lft x$tl=x$tl';
161 x$tb=x$tl-fj; bot y$tb=y$tl-1/2desc_depth;
162 filldraw z${down}..{-pdir}z$tb & z$tb{pdir}..{up}z$tl--cycle;
163 pickup oldpen;
164 labels($tb,$tl);
165 enddef; % end of draw_tail
166
167 def draw_triangle(suffix $)(expr sz)=
168 pen oldpen; oldpen:=currentpen;
169 pickup stylus;
170 x$t1=x$-sz/2; x$t3=x$+sz/2;
171 y$t1=y$t3=y$;
172 x$t2=x$; y$t2=y$-0.9sz; % approx sqrt(3)/2
173 filldraw z$t1--z$t2--z$t3--cycle;
174 pickup oldpen;
175 labels($t1,$t2,$t3);
176 enddef; % end of draw_triangle
177
178 def draw_rtriangle(suffix $)(expr sz)=
179 pen oldpen; oldpen:=currentpen;
180 pickup stylus;
181 x$t1=x$-sz; rt x$t3=x$;
182 y$t1=y$t3=y$;
183 x$t2=x$t3; y$t2=y$-sz;
184 filldraw z$t1--z$t2--z$t3--cycle;
185 pickup oldpen;
186 labels($t1,$t2,$t3);
187 enddef; % end of draw_rtriangle
188
189 def draw_rutriangle(suffix $)(expr sz)=
190 pen oldpen; oldpen:=currentpen;
191 pickup stylus;
192 x$t1=x$-sz; rt x$t3=x$;
193 y$t1=y$t3=y$;
194 x$t2=x$t3; y$t2=y$+sz;
195 filldraw z$t1--z$t2--z$t3--cycle;
196 pickup oldpen;
197 labels($t1,$t2,$t3);
198 enddef; % end of draw_rutriangle
199
200 def draw_fork(suffix $, $$)(expr sz)=
201 pen oldpen; oldpen:=currentpen;
202 pickup quill;
203 x$f1'=lft x$; y$f1'=bot y$;
204 x$f3'=rt x$; y$f3'=top y$;
205 pickup stylus;
206 lft x$f1=x$f1'; bot y$f1=y$f1';
207 rt x$f3=x$f3'; y$f3-y$=2*(y$-y$f1);
208 rt x$f2=x$$-sz; bot y$f2=y$$;
209 rt x$f4= rt x$f5=x$$;
210 bot y$f5=y$$-sz; top y$f4=y$$+1/2sz;
211 filldraw z$f1--z$f2--z$f3--cycle; % the line
212 draw z$f2{right}..z$f4; % upper fork
213 draw z$f2{right}..z$f5; % lower fork
214 pickup oldpen;
215 labels($f1,$f2,$f3,$f4,$f5);
216 enddef; % end of draw_fork
217
218 def draw_urswish(suffix $, $$)=
219 pen oldpen; oldpen:=currentpen;
220 pickup quill;
221 rt x$$s1=x$$-thick; top y$$s1=y$$;
222 rt x$$s2=x$$;
223 %% x$$s3=x$$-thick;
224 lft x$$s3=x$$s1;
225 bot y$$s3=y$$-thick; y$$s2=0.5[y$$s1,y$$s3];
226 %% draw z$---z$$s1{right}..z$$s2{down}..{-pdir}z$$s3;
227 draw z$..z$$s1{pdir}..z$$s2{down};
228 labels($$s1,$$s2,$$s3);
229 enddef; % end of draw_urswish
230
231 def bowl_stem(suffix $, $$)=
232 x$'=0.5[x$,x$$]; y$'=y$; % the mid-point
233 z$''=z$' shifted (thick*pdir);
234 x$i=x$$; z$i=whatever[z$',z$''];
235 labels($',$i);
236 enddef; % end of bowl_stem
237
238 def draw_pdot(suffix $)(expr sz)=
239 z$s = z$ shifted (0.5sz*left);
240 z$t = z$ shifted (0.5sz*up);
241 z$u = z$s shifted (sz*right);
242 z$v = z$t shifted (sz*down);
243 pickup stylus;
244 filldraw z$s--z$t--z$u--z$v--cycle;
245 labels($s,$t,$u,$v);
246 enddef; % end of draw_pdot
247
248
249 def draw_pcomma(suffix $)(expr sz, ar)=
250 z$s = z$ shifted (0.5sz*left);
251 z$t = z$s shifted (sz*right);
252 x$v=x$s-ar; y$v=y$s-ar;
253 z$u = z$v shifted (sz*right);
254 pickup stylus;
255 filldraw z$s--z$t--z$u--z$v--cycle;
256 %% filldraw z$s--z$t--z$u--cycle;
257 labels($s,$t,$u,$v);
258 enddef; % end of draw_pcomma
259
260
261 def draw_plq(suffix $)(expr sz, ar)=
262 z$s = z$ shifted (0.5sz*left);
263 z$t = z$s shifted (sz*right);
264 x$v=x$s+ar; y$v=y$s-ar;
265 z$u = z$v shifted (sz*right);
266 pickup stylus;
267 filldraw z$s--z$t--z$u--z$v--cycle;
268 %% filldraw z$s--z$t--z$v--cycle;
269 labels($s,$t,$u,$v);
270 enddef; % end of draw_plq
271
272
273 font_coding_scheme:="ASCII minuscules and punctuation";
274 mode_setup;
275 huncial_font_setup;
276
277
278 input huncll; % minuscules (lower case)
279 input hunclu; % majuscules (capitals)
280 input hunclpunct; % punctuation
281 input huncllig; % the several dashes
282 input huncldig; % arabic digits
283
284
285 font_slant slant; font_x_height x_height#;
286 if monospace: font_normal_space 9u#; % no stretching or shrinking
287 font_quad 18u#;
288 font_extra_space 9u#;
289 else: font_normal_space 6u#+2letter_fit#;
290 font_normal_stretch 3u#; font_normal_shrink 2u#;
291 font_quad 18u#+4letter_fit#;
292 font_extra_space 2u#;
293 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
294 %% ligtable "P": "T": "Y": "A" kern kk#;
295 %% ligtable "F": "V": "W": "A" kern if serifs: kkk# else: kk#fi,
296 %% "K": "X": "O" kern k#, "C" kern k#, "G" kern k#, "Q" kern k#;
297 %% ligtable "O": "D": "X" kern k#, "W" kern k#, "A" kern k#,
298 %% "V" kern k#, "Y" kern k#;
299 %% ligtable "A": if serifs: "R": fi
300 %% "C" kern k#, "O" kern k#, "G" kern k#, "U" kern k#, "Q" kern k#,
301 %% "L": "T" kern kk#, "Y" kern kkk#, "V" kern kk#, "W" kern kkk#;
302 %%ligtable "I": "I" kern -k#; % Richard III
303 fi
304
305 bye.
306