Debian Codegraph @

texmf-dist/fonts/source/public/bookhands/cmintitle.mf

raw
1 %%
2 %% This is file `cmintitle.mf',
3 %% generated with the docstrip utility.
4 %%
5 %% The original source files were:
6 %%
7 %% carolmin.dtx (with options: `mfd')
8 %%
9 %% Copyright 1999 Peter R. Wilson
10 %%
11 %% This program is provided under the terms of the
12 %% LaTeX Project Public License distributed from CTAN
13 %% archives in directory macros/latex/base/lppl.txt.
14 %%
15 %% Author: Peter Wilson (CUA)
16 %% now at: [email protected]
17 %%
18 def makebox(text rule) =
19 for y=0,half_height,cap_height,body_height,x_height,-desc_depth,-body_depth:
20 rule((l,y)t_,(r,y)t_); endfor % horizontals
21 for x=l,r: rule((x,-body_depth)t_,(x,body_height)t_); endfor % verticals
22 for x=u*(1+floor(1/u)) step u until r-1:
23 rule((x,-body_depth)t_,(x,body_height)t_); endfor % more verticals
24 if charic<>0:
25 rule((r+charic*pt,h.o_),(r+charic*pt,.5h.o_)); fi % italic correction
26 enddef;
27
28
29 def proofpcbb(suffix $)(expr xoff, yoff) =
30 if proofing > 0:
31 x$bl = x$ - xoff; y$bl = y$ - yoff; % Bottom Left Hand Corner
32 z$br = (x$bl+side, y$bl); % BRHC
33 z$tr = (x$bl+side, y$bl+side); % TRHC
34 z$tl = (x$bl, y$bl+side); % TLHC
35 z$bc = 1/2[z$bl,z$br]; z$tc = 1/2[z$tl,z$tr]; % horizontal mid points
36 pair hc, vc;
37 hc = (2u,0); vc = (0,2u);
38 pickup pensquare scaled 2;
39 for s = z$bl, z$br, z$tr, z$tl, z$bc, z$tc:
40 draw s-hc--s+hc;
41 draw s-vc--s+vc;
42 endfor
43 fi
44 enddef;
45
46
47 def carolmin_font_setup= % contains special stuff for carolmin fonts
48 define_pixels(side,half_height,carol_height,comma_width);
49 define_pixels(u,dot_size,letter_size,cap_height,width_adj,serif_fit,
50 cap_serif_fit,jut,clubjut,cap_jut,trijut);
51 define_pixels(fig_width);
52 define_whole_pixels(letter_fit,sb);
53 define_whole_vertical_pixels(body_height,asc_height,cap_height,x_height,
54 desc_depth,body_depth,fig_height);
55 define_corrected_pixels(o);
56 define_blacker_pixels(thick,thin);
57 let adjust_fit = normal_adjust_fit;
58 pickup pencircle scaled thin;
59 stylus:=savepen;
60 pickup pencircle scaled (1.5thin);
61 thickstylus:=savepen;
62 pickup pencircle xscaled thick yscaled thin rotated pangle;
63 quill:=savepen;
64
65 pickup pencircle xscaled 3/4thick yscaled thin rotated pangle;
66 threequarterquill := savepen;
67
68 pickup pencircle xscaled 1/2thick yscaled thin rotated pangle;
69 halfquill := savepen;
70
71 pickup pencircle xscaled 1/4thick yscaled thin rotated pangle;
72 quarterquill := savepen;
73
74 numeric pcshiftx#; % x value of LHS of box wrt origin of char box
75 define_pixels(pcshiftx);
76 numeric sqxside#; % x size of the square
77 numeric sqyside#; % y size of the square
78 define_pixels(sqxside,sqyside);
79
80 enddef; % end of carolmin_font_setup
81
82 boolean ductus;
83 ductus:=false;
84 numeric qhor, qvert;
85 qhor:=cosd(pangle); qvert:=sind(pangle);
86 pair pdir; pdir=dir(pangle);
87 pair ppdir; ppdir=dir(pangle+90);
88
89 def draw_serif(suffix $, $$)(expr fr)=
90 numeric beta, ajut, bjut;
91 beta=1-fr;
92 ajut=fr*jut; bjut=beta*jut;
93 pair vec[]; vec1=unitvector(z$$-z$);
94 vec2=ajut*vec1;
95 z$a=z$ shifted vec2;
96 z$b=z$a rotatedaround (z$,-90);
97 boolean top_serif;
98 if y$>y$$:
99 top_serif := true;
100 z$c=z$b shifted (-bjut*pdir);
101 else:
102 top_serif:=false;
103 z$c=z$b shifted (bjut*pdir);
104 fi
105 if top_serif:
106 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
107 else:
108 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
109 fi
110 labels($a,$b,$c);
111 enddef; % end of draw_serif
112
113
114 def draw_roundserif(suffix $, $$)(expr fr)=
115 draw_serif($, $$, fr);
116 undraw z$--z$a;
117 enddef; % end of draw_roundserif
118
119
120 def draw_flatserif(suffix $, $$)(expr fr)=
121 numeric beta, ajut, bjut;
122 beta=1-fr;
123 ajut=fr*jut; bjut=beta*jut;
124 pair vec[]; vec1=unitvector(z$$-z$);
125 vec2=ajut*vec1;
126 z$a=z$ shifted vec2;
127 %%% z$b=z$a rotatedaround (z$,-90);
128 boolean top_serif;
129 if y$>y$$:
130 top_serif := true;
131 z$c=z$ shifted (-jut*pdir);
132 else:
133 top_serif:=false;
134 z$c=z$ shifted (jut*pdir);
135 fi
136 z$b = fr[z$,z$c];
137 draw z$a--z$;
138 if top_serif:
139 draw z$c--z$b{pdir}..{z$$-z$}z$a; % the serif
140 else:
141 draw z$c--z$b{-pdir}..{z$$-z$}z$a;
142 fi
143 labels($a,$b,$c);
144 enddef; % end of draw_flatserif
145
146
147 def draw_clubserif(suffix $, $$)(expr fr)=
148 numeric beta, ajut, bjut;
149 %% beta=1-fr;
150 ajut=clubjut; bjut=beta*jut;
151 pair vec[]; vec1=unitvector(z$$-z$);
152 %% vec2=ajut*vec1;
153 %% z$a=z$ shifted vec2;
154 boolean top_serif;
155 if y$>y$$:
156 top_serif := true;
157 z$c=z$ shifted (-clubjut*pdir);
158 else:
159 top_serif:=false;
160 z$c=z$ shifted (clubjut*pdir);
161 fi
162 z$a = fr[z$,z$$];
163 draw z$c..z$a{vec1};
164 labels($a,$b,$c);
165 enddef; % end of draw_clubserif
166
167
168 def draw_triserif(suffix $)(expr tj)=
169 pen oldpen; oldpen:=currentpen;
170 pickup quill;
171 x$ts1'=lft x$; y$ts1'=bot y$;
172 pickup stylus;
173 lft x$ts1=x$ts1'; bot y$ts1=y$ts1';
174 x$ts2=x$ts1-tj; z$ts2=whatever[z$,z$ts1];
175 x$ts3=x$ts1; y$ts3=y$ts2-tj;
176 pickup stylus;
177 %% filldraw z$ts1--z$ts2--z$ts3--cycle;
178 filldraw z$--z$ts2--z$ts3--cycle;
179 pickup oldpen;
180 labels($ts1,$ts2,$ts3);
181 enddef; % end of draw_triserif
182
183
184 def draw_istem(suffix $, $$)(expr fr)=
185 draw_serif($, $$, fr); % top serif
186 draw_serif($$, $, fr); % bottom serif
187 draw z$a--z$$a; % the stem
188 enddef; % end of draw_istem
189
190
191 def draw_tstem(suffix $, $$)(expr fr)=
192 %% draw_serif($$, $, fr); % the serif
193 %% draw z$--z$$a; % the stem
194 draw z$--z$$;
195 enddef; % end of draw_tstem
196
197
198 def draw_tlserif(suffix $, $$)(expr fr)=
199 draw_serif($, $$, fr); % the serif
200 draw z$a--z$$; % the stem
201 enddef; % end of draw_tlserif
202
203
204 def draw_flick(suffix $)(expr rise, fall, fjut)=
205 rt x$b = x1+fjut; top y$b=y$-fall;
206 x$a=0.5[x$,x$b]; top y$a=y$+rise;
207 draw z$..z$a..z$b;
208 labels($a,$b);
209 enddef; % end of draw_flick
210
211
212 def draw_wave(suffix $,$$)(expr f)=
213 x$wl=x$; y$wl=y$-f;
214 x$wr=x$$; y$wr=y$$+f;
215 z$wc=0.5[z$wl,z$wr];
216 draw z$wl{pdir}..z$wc{right}..{pdir}z$wr;
217 labels($wl,$wc,$wr);
218 enddef; % end of draw_wave
219
220 def draw_tail(suffix $)(expr fj)=
221 pen oldpen; oldpen:=currentpen;
222 pickup quill;
223 x$tl' = lft x$; y$tl=bot y$;
224 pickup stylus;
225 lft x$tl=x$tl';
226 x$tb=x$tl-fj; bot y$tb=y$tl-1/2desc_depth;
227 filldraw z${down}..{-pdir}z$tb & z$tb{pdir}..{up}z$tl--cycle;
228 pickup oldpen;
229 labels($tb,$tl);
230 enddef; % end of draw_tail
231
232 def draw_triangle(suffix $)(expr sz)=
233 pen oldpen; oldpen:=currentpen;
234 pickup stylus;
235 x$t1=x$-sz/2; x$t3=x$+sz/2;
236 y$t1=y$t3=y$;
237 x$t2=x$; y$t2=y$-0.9sz; % approx sqrt(3)/2
238 filldraw z$t1--z$t2--z$t3--cycle;
239 pickup oldpen;
240 labels($t1,$t2,$t3);
241 enddef; % end of draw_triangle
242
243 def draw_utriangle(suffix $)(expr sz)=
244 pen oldpen; oldpen:=currentpen;
245 pickup stylus;
246 x$t1=x$-sz/2; x$t3=x$+sz/2;
247 y$t1=y$t3=y$;
248 x$t2=x$; y$t2=y$+0.9sz; % approx sqrt(3)/2
249 filldraw z$t1--z$t2--z$t3--cycle;
250 pickup oldpen;
251 labels($t1,$t2,$t3);
252 enddef; % end of draw_utriangle
253
254 def draw_rtriangle(suffix $)(expr sz)=
255 pen oldpen; oldpen:=currentpen;
256 pickup stylus;
257 x$t1=x$-sz; rt x$t3=x$;
258 y$t1=y$t3=y$;
259 x$t2=x$t3; y$t2=y$-sz;
260 filldraw z$t1--z$t2--z$t3--cycle;
261 pickup oldpen;
262 labels($t1,$t2,$t3);
263 enddef; % end of draw_rtriangle
264
265 def draw_rutriangle(suffix $)(expr sz)=
266 pen oldpen; oldpen:=currentpen;
267 pickup stylus;
268 x$t1=x$-sz; rt x$t3=x$;
269 y$t1=y$t3=y$;
270 x$t2=x$t3; y$t2=y$+sz;
271 filldraw z$t1--z$t2--z$t3--cycle;
272 pickup oldpen;
273 labels($t1,$t2,$t3);
274 enddef; % end of draw_rutriangle
275
276 def draw_fork(suffix $, $$)(expr sz)=
277 pen oldpen; oldpen:=currentpen;
278 pickup quill;
279 x$f1'=lft x$; y$f1'=bot y$;
280 x$f3'=rt x$; y$f3'=top y$;
281 pickup stylus;
282 lft x$f1=x$f1'; bot y$f1=y$f1';
283 rt x$f3=x$f3'; y$f3-y$=2*(y$-y$f1);
284 rt x$f2=x$$-sz; bot y$f2=y$$;
285 rt x$f4= rt x$f5=x$$;
286 bot y$f5=y$$-sz; top y$f4=y$$+1/2sz;
287 filldraw z$f1--z$f2--z$f3--cycle; % the line
288 draw z$f2{right}..z$f4; % upper fork
289 draw z$f2{right}..z$f5; % lower fork
290 pickup oldpen;
291 labels($f1,$f2,$f3,$f4,$f5);
292 enddef; % end of draw_fork
293
294 def draw_urswish(suffix $, $$)=
295 pen oldpen; oldpen:=currentpen;
296 pickup quill;
297 rt x$$s1=x$$-thick; top y$$s1=y$$;
298 rt x$$s2=x$$;
299 %% x$$s3=x$$-thick;
300 lft x$$s3=x$$s1;
301 bot y$$s3=y$$-thick; y$$s2=0.5[y$$s1,y$$s3];
302 %% draw z$---z$$s1{right}..z$$s2{down}..{-pdir}z$$s3;
303 draw z$..z$$s1{pdir}..z$$s2{down};
304 labels($$s1,$$s2,$$s3);
305 enddef; % end of draw_urswish
306
307 def bowl_stem(suffix $, $$)=
308 x$'=0.5[x$,x$$]; y$'=y$; % the mid-point
309 z$''=z$' shifted (thick*pdir);
310 x$i=x$$; z$i=whatever[z$',z$''];
311 labels($',$i);
312 enddef; % end of bowl_stem
313
314 def draw_clubbase(suffix $, $$)(expr st, lft, rt)=
315 z$$l = z$$ shifted (lft*thick*(-pdir));
316 z$$r = z$$ shifted (rt*thick*(pdir));
317 z$$t = st[z$$,z$];
318 draw z$$t{z$$-z$}..z$$l--z$$r..{z$-z$$}z$$t;
319 labels($$t,$$l,$$r);
320 enddef; % end of draw_clubbase
321
322
323 def draw_pdot(suffix $)(expr sz)=
324 z$s = z$ shifted (0.5sz*left);
325 z$t = z$ shifted (0.5sz*up);
326 z$u = z$s shifted (sz*right);
327 z$v = z$t shifted (sz*down);
328 pickup stylus;
329 filldraw z$s--z$t--z$u--z$v--cycle;
330 labels($s,$t,$u,$v);
331 enddef; % end of draw_pdot
332
333
334 def draw_pcomma(suffix $)(expr sz, ar)=
335 z$s = z$ shifted (0.5sz*left);
336 z$t = z$s shifted (sz*right);
337 x$v=x$s-ar; y$v=y$s-2ar;
338 z$u = z$v shifted (sz*right);
339 z$sv = (x$s, 1/3[y$s,y$v]);
340 z$tu = (x$t, y$sv);
341 z$uv = 1/3[z$u,z$v];
342 z$vu = 1/3[z$v,z$u];
343 pickup stylus;
344 %% filldraw z$s--z$t--z$u--z$v--cycle;
345 filldraw z$s--z$t--z$tu{down}..{left}z$uv--z$vu{right}..{up}z$sv--cycle;
346 labels($s,$t,$u,$v,$sv,$tu,$uv,$vu);
347 enddef; % end of draw_pcomma
348
349
350 def draw_plq(suffix $)(expr sz, ar)=
351 z$s = z$ shifted (0.5sz*left);
352 z$t = z$s shifted (sz*right);
353 x$v=x$s+ar; y$v=y$s-2ar;
354 z$u = z$v shifted (sz*right);
355 z$sv = (x$s, 1/3[y$s,y$v]);
356 z$tu = (x$t, y$sv);
357 z$uv = 1/3[z$u,z$v];
358 z$vu = 1/3[z$v,z$u];
359 pickup stylus;
360 %% filldraw z$s--z$t--z$u--z$v--cycle;
361 filldraw z$s--z$t--z$tu{down}..{right}z$uv--z$vu{left}..{up}z$sv--cycle;
362 labels($s,$t,$u,$v);
363 enddef; % end of draw_plq
364
365
366 path obouter, obinner, obfirst, obsecond;
367 def offsetbowl(suffix $)(expr sx, sy, fx, fy)=
368 numeric inx, iny, cx, cy;
369 pair pt[];
370 path pth[];
371 inx := 1/2thick*cosd(pangle); iny := 1/2thick*sind(pangle);
372 cx := x$+fx*sx; cy := y$+fy*sy;
373 z$obc = (cx,cy);
374 if pangle = 90:
375 z$wt=(x$+1/2thin, cy);
376 z$et=(x$+sx-1/2thin, cy);
377 else:
378 z$wt=(x$+inx, cy);
379 z$et=(x$+sx-inx, cy);
380 penpos$wt(thick,pangle);
381 penpos$et(thick,pangle);
382 fi
383 if pangle = 0:
384 z$nh=(cx, y$+sy-1/2thin);
385 z$sh=(cx, y$+1/2thin);
386 else:
387 z$nh=(cx, y$+sy-iny);
388 z$sh=(cx, y$+iny);
389 penpos$nh(thick,pangle);
390 penpos$sh(thick,pangle);
391 fi
392 obfirst := z$nh{right}..z$et{down}..z$sh{left}..z$wt{up}..cycle;
393 if pangle = 90:
394 z$minl = z$wt; z$maxr = z$nh; z$minr = z$et; z$maxl = z$sh;
395 else:
396 if pangle = 0:
397 z$minl = z$nh; z$maxr = z$et; z$minr = z$sh; z$maxl = z$wt;
398 else:
399 z$minl = directionpoint dir(pangle) of obfirst;
400 z$minr = directionpoint -dir(pangle) of obfirst;
401 pt1 := z$minr - z$minl; % direction
402 pt2 := (- ypart pt1, xpart pt1); % perpendicular
403 pt3 := 1/2[z$minl, z$minr];
404 pt4 := pt3 shifted pt2;
405 pt5 := pt3 shifted -pt2;
406 pth1 := pt3--pt4;
407 pth2 := pt3--pt5;
408 z$maxr = pth1 intersectionpoint obfirst;
409 z$maxl = pth2 intersectionpoint obfirst;
410 \fi
411 \fi
412 penpos$minl(thin,pangle+90);
413 penpos$maxr(thick,pangle);
414 penpos$minr(thin,pangle+90);
415 penpos$maxl(thick,pangle);
416 obsecond := z$minl..z$maxr..z$minr..z$maxl..cycle;
417 z$minlo = z$minl.r; z$maxro = z$maxr.r;
418 z$minro = z$minr.l; z$maxlo = z$maxl.l;
419 obouter := z$minlo{dir(pangle)}...z$maxro...z$minro{-dir(pangle)}...z$maxlo...cycle;
420 z$minli = z$minl.l; z$maxri = z$maxr.l;
421 z$minri = z$minr.r; z$maxli = z$maxl.r;
422 obinner := z$minli...z$maxri...z$minri...z$maxli...cycle;
423 labels($obc, $nh, $et, $sh, $wt);
424 labels($minl, $maxr, $minr, $maxl);
425 labels($minlo, $maxro, $minro, $maxlo);
426 labels($minli, $maxri, $minri, $maxli);
427 enddef;
428
429
430 def obowl(suffix $)(expr sx, sy)=
431 offsetbowl($, sx, sy, 1/2, 1/2);
432 enddef;
433
434
435 primarydef v scalarprod w =
436 (xpart v * ypart w - ypart v * xpart w)
437 enddef;
438
439
440 def tangentpoint(suffix $)(expr pth)=
441 pair vecll, veclr, veclm; % "tangent" line directions
442 numeric pl, pr, pm; % path parameter values
443 pair vecpl, vecpr, vecpm; % path directions
444 pair ptl, ptr, ptm; % path points
445 numeric sl, sr, sm; % scalar products of path/line directions
446 numeric stpsize; % size of current binary step
447 numeric tantol; % tolerance
448 boolean wtest; % a boolean
449
450 tantol := eps;
451 pl:=0; pr:=length pth; pm:=0.5(pl+pr); stpsize:=pr-pl;
452 ptl := point pl of pth;
453 ptm := point pm of pth;
454 ptr := point pr of pth;
455 vecll := unitvector (z$-ptl);
456 veclm := unitvector (z$-ptm);
457 veclr := unitvector (z$-ptr);
458 vecpl := unitvector (direction pl of pth);
459 vecpm := unitvector (direction pm of pth);
460 vecpr := unitvector (direction pr of pth);
461 sl := vecll scalarprod vecpl;
462 sm := veclm scalarprod vecpm;
463 sr := veclr scalarprod vecpr;
464 wtest := (stpsize < tantol) or (sl*sr > 0) or
465 (abs sl < tantol) or (abs sm < tantol) or (abs sr < tantol);
466 if wtest:
467 if (stpsize < tantol):
468 z$tan=(0,0);
469 errmessage("No tangent; path too short");
470 else:
471 if (sl*sr > 0):
472 z$tan=(0,0);
473 errmessage("No tangent; end products have the same sign");
474 else:
475 if (abs sl < tantol):
476 z$tan=ptl;
477 else:
478 if (abs sm < tantol):
479 z$tan=ptm;
480 else:
481 z$tan=ptr;
482 fi
483 fi
484 fi
485 fi
486 else:
487 forever:
488 if (sl*sm < 0): % opposite signs, look between pl & pm
489 pr:=pm; pm:=0.5(pr+pl);
490 vecpr := vecpm; veclr := veclm; sr:=sm;
491 else:
492 pl:=pm; pm:=0.5(pr+pl);
493 vecpl:=vecpm; vecll:=veclm; sl:=sm;
494 fi
495 stpsize:=pr-pl;
496 ptm := point pm of pth;
497 veclm := unitvector (z$-ptm);
498 vecpm := unitvector (direction pm of pth);
499 sm := veclm scalarprod vecpm;
500 wtest := (stpsize < tantol) or (abs sm < tantol);
501 if wtest:
502 if (abs sm < tantol):
503 z$tan = ptm;
504 else:
505 z$tan = ptm;
506 %%%%%% errmessage("Warning: tangent approximated");
507 fi
508 fi
509 exitif wtest;
510 endfor
511 fi
512 enddef;
513
514
515 font_coding_scheme:="ASCII minuscules and punctuation";
516 mode_setup;
517 carolmin_font_setup;
518
519
520 input cminl; % lower case
521 input cminu; % capitals
522 input cminpunct; % punctuation
523 input cminlig; % the several dashes
524 input cmindig; % arabic digits
525
526
527 font_slant slant; font_x_height x_height#;
528 if monospace:
529 font_normal_space vstretch*9u#; % no stretching or shrinking
530 font_quad vstretch*18u#;
531 font_extra_space vstretch*9u#;
532 else:
533 font_normal_space vstretch*6u#+2letter_fit#;
534 font_normal_stretch vstretch*3u#; font_normal_shrink vstretch*2u#;
535 font_quad vstretch*18u#+4letter_fit#;
536 font_extra_space vstretch*2u#;
537
538
539 fi
540
541 bye.
542
543 k#:=-.5u#; kk#:=-1.5u#; kkk#:=-2u#; % three degrees of kerning
544 kks#:=-4u#; kkx#:=-1.5u#; kkj#:=-2u#; kkr#:=-5u#; kkrs#:=-2u#; kkrl#:=-8u#;
545 ligtable "s":
546 "a" kern kks#, "A" kern kks#,
547 "c" kern kks#, "C" kern kks#,
548 "d" kern kks#, "D" kern kks#,
549 "e" kern kks#, "E" kern kks#,
550 "f" kern kks#, "F" kern kks#,
551 "g" kern kks#, "G" kern kks#,
552 "i" kern kks#, "I" kern kks#,
553 "j" kern kks#, "J" kern kks#,
554 "k" kern kks#, "K" kern kks#,
555 "m" kern kks#, "M" kern kks#,
556 "n" kern kks#, "N" kern kks#,
557 "o" kern kks#, "O" kern kks#,
558 "p" kern kks#, "P" kern kks#,
559 "q" kern kks#, "Q" kern kks#,
560 "r" kern kks#, "R" kern kks#,
561 "t" kern kks#, "T" kern kks#,
562 "u" kern kks#, "U" kern kks#,
563 "v" kern kks#, "V" kern kks#,
564 "w" kern kks#, "W" kern kks#,
565 "x" kern kks#, "X" kern kks#,
566 "y" kern kks#, "Y" kern kks#,
567 "z" kern kks#, "Z" kern kks#;
568
569 ligtable "S":
570 "a" kern kks#, "A" kern kks#,
571 "c" kern kks#, "C" kern kks#,
572 "d" kern kks#, "D" kern kks#,
573 "e" kern kks#, "E" kern kks#,
574 "f" kern kks#, "F" kern kks#,
575 "g" kern kks#, "G" kern kks#,
576 "i" kern kks#, "I" kern kks#,
577 "j" kern kks#, "J" kern kks#,
578 "k" kern kks#, "K" kern kks#,
579 "m" kern kks#, "M" kern kks#,
580 "n" kern kks#, "N" kern kks#,
581 "o" kern kks#, "O" kern kks#,
582 "p" kern kks#, "P" kern kks#,
583 "q" kern kks#, "Q" kern kks#,
584 "r" kern kks#, "R" kern kks#,
585 "t" kern kks#, "T" kern kks#,
586 "u" kern kks#, "U" kern kks#,
587 "v" kern kks#, "V" kern kks#,
588 "w" kern kks#, "W" kern kks#,
589 "x" kern kks#, "X" kern kks#,
590 "y" kern kks#, "Y" kern kks#,
591 "z" kern kks#, "Z" kern kks#;
592
593 ligtable "x":
594 "a" kern kkx#, "A" kern kkx#,
595 "b" kern kkx#, "B" kern kkx#,
596 "c" kern kkx#, "C" kern kkx#,
597 "d" kern kkx#, "D" kern kkx#,
598 "e" kern kkx#, "E" kern kkx#,
599 "g" kern kkx#, "G" kern kkx#,
600 "j" kern kkx#, "J" kern kkx#,
601 "l" kern kkx#, "L" kern kkx#,
602 "o" kern kkx#, "O" kern kkx#,
603 "q" kern kkx#, "Q" kern kkx#,
604 "t" kern kkx#, "T" kern kkx#,
605 "u" kern kkx#, "U" kern kkx#,
606 "v" kern kkx#, "V" kern kkx#,
607 "w" kern kkx#, "W" kern kkx#,
608 "y" kern kkx#, "Y" kern kkx#;
609
610 ligtable "X":
611 "a" kern kkx#, "A" kern kkx#,
612 "b" kern kkx#, "B" kern kkx#,
613 "c" kern kkx#, "C" kern kkx#,
614 "d" kern kkx#, "D" kern kkx#,
615 "e" kern kkx#, "E" kern kkx#,
616 "g" kern kkx#, "G" kern kkx#,
617 "j" kern kkx#, "J" kern kkx#,
618 "l" kern kkx#, "L" kern kkx#,
619 "o" kern kkx#, "O" kern kkx#,
620 "q" kern kkx#, "Q" kern kkx#,
621 "t" kern kkx#, "T" kern kkx#,
622 "u" kern kkx#, "U" kern kkx#,
623 "v" kern kkx#, "V" kern kkx#,
624 "w" kern kkx#, "W" kern kkx#,
625 "y" kern kkx#, "Y" kern kkx#;
626
627 ligtable "a": "A":
628 "b": "B":
629 "c": "C":
630 "d": "D":
631 "e": "E":
632 "h": "H":
633 "i": "I":
634 "k": "K":
635 "l": "L":
636 "m": "M":
637 "n": "N":
638 "o": "O":
639 "p": "P":
640 "t": "T":
641 "u": "U":
642 "v": "V":
643 "w": "W":
644 "z": "Z":
645 "j" kern kkj#, "J" kern kkj#;
646
647 ligtable "r":
648 "a" kern kkr#, "A" kern kkr#,
649 "b" kern kkr#, "B" kern kkr#,
650 "c" kern kkr#, "C" kern kkr#,
651 "d" kern kkr#, "D" kern kkr#,
652 "e" kern kkr#, "E" kern kkr#,
653 "f" kern kkrs#, "F" kern kkrs#,
654 "g" kern kkrs#, "G" kern kkrs#,
655 "h" kern kkr#, "H" kern kkr#,
656 "i" kern kkr#, "I" kern kkr#,
657 "j" kern kkj#, "J" kern kkj#,
658 "k" kern kkrs#, "K" kern kkrs#,
659 "l" kern kkr#, "L" kern kkr#,
660 "m" kern kkr#, "M" kern kkr#,
661 "n" kern kkrs#, "N" kern kkrs#,
662 "o" kern kkr#, "O" kern kkr#,
663 "p" kern kkrs#, "P" kern kkrs#,
664 "q" kern kkr#, "Q" kern kkr#,
665 "r" kern kkrs#, "R" kern kkrs#,
666 "s" kern kkr#, "S" kern kkr#,
667 "t" kern kkr#, "T" kern kkr#,
668 "u" kern kkr#, "U" kern kkr#,
669 "v" kern kkr#, "V" kern kkr#,
670 "w" kern kkr#, "W" kern kkr#,
671 "x" kern kkx#, "X" kern kkx#,
672 "y" kern kkr#, "Y" kern kkr#,
673 "z" kern kkr#, "Z" kern kkr#;
674
675 ligtable "R":
676 "a" kern kkr#, "A" kern kkr#,
677 "b" kern kkr#, "B" kern kkr#,
678 "c" kern kkr#, "C" kern kkr#,
679 "d" kern kkr#, "D" kern kkr#,
680 "e" kern kkr#, "E" kern kkr#,
681 "f" kern kkrs#, "F" kern kkrs#,
682 "g" kern kkrs#, "G" kern kkrs#,
683 "h" kern kkr#, "H" kern kkr#,
684 "i" kern kkr#, "I" kern kkr#,
685 "j" kern kkj#, "J" kern kkj#,
686 "k" kern kkrs#, "K" kern kkrs#,
687 "l" kern kkr#, "L" kern kkr#,
688 "m" kern kkr#, "M" kern kkr#,
689 "n" kern kkrs#, "N" kern kkrs#,
690 "o" kern kkr#, "O" kern kkr#,
691 "p" kern kkrs#, "P" kern kkrs#,
692 "q" kern kkr#, "Q" kern kkr#,
693 "r" kern kkrs#, "R" kern kkrs#,
694 "s" kern kkr#, "S" kern kkr#,
695 "t" kern kkr#, "T" kern kkr#,
696 "u" kern kkr#, "U" kern kkr#,
697 "v" kern kkr#, "V" kern kkr#,
698 "w" kern kkr#, "W" kern kkr#,
699 "x" kern kkx#, "X" kern kkx#,
700 "y" kern kkr#, "Y" kern kkr#,
701 "z" kern kkr#, "Z" kern kkr#;
702
703 fi
704
705 bye.
706