Debian Codegraph @

texmf-dist/doc/latex/circuit-macros/examples/dpv/MixerDPV.m4

raw
1 .PS
2 #`MixerDPV.m4
3 # Showing VMOS mosfet and custom transformer'
4 cct_init(svg_font(sans-serif,10.5bp__,1bp__))
5
6 define(`dimen_',0.6)
7 define(`elen_',0.75)
8
9 define(`Xform21',
10 `[ L1: inductor(to rvec_(dimen_*0.5,0),L,,M)
11 Core1E: M4Core1.end; Core2E: M4Core2.end
12 D: (0.5 between M4Core1 and M4Core2) - L1
13 T: line to rvec_(dimen_/3,0); { dot(at T.c) }
14 L2: inductor(to rvec_(L1.len,0),L,,M)
15 line from M4Core1.start to Core1E
16 line from M4Core2.start to Core2E
17 L3: inductor(to rvec_(-L1.len,0) with .c at T+(D.x*2,D.y*2),L) ]')
18
19 del = dimen_/3
20 setdir_(U)
21 T1: Xform21; "T1" at T1.n above rjust
22 dot(at T1.L3.start+(0,4bp__))
23 dot(at T1.L1.end+(4bp__,0))
24 dot(at T1.L2.end+(4bp__,0))
25 line from T1.L3.start left_ dimen_*2/3
26 RF: dot(,,1); "RF" at RF.w rjust
27 line from T1.L3.end left_ del; corner; ground(,,F)
28
29 line down_ del/2 from T1.L1.start then right_ del
30 reversed(`capacitor',right_ dimen_,C); llabel(,0.1 svg_micro`'F)
31 BT: dot(at Here)
32 line up_ del/2 from T1.L2.end then right del
33 reversed(`capacitor',right_ dimen_,C); llabel(,0.1 svg_micro`'F)
34 t = dimen_*7/8
35 line to (BT.x+4*t,Here.y)
36 TT: dot
37 line right_ dimen_+del/2; setdir_(U)
38 Q1: mosfet(,,dMESDQuB,E) with .G at Here
39 { "Q1" at Q1.Env.ne above ljust }
40 ground(at Q1.S,,F)
41 line right_ del*3/2 from Q1.D then down_ Q1.D.y-T1.L2.end.y
42 T2: Xform21 with .L1.start at (Here,T1.L2.end); "T2" at T2.n above ljust
43 dot(at T2.L1.start+(-4bp__,0))
44 dot(at T2.L3.end+(0,4bp__))
45 line from T2.L3.end right_ dimen_*2/3
46 IF: dot(,,1); "IF" wid 12bp__ at IF.e ljust
47 setdir_(U)
48 Q2: mosfet(,,dMESDQuB,E) at (Q1,T2.s-(0,elen_-del))
49 { "Q2" at Q2.Env.ne above ljust }
50 line from Q2.D to (T2.L2.end,Q2.D) then to T2.L2.end
51 line from Q2.G left_ del/2 then up_ BT.y-Q2.G.y then to BT
52
53 line right_ del from T1.T then down_ T1.T.y-BT.y+del*3/2
54 corner; left_
55 capacitor(to (T1.L3.end-(del,0),Here),C)
56 rlabel(,0.1 svg_micro`'F )
57 LOD: dot
58 { line to (RF,Here)
59 dot(,,1); move left_ 4bp__; "local" rjust "oscillator" rjust;
60 move left 50bp__ }
61 line from T2.T left_ to (Q1.S,T2.T)
62 T2T: dot
63 { capacitor(down_ to (Here,BT),C); rlabel(,0.1 svg_micro`'F)
64 ground(,T,F) }
65 { line from T2.L3.start right_ del; corner; ground(,,F) }
66 Vt: dot(at (0.5 between BT and TT,Q1.Env.nw),,1)
67 { "+V`'svg_sub(CC)" at last [].e ljust }
68 line to (Here,T2T); dot
69 { line to (Here,BT); Cv: capacitor(down_ 3/2*dimen_,C)
70 llabel(10 svg_micro`'F); G: dot; ground(,,F) }
71
72 for s=-1 to 1 by 2 do {{
73 line right s*t; corner
74 resistor(down_ to (Here,BT))
75 if s<0 then { llabel(,5 k`'svg_ohm) } \
76 else { rlabel(,5 k`'svg_ohm)
77 { dot(at last line.start); line to (TT,Here)
78 resistor(right_ to (T2T,Here))
79 llabel(,10 svg_ohm) } }
80 P: potentiometer(down_ Cv.len,,0.5,s*t ) with .Start at Here
81 if s<0 then { "1 k`'svg_ohm" at P. 1st [].ne ljust } \
82 else { "1 k`'svg_ohm" at P. 1st [].sw rjust }
83 dot(at P.End)
84 dot(at P.T1)
85 { L: inductor(up_ to (Here,BT),L);
86 if s<0 then { "100 svg_micro`'H" at last [].sw rjust } \
87 else { line to TT
88 "100 svg_micro`'H" at last [].ne ljust below } }
89 capacitor(down_ to (Here,G),C)
90 if s<0 then { rlabel(,0.1 svg_micro`'F) } \
91 else { llabel(,0.1 svg_micro`'F) }
92 dot }}
93
94 resistor(down_ from LOD to (LOD,G)); llabel(,51 svg_ohm); corner
95 line to (Q2.S,Here) then to Q2.S
96
97 command "</g>" # end font
98 .PE