Debian Codegraph @

texmf-dist/doc/latex/circuit-macros/examples/dpv/HeathkitDPV.m4

raw
1 .PS
2 cct_init(svg_font(Helvetica,7pt__))
3 # HeathkitDPV.m4
4 # Landscape
5 maxpswid = 11
6 maxpsht = 8.5
7
8 # llabel and rlabel without math mode
9 define(`Llabel',`llabel(
10 ifelse(`$1',,,`m4lstring(`$1',"`$1'")'),
11 ifelse(`$2',,,`m4lstring(`$2',"`$2'")'),
12 ifelse(`$3',,,`m4lstring(`$3',"`$3'")'))')
13 define(`Rlabel',`rlabel(
14 ifelse(`$1',,,`m4lstring(`$1',"`$1'")'),
15 ifelse(`$2',,,`m4lstring(`$2',"`$2'")'),
16 ifelse(`$3',,,`m4lstring(`$3',"`$3'")'))')
17
18 # Grid parameters
19 picwid = 8.5
20 picht = 6
21 g = 1/12
22
23 # Element scaling
24 linewid = 8*g
25 define(`dimen_',dimen_*4/5)
26 # Default sizes
27 boxwid = 2*g
28 boxht = 2*g
29 arrowht = arrowht*2/3
30
31 # Grid
32 linethick_(0.4)
33 for i=0 to picwid/g do { line color "lightgray" up picht from (i*g,0) }
34 for i=0 to picwid/g by 10 do { sprintf("%g",i) at (i*g,0) below }
35 for i=0 to picht/g do { line color "lightgray" right picwid from (0,i*g) }
36 for i=0 to picht/g by 10 do { sprintf("%g",i) at (0, i*g) rjust }
37 move left 2*g from (0,0)
38 linethick_(0.8)
39
40 spline outlined "white" shaded "white" \
41 from (0,picht+g) down g then down picht/5 then right picwid/5
42 for i=1 to 4 do { continue down picht/5 then right picwid/5 }
43 continue right 2*g then up 2*g
44 continue up picht-2*g then up g then left g
45
46 # Place the bottom inductor on the grid
47 I1: inductor(down_ 13*g from (80,22)*g,,13,,g)
48 I2: inductor(down_ 10*g from I1.start+(0,21*g),,10,,g)
49 I3: inductor(down_ 10*g from I2.start+(0,12)*g,,10,M,g)
50 line from M4Core1.end to (M4Core1,I1.end)
51 line from M4Core2.end to (M4Core2,I1.end)
52 Scrn: 2 between M4Core1.start and M4Core2.start
53 line dashed from Scrn to (Scrn,I1.end)
54 ground
55 I4: inductor(up_ 5*g from (Scrn.x+M4Core1.x-I2.x,I2.start.y-2*g),,5,,g)
56 I5: inductor(up_ 5*g from (I4,I2.end+(0,g)),,5,,g)
57
58 # Circuit board
59 Board: box dashed thick 2 wid 58*g ht 55*g with .se at I1.end+(-7,-2)*g
60 P: box invis wid 12*g ht 4*g with .s at Board.sw+(26*g,0) \
61 "POWER SUPPLY" "CIRCUIT BOARD"
62 line dashed thick 2 from P.sw to P.nw; line dashed thick 2 to P.ne
63 line dashed thick 2 to P.se
64
65 define Pad { P`$1': box fill_(1) "$1" }
66 # Board connections on the right
67 Pad(1) at (Board.e,I1.end)
68 line from P1.e to I1.end "RED" above
69 Pad(2) at (Board.e,I1.start)
70 line from P2.e to I1.start "RED" above
71 Pad(3) at (Board.e,I2.end)
72 GRN1: line left 4*g from I2.start "GRN" above ; ground
73 GRN2: line from P3.e to I2.end "GRN" above
74 spline <-> from GRN2.end+(-g,0) up 2.5*g right 0.5*g then up 5*g left g \
75 then up 2.5*g right 0.5*g
76 box invis fill_(1) wid 3*g ht g "6 VAC" at I2-(2*g,0)
77 Pad(4) at P3-(0,3)*g
78 line right_ 3*g from P4.e "BRN" above
79 arrow down_ 2*g ht arrowht*2/3
80 "TO DIAL" "LAMPS" at Here+(0,-g)
81 Pad(5) at (Board.e,I3.end)
82 line from P5.e to I3.end "BLU" above
83 Pad(7) at (Board.e,I3.start)
84 line from P7.e to I3.start "BLU" above
85 Pad(6) at 0.5 between P5 and P7
86 line from P6.e to I3 "BLU-YEL" above
87
88 # Power wiring, plug, switch
89 define(`socket',`[
90 Outer: box wid dimen_*2/3 ht dimen_/2*3/4
91 L: box wid dimen_/16 ht dimen_/4 at Outer-(dimen_/6,0)
92 R: box wid dimen_/16 ht dimen_/4 at Outer+(dimen_/6,0)
93 line from Outer.w to L.w
94 line from Outer.e to R.e
95 ] ')
96
97 BLK: line from I4.end to (int(I4.end.x/g+8)*g,I4.end.y) "BLK" below ; dot
98 b = lin_leng(BLK)
99 BLKYEL: line from I4.start right_ b "BLK-YEL" above ; dot
100 BLKGRN: line from I5.end right_ b "BLK-GRN" below ; dot
101 BLKRED: line from I5.start right_ b "BLK-RED" above ; dot
102 line right_ g; PL: dot
103 line from BLKYEL.end right g then to Here+(0,-g)
104 fuse(down_ 3*g,D)
105 {"3 A FUSE" "SLOW BLOW" at last line+(-5*g,0) }
106 line to (Here.x,int(Here.y/g)*g-g); dot
107 Sckt1: socket at Here+(5,0)*g
108 line from Sckt1.w to (PL,Sckt1); A: dot; "A" rjust
109 line from Sckt1.e right_ lin_leng(last line); B: dot; "B" ljust
110 Sckt2: socket at (Sckt1,P1+(0,6)*g)
111 line from Sckt2.w to (A,Sckt2); dot
112 line from Sckt2.e to (B,Sckt2); dot
113 Sckt3: socket at (Sckt1,P1+(0,2)*g)
114 line from Sckt3.w to (A,Sckt3); dot
115 line from Sckt3.e to (B,Sckt3); dot
116
117 define(`plug',`[ w = dimen_*2/3; q = 0.25*w
118 F: line right_ w
119 arc cw from F.start to F.end with .c at F
120 T1: F+(-q,w/2+g/2)
121 T2: F+( q,w/2+g/2)
122 line from T1 to (T1,F)-(0,2*g)
123 line from T2 to (T2,F)-(0,2*g) ]')
124
125 PP: plug with .F at Sckt3+(0,-8)*g
126 {"120 VAC" ljust "50/60 Hz" ljust at PP.e }
127
128 define(`pwrswitch',`[ right; circlerad = 1.75*g/2
129 C1: circle "1"
130 C4: circle "4"
131 C2: circle "2" with .n at C1.s+(0,-C1.diam/2)
132 C5: circle "5"
133 C3: circle "3" with .n at C2.s+(0,-C1.diam/2)
134 C6: circle "6"
135 hatchbox(wid g ht C2.n.y-C3.s.y,0.05) with .w at 0.5 between C5.e and C6.e
136 ]')
137
138 Psw: pwrswitch with .C4.e at Sckt1+(0,-4*g)
139 "POWER" at Psw.w+(-2*g,0) rjust
140 arrow up Psw.ht/2 at Psw.e+(1.5*g,0)
141 "ON" above; "OFF" at last arrow.start below
142 line from Psw.C1.w to (A,Psw.C1) then to A
143 line from Psw.C2.w to (A,Psw.C2); continue to (Here,PP.T1) then to PP.T1
144 line from PP.T2 to (B,PP.T2) then to (B,I4.end) then to I4.end
145 line from BLKGRN.end to (B,BLKGRN); dot
146
147 # Bottom connections
148 Pad(25) at Board.se+(-3,0)*g
149 R516: resistor(down_ 6*g from P25.s)
150 {"R516" "22" at last line+(-2*g,0)} ; ground(,T)
151 dot(at P25.s+(0,-g)); line right_ 5*g
152 reversed(`source',down_ 4*g,B)
153 {"#49" ljust "HI" ljust "TEMP" ljust at last line+(2*g,0) }
154 line to (P25,Here); dot
155 t = linethick; linethick_(0.4)
156 arrow <- from P25.s+(0,-g/2) right_ 2*g up_ g/4; "BRN" ljust; linethick_(t)
157
158 Pad(24) at P25+(-4,0)*g
159 line from P24.s to (P24,R516.end); ground(,T)
160 Pad(23) at Board.sw+(12*g,0)
161 line from P23.s to (P23,R516.end); ground(,T)
162
163 Pad(22) at Board.sw+(0,3)*g
164 R514: resistor(right_ 8*g from P22.e); Llabel(,R514); Rlabel(,680 K)
165 dot; { ground }
166 line to (P23,Here) then to P23.n
167
168 # Diode bridge
169 BE: dot(at (P24,I1))
170 d1h = lin_leng(I1)/2
171 diode(left_ d1h up_ d1h); Rlabel(,,D508)
172 BN: dot
173 diode(left_ d1h down_ d1h); Rlabel(D506)
174 BW: dot
175 diode(from BE left_ d1h down_ d1h); Llabel(,,D509)
176 BS: dot
177 diode(left_ d1h up_ d1h); Llabel(D507)
178 capacitor(down_ from BN to BS,C); Llabel(C507,,.22)
179 line from BE to P24.n
180 line from BN to P2.w
181 line from BS to P1.w
182 spline <-> from (BE.x+2*g,BS.y) \
183 up d1h/2 right g/2 then up d1h left g then up d1h/2 right g/2
184 box invis fill_(1) ht 2*g wid 2*g "57" "VAC" at last spline
185
186 # Left board connections
187 Pad(21) at (Board.w,BW); line from P21.e to BW
188 Pad(19) at P21+(0,-3*g)
189 Pad(20) at P21+(0, 3*g)
190
191 # Transistor with circles
192 define(`hbi_tr',`[ linewid = linewid*4/4.16
193 Q: bi_tr(`$1',`$2',`$3',E)
194 E: circle rad m4_xyU at 5/4 between Q.A1 and Q.E "E"
195 B: circle rad m4_xyU at 5/4 between Q.A1 and Q.B "B"
196 C: circle rad m4_xyU at 5/4 between Q.A1 and Q.C "C"
197 ]')
198
199 # Interior circuits
200 line from P6.w left 2*g; ground
201 line from P5.w left 4*g; dot
202 { C504: capacitor(down_ 4*g,C); Llabel(C504,,.22); ground(,T) }
203 D504: diode(left_ 5*g); Rlabel(,D504); dot
204 { C505: capacitor(down_ to (Here,C504.end),C+L)
205 Rlabel(C505,100,75 V); ground(,T) }
206 line right_ to (Here,P7); dot
207 { D503: reversed(`diode',to (D504.start,Here)); Llabel(,D503); line to P7.w }
208 d3 = lin_leng(I3)
209 spline <-> from C504.start+(g/2,0) \
210 up d3/4 right g/4 then up d3*2/4 left g/2 then up d3/4 right g/4
211 box invis fill_(1) ht g wid 4*g "100 VAC" at last spline+(-g,0)
212
213 down_
214 Q503: hbi_tr(,R,P) with .E at (C505,P3)
215 line from Q503.C.e to (P25,Q503.C) then to P25.n
216 line from Q503.B.s to (Q503.B.x,Q503.E.y-4*g)
217 R513: resistor(down_ 5*g)
218 {"R513" ljust "1500" ljust at last [].e}; ground(,T)
219 line from P19.e to (BW-(2*g,0),P19) then up Q503.E.y-P19.y+2*g
220 R511: resistor(right_ 5*g); Llabel(,R511); Rlabel(,470);
221 line to (Q503.E,Here) then to Q503.E.n
222 line from P20.e to (BW,P20) then up R513.end.y-P20.y
223 resistor(up_ lin_leng(R513))
224 {"R512" ljust "5600" ljust "1 W" ljust at last [].e}
225 line to (Here,Q503.B) then to Q503.B.w
226 "Q503" "S2091 HI TEMP" "CONTROL" at Q503.E+(1.5,4)*g
227 D505: reversed(`diode',right_ from Q503.E.e to (C504,Q503.E)); Llabel(,D505)
228 line to P3.w
229
230 line from P4.w left_ 2*g then up P3.y-P4.y; dot
231 line from D503.end to (R513,D503); dot
232 { Pad(8) at (Here,Board.n) }
233 { line to P8.s }
234 R505: resistor(down_ to (Here,P6)); Llabel(,"R505" ljust "12 K"); dot
235 { C503: capacitor(down_ to (Here,C505.end),C+L)
236 Rlabel(C503,100,70 V); ground(,T) }
237 right_
238 Q502: hbi_tr(,R) with .B at (R511.start,Here)
239 line from Q502.C.e to R505.start
240 line from Q502.B.e to R505.end
241 R504: resistor(down_ from Q502.B.s to (Q502.B,C505.end))
242 {"R504" ljust "51 K" ljust at last [].e}; ground(,T)
243 "Q502" "TA7311" "REGULATOR" "CONTROL" at Q502.C+(-1,3)*g
244
245 Pad(9) at (Q502.E,Board.n)
246 line from Q502.E.n to P9.s
247 Pad(10) at (Q502.B-(9,0)*g,Board.n)
248 R502: resistor(left_ from Q502.E.w to (P10,Q502.E))
249 Rlabel(,R502); Llabel(,150); dot
250
251 Pad(11) at (Board.w,Q502.E)
252 Pad(14) at P11+(0,2.5)*g
253 Pad(12) at P11+(0,-2.5)*g
254 Pad(13) at P12+(0,-2.5)*g
255 line right 2*g from P13.e then up P11.y-P13.y; dot
256 line from P12.e to (Here,P12); dot
257 Pad(15) at P13+(0,-3)*g
258
259 right_
260 Q501: hbi_tr(,R) with .B at P9.n+(0,2*g)
261 line from Q501.B.s to P9.n
262 line from Q501.C.e to (P8,Q501.C) then to P8.n
263 line from Q501.E.w to (P10,Q501.E) then to P10.n
264 "Q501" "2N3055" "REGULATOR" at Q501.n+(0,2)*g
265 line from P14.e to (P10,P14); dot
266
267 Pad(17) at (Board.w,R511)
268 Pad(16) at P17+(0,3*g)
269 Pad(18) at P17+(0,-3*g)
270 line right 2*g from P18.e then up P17.y-P18.y; dot
271
272 right_
273 Q504: hbi_tr(,R) with .C at (P10,P17)
274 line from P17.e to Q504.E.w
275 line from Q504.B.s to (Q504.B,R513.start)
276 R508:resistor(down_ to (Here,R513.end))
277 {"R508" ljust "680" ljust at last [].e}; ground(,T)
278 dot(at (P10,P15))
279 { line to P10.s }
280 { resistor(down_ 5*g); {"225" ljust "10 W" ljust "5 %" ljust at last [].e}
281 line to Q504.C.n }
282 R503:resistor(left_ 10*g); Rlabel(,R503); Llabel(,290 10 W 5%); dot
283 line to (Here,Q504.B)
284 resistor(right_ to Q504.B.w); Llabel(,R507); Rlabel(,100)
285 line from P15.e to R503.end
286 "Q504" "40409" "REGULATOR" at Q504.C+(3.5,3)*g
287 resistor(left_ from R502.end to (R503.end,P11))
288 Rlabel(,R501); Llabel(,390 5W 5%); line to P11.e
289
290 resistor(right_ from P16.e to (R514.end,P16)); Llabel(,R506); Rlabel(,82)
291 line down P16.y-P17.y; dot
292
293 dot(at (R514.end,P11))
294 C501: capacitor(down_ 6*g,C+)
295 Llabel(C501); {"100" ljust "30 V" ljust at last [].s +(0,-g)}
296 ground(,T)
297 dot(at (Here.x+4*g,P11.y))
298 ZD501: reversed(`diode',down_ lin_leng(C501),Z); Llabel(ZD501); ground(,T)
299
300 dot(at (R514.end,P15))
301 C502: capacitor(down_ 6*g,C+)
302 Llabel(C502); {"100" ljust "30 V" ljust at last [].s +(0,-g)}
303 ground(,T)
304 dot(at (Here.x+4*g,P15.y))
305 ZD502: reversed(`diode',down_ lin_leng(C502),Z); Llabel(ZD502); ground(,T)
306
307 line from (C502,P17) to (C502,R508.start+(0,g))
308 C506: capacitor(down_ to (Here,R508.end),C+)
309 Llabel(C506); {"100" ljust "30 V" ljust at last [].s +(0,-g)}
310 ground(,T)
311
312 # Left-side boxes
313 boxwid = 10*g
314 boxht = 5*g
315 line left 3*g from P22.w "GRY" above
316 line left 3*g from P19.w "VIOL" above
317 box with .e at (Here,0.5 between P19 and P22) "TO SIGNAL" "METER CIRCUIT"
318
319 line left 8*g from P21.w "RED TO C508" above
320 line left 8*g from P20.w "VIOL" above
321
322 line left 3*g from P17.w "RED" above
323 line left 3*g from P18.w; {"WHT-" ljust "RED" ljust at Here+(0,g) }
324 box with .e at (Here,0.5 between P17 and P18) "12.7 V SOURCE" "TO MULTIPLEX"
325
326 line left 3*g from P16.w "WHT" above
327 box with .se at Here+(0,-g) "12 V SOURCE" "TO FM TUNER" "SOURCE SWITCH"
328
329 line left 3*g from P15.w "ORG" above
330 box ht 3*g with .e at Here "15 V SOURCE" "TO FM TUNER"
331
332 line left 3*g from P13.w "BLU" above
333 line left 3*g from P12.w; {"WHT-" ljust "RED" ljust at Here+(0,g) }
334 line left 3*g from P11.w "RED" above
335 box ht 6*g with .e at (Here,P12) "27 V SOURCE" "TO CONTROL" "PREAMP AND" \
336 "PWR AMPLIFIER"
337
338 line left 3*g from P14.w
339 {"WHT-" ljust "GRY-" ljust "GRN" ljust at Here+(0,1.5*g) }
340 box with .se at Here+(0,-g) "50 V SOURCE" "TO PHONO" "PREAMP"
341
342 command "</g>" # end font
343 .PE