Debian Codegraph @

texmf-dist/doc/latex/circuit-macros/svg.m4

raw
1 divert(-1)
2 svg.m4 Initialization for svg output.
3
4 * Circuit_macros Version 11.0, copyright (c) 2026 J. D. Aplevich under *
5 * the LaTeX Project Public Licence in file Licence.txt. The files of *
6 * this distribution may be redistributed or modified provided that this *
7 * copyright notice is included and provided that modifications are clearly *
8 * marked to distinguish them from this distribution. There is no warranty *
9 * whatsoever for these files. *
10
11 define(`m4picprocessor',dpic)
12 define(`m4postprocessor',svg)
13 Default is to produce svg for web documents
14 ifdef(`m4textprocessor',,`define(`m4textprocessor',xml)')
15
16 ifdef(`libgen_',,`include(libgen.m4)divert(-1)')dnl
17
18 # The following definitions are still subject to change.
19 # The use of changecom may cause difficulty for non-GNU m4.
20 # ---------------------------------------------------------------------------#
21 #
22 # If either nosvgformat or Inkscape is defined then the svg formatting
23 # macros are turned off. Text formatting can then be done in Inkscape.
24
25 dnl Put define(`Inkscape') in the source for Inkscape input
26 ifelse(ifdef(`Inkscape',T)`'ifdef(`nosvgformat',T),T,
27 `define(`svg_it',`$1')
28 define(`svg_tt',`$1')
29 define(`svg_sf',`$1')
30 define(`svg_norm',`$1')
31 define(`svg_bf',`$1')
32 define(`svg_small',`$1')
33 define(`svg_fsize',`$1')
34 define(`svg_sub',`$1')
35 define(`svg_sup',`$1')
36 define(`svg_font',`$1')
37 define(`svg_symbol',`$1')
38 define(`svg_micro',`$1')
39 define(`svg_ohm',`$1')
40 define(`svg_lt',`$1')
41 define(`svg_gt',`$1')
42 ',
43 `define(`svg_tspan',`patsubst(<tspan `$1'
44 >`$2'</tspan>,",\\")')
45 divert(-1)
46 `svg_font(fontname,nominal ht:dptextratio,textoffset)
47 or svg_font(fontname,nominal ht:dptextratio,textoffset,
48 text)
49 Note: nominal ht = text height in drawing units,
50 e.g. 12bp__ for 12pt text
51 actual height = nominal ht * dptextratio '
52 define(`svg_font',`m4thtmp=textht; ifinstr(`$2',:,
53 `stacksplit_(`m4svgf',`$2',:)
54 ifelse(m4svgf,,,`ifelse(`$4',,,`m4trtmp=dptextratio;') dnl
55 dptextratio = m4svgf;')popdef(`m4svgf')dnl
56 ifelse(m4svgf,,,`ifelse(`$4',,,`m4thtmp=textht;') dnl
57 textht=(m4svgf)*dptextratio; ')undefine(`m4svgf')',
58 `ifelse(`$4',,,`m4trtmp=dptextratio;') dptextratio=svgfontratio(`$1'); dnl
59 ifelse(`$2',,,m4thtmp=textht; textht=(`$2')*dptextratio; )')dnl
60 ifelse(`$3',,,`textoffset=`$3'; ')
61 command "<g patsubst(ifelse(`$1',,,
62 index(`$1',font),0,`$1',
63 index(`$1',style),0,`$1',
64 style="font-family:`$1'")
65 ,",\\")>"
66 `$4'
67 ifelse(`$4',,,`command "</g>"; textht=m4thtmp; dptextratio=m4trtmp;')')
68
69 `e.g. svg_font(Times)
70 svg_font(Times,12bp__:0.66)
71 svg_font(Times,11bp__,1bp__,"text" at A)
72 svg_font(font-family="Times")
73 svg_font(font-family="Times" font-style="italic")
74 svg_font(style="font-family:Times; font-style:italic")
75
76 Some fairly safe choices: Arial, Helvetica, Times, Courier, Verdana, Georgia,
77 Palatino, Garamond, Bookman, Cursive, Trebuchet MS, Arial Black, Impact.
78 '
79 `svgfontratio(fontname)
80
81 reasonable dptextratio values for common fonts'
82 define(`svgfontratio',`ifinstr(
83 `$1',Times,0.66,
84 `$1',sans-serif,0.71,
85 `$1',Arial,0.71,
86 `$1',Helvetica,0.71,
87 `$1',Courier,0.57,
88 `$1',Cursive,0.7,
89 `$1',Verdana,0.72,
90 `$1',Georgia,0.70,
91 `$1',Palatino,0.66,
92 `$1',Garamond,0.62,
93 `$1',Bookman,0.66,
94 `$1',Comic Sans MS,0.75,
95 `$1',Trebuchet MS,0.71,
96 `$1',Arial Black,0.71,
97 `$1',Impact,0.79,
98 dptextratio)')
99
100 define(`svg_baselineskip',`(textht/svgfontratio)')
101
102 `see http://www.ascii.cl/htmlcodes.htm
103 and http://webdesign.about.com/od/localization/l/blhtmlcodes-gr.htm'
104 `These macros are used in strings so the double quote is entered as \". '
105 define(`svg_symbol',`changecom(,)`$1'changecom(`#',)')
106 define(`svg_it',`<tspan font-style=\"italic\">`$1'</tspan>')
107 define(`svg_tt',`<tspan font-family=\"Courier\">`$1'</tspan>')
108 define(`svg_sf',`<tspan font-family=\"Helvetica\">`$1'</tspan>')
109 define(`svg_norm',`<tspan font-style=\"normal\">`$1'</tspan>')
110 define(`svg_bf',`<tspan font-style=\"bold\">`$1'</tspan>')
111
112 dnl T0 GET %% in a sprintf string, set the size explicitly,
113 dnl eg sprintf("x`'svg_sub(%g,50%)",i)
114
115 define(`svg_small',`svg_fsize(`$1',ifelse(`$2',,66,`$2'))')
116 define(`svg_fsize',`<tspan font-size=\"ifelse(`$2',,100,`$2')%\">`$1'</tspan>')
117
118 dnl svg_ul(text) Underline text
119 define(`svg_ul',`<tspan text-decoration=\"overline\">`$1'</tspan>')
120 dnl svg_ol(text) Overline text
121 define(`svg_ol',`<tspan text-decoration=\"overline\">`$1'</tspan>')
122
123 dnl svg_sup
124 dnl This is black magic but seems necessary to work with Firefox
125 dnl Arg 2: size of subscript font in percent
126 dnl Arg 3: vertical shift, e.g. svg_sub(1,,0.5ex)
127 dnl Arg 4 shifts the subscript horizontally e.g., svg_sup(1,,,-0.5ex)
128 define(`svg_sup',`<tspan font-size=\"ifelse(`$2',,70,`$2')%\"
129 dy=\"-ifelse(`$3',,1.5ex,`$3')\" dx=\"ifelse(`$4',,,`$4')\">`$1'</tspan><tspan
130 font-size=\"ifelse(`$2',,70,`$2')%\" dy=\"ifelse(`$3',,1.5ex,`$3')\"
131 dx=\"-0.5ex\"> </tspan>')dnl note the space
132
133 dnl This is black magic but seems necessary to work with Firefox
134 dnl Arg 2: size of subscript font in percent
135 dnl Arg 3: vertical shift, e.g. svg_sub(1,,0.5ex)
136 dnl Arg 4 shifts the subscript horizontally
137 define(`svg_sub',`<tspan font-size=\"ifelse(`$2',,70,`$2')%\"
138 dy=\"ifelse(`$3',,0.66ex,`$3')\" dx=\"ifelse(`$4',,,`$4')\">`$1'</tspan><tspan
139 font-size=\"ifelse(`$2',,70,`$2')%\" dy=\"-ifelse(`$3',,0.66ex,`$3')\"
140 dx=\"-0.5ex\"> </tspan>')dnl note the space
141
142
143
144 `svg_frac(numerator[:wid],denominator[:wid])
145 Basic fraction for simple arguments
146 wid is in drawing units'
147 define(`svg_frac',`define(`m4ex',`(textht*0.675)')dnl sans-serif: 0.8525
148 define(`m4num',`patsubst(`$1',:.*)')dnl
149 define(`m4den',`patsubst(`$2',:.*)')dnl
150 define(`m4numx',`ifinstr(`$1',:,((patsubst(`$1',.*:))/m4ex),len(`$1'))')dnl
151 define(`m4denx',`ifinstr(`$2',:,((patsubst(`$2',.*:))/m4ex),len(`$2'))')dnl
152 define(`m4mx',`max(m4numx,m4denx)')dnl
153 "<tspan dx="+sprintf("\"%gex\"", m4mx/2)+"> </tspan><tspan dy=\"-1.2ex\"
154 dx="+sprintf("\"%gex\"", (m4mx-m4numx)/2)+">m4num</tspan><tspan
155 dy=\" 2.6ex\"
156 dx="+sprintf("\"%gex\"", -m4numx/2-m4denx/2)+">m4den</tspan><tspan
157 dy=\"-1.4ex\" dx="+sprintf("\"%gex\"", m4mx/2-m4denx/2)+"> </tspan>"
158 line right m4mx*m4ex from Here+((m4mx/2-0.8)*m4ex,-0.2*m4ex)
159 move to Here+(0,0.2*m4ex)
160 {box invis wid last line.len ht 2.8*textht with .w at last line.start}
161 ')
162
163 define(`svg_hat',`<tspan>svg_circ</tspan><tspan dx=\"-0.9ex\">`$1'</tspan>')
164
165 define(`svg_Delta',`svg_symbol(&`#'916;)')
166 define(`svg_Gamma',`svg_symbol(&`#'915;)')
167 define(`svg_Lambda',`svg_symbol(&`#'923;)')
168 define(`svg_Omega',`svg_symbol(&`#'937;)')
169 define(`svg_Phi',`svg_symbol(&`#'934;)')
170 define(`svg_Pi',`svg_symbol(&`#'928;)')
171 define(`svg_Psi',`svg_symbol(&`#'936;)')
172 define(`svg_Sigma',`svg_symbol(&`#'931;)')
173 define(`svg_Theta',`svg_symbol(&`#'920;)')
174 define(`svg_Xi',`svg_symbol(&`#'926;)')
175 define(`svg_alpha',`svg_symbol(&`#'945;)')
176 define(`svg_amp',`svg_symbol(&`#'38;)')
177 define(`svg_backsl',`svg_symbol(&`#'92;)')
178 define(`svg_beta',`svg_symbol(&`#'946;)')
179 define(`svg_chi',`svg_symbol(&`#'967;)')
180 define(`svg_circ',`svg_symbol(&`#'710;)')
181 define(`svg_comma',`svg_symbol(&`#'44;)')
182 define(`svg_deg',`svg_symbol(&`#'176;)')
183 define(`svg_delta',`svg_symbol(&`#'948;)')
184 define(`svg_emsp',`svg_symbol(&`#'8195;)')
185 define(`svg_ensp',`svg_symbol(&`#'8194;)')
186 define(`svg_epsilon',`svg_symbol(&`#'949;)')
187 define(`svg_equiv',`svg_symbol(&`#'8801;)')
188 define(`svg_eta',`svg_symbol(&`#'951;)')
189 define(`svg_gamma',`svg_symbol(&`#'947;)')
190 define(`svg_geq',`svg_symbol(&`#'8805;)')
191 define(`svg_grave',`svg_symbol(&`#'96;)')
192 define(`svg_gt',`svg_symbol(&`#'62;)')
193 define(`svg_iota',`svg_symbol(&`#'953;)')
194 define(`svg_kappa',`svg_symbol(&`#'954;)')
195 define(`svg_lambda',`svg_symbol(&`#'955;)')
196 define(`svg_leq',`svg_symbol(&`#'8804;)')
197 define(`svg_lparen',`svg_symbol(&`#'40;)')
198 define(`svg_lt',`svg_symbol(&`#'60;)')
199 define(`svg_micro',`svg_symbol(&`#'956;`$1')')
200 define(`svg_mu',`svg_symbol(&`#'956;)')
201 define(`svg_nu',`svg_symbol(&`#'957;)')
202 define(`svg_ohm',`svg_symbol(&`#'937;)')
203 define(`svg_omega',`svg_symbol(&`#'969;)')
204 define(`svg_phi',`svg_symbol(&`#'966;)')
205 define(`svg_pi',`svg_symbol(&`#'960;)')
206 define(`svg_pound',`svg_symbol(&`#'35;)')
207 define(`svg_prime',`svg_symbol(&`#'8242;)')
208 define(`svg_psi',`svg_symbol(&`#'968;)')
209 define(`svg_rho',`svg_symbol(&`#'961;)')
210 define(`svg_rparen',`svg_symbol(&`#'41;)')
211 define(`svg_sigma',`svg_symbol(&`#'963;)')
212 define(`svg_tau',`svg_symbol(&`#'964;)')
213 define(`svg_theta',`svg_symbol(&`#'952;)')
214 define(`svg_thinsp',`svg_symbol(&`#'8201;)')
215 define(`svg_tilde',`svg_symbol(&`#'126;)')
216 define(`svg_upsilon',`svg_symbol(&`#'965;)')
217 define(`svg_uscore',`svg_symbol(&`#'95;)')
218 define(`svg_xi',`svg_symbol(&`#'958;)')
219 define(`svg_zeta',`svg_symbol(&`#'950;)')
220 ')
221
222 define(`svgcolor',`sprintf("rgb(%g,%g,%g)",\
223 int(`$1'+0.5),int(`$2'+0.5),int(`$3'+0.5))')
224
225 # Obsolete but kept for compatibility. Use `rgbstring(r,g,b)'
226 define(`svgcolor255',
227 `svgcolor(int((`$1')*255+0.5),int((`$2')*255+0.5),int((`$3')*255+0.5))')
228
229 define(`svgLink',`command "<a xlink:href=\"`$1'\"dnl
230 ifelse(`$3',,`target=\"_blank\"',`$3',B,,`$3')>
231 <g stroke=\"rgb(0,0,255)\">"
232 `$2'
233 command "</g></a>"')
234 define(`svgLinkString',`"<a xlink:href=\"`$1'\"dnl
235 ifelse(`$3',,`target=\"_blank\"',`$3',B,,`$3') dnl
236 stroke=\"rgb(0,0,255)\">dnl
237 `$2' dnl
238 </a>"')
239
240 # `svg_rot_init(filename)
241 # rotation is about the bottom centre
242 # filename is the basename of the output
243 # produced by dpic -v filename.pic > filename.svg'
244 define(`svg_rot_init',`
245 `# svg_rot'_init begin
246 NeedDpicTools
247 define(`_file_',ifelse(`$1',,patsubst(__file__,.m4),`$1'))
248 syscmd( touch _file_.svg _file_.cor ; \
249 sed -e "s/^.*x=/x=/" _file_.svg > _file_.tmp )
250 # Extract from the .svg file the x= y= coordinates
251 # that appear after each transform="rotate(.." line
252 retcode = ( sh "awk -e \"/transform=\\"rotate/ { r=1 }; dnl
253 /x=\\".*y=\\"/ { if(r==1){ print; r=0 } }\" _file_.tmp dnl
254 | sed -e \"s/x=\\"\([0-9.]*\)\\" y=\\"\([0-9.]*\)\\".*/\1 \2/\" dnl
255 > _file_.cor" )
256 if retcode != 0 then { print "
257 Awk failure.
258 Awk and sed are required by svg_rot to rotate svg text.
259 " }
260 svgrot_k = 0
261 define svg_rotcoords { if "$`'1" != "" then { svgrot_k += 1
262 svg_rx[svgrot_k] = $`'1; svg_ry[svgrot_k] = $`'2 }
263 }
264 copythru(svg_rotcoords, _file_.cor)
265 sh "rm -f _file_.tmp _file_.cor"
266 svgrot_i = 0
267
268 ifdef(`svg_rot_',,`
269 # `svg_rot(degrees,"text" or object,[at position])
270 # Rotate text or object degrees ccw about its centre
271 # Requires svg_rot_init(filename)
272 # which uses both awk and sed.
273 # The source must be processed twice by m4 and dpic.'
274 define svg_rot { if retcode != 0 then {$`'2} else {
275 if "$`'1" != "" then { svg_rang = -($`'1) } else { svg_rang = -90 }
276 if svgrot_k != 0 then { svgrot_i +=1
277 command sprintf("<g transform=\"rotate(%g %g %g)\">",svg_rang,\
278 svg_rx[svgrot_i], svg_ry[svgrot_i]) }\
279 else { command sprintf("<g transform=\"rotate(%g)\">",svg_rang) }
280 if "$`'3"=="" then { $`'2 } \
281 else { $`'2 $`'3 - (sind(svg_rang),(cosd(svg_rang)-1))*textht/2 }
282 command "</g>" } }
283 define(`svg_rot_') ')
284 `# svg_rot'_init end
285 ')
286
287 # ---------------------------------------------------------------------------#
288
289 define(`thinlines_',`linethick = 0.4
290 arrowwid = 0.04*scale; arrowht = 0.2/3*scale')
291 define(`thicklines_',`linethick = 0.8
292 arrowwid = 0.05*scale; arrowht = 0.1*scale')
293 `linethick_(x) set line width to x pt'
294 define(`linethick_',`linethick = ifelse(`$1',,`0.8',`$1'); dnl
295 arrowwid = ifelse(`$1',,`0.05',linethick/16)*scale; dnl
296 arrowht = ifelse(`$1',,`0.1',linethick/8)*scale;')
297
298 divert(0)dnl