Debian Codegraph @

texmf-dist/doc/latex/circuit-macros/examples/extras/Planes.m4

raw
1 .PS
2 # Planes.m4
3 # https://tex.stackexchange.com/questions/727666/gate-all-around-fet-gaafet-nanosheet-3d-illustration
4 threeD_init
5 NeedDpicTools
6
7 # These 3D diagrams are like many others: define the surface facets,
8 # use normal vectors to determine visibility, sort and plot the visible
9 # facets from back to front.
10
11 divert(-1)
12 #####################################################################
13 # Recover point coordinates
14 define(`triple',`x_[$1], y_[$1], z_[$1]')
15 # Store a point as x_[i], y_[i], z_[i]
16 define(`mktriple',
17 `x_[$1] = $2
18 y_[$1] = $3
19 z_[$1] = $4 ')
20
21 # Normal vector to stored facet
22 define(`facetnormal',`cross3D(
23 diff3D(triple((`$1')*3+1),triple((`$1')*3)),
24 diff3D(triple((`$1')*3+2),triple((`$1')*3+1)))')
25
26 define(`facetcenter',`sprod3D(0.5,sum3D(triple($1*3),triple($1*3+2)))')
27
28 # Facets are rectangles; store NW, NE, SE corners
29 # `mkpfacet(index,NW2D,NE2D,-d)'
30 define(`mkpfacet',`
31 mktriple((`$1')*3, 0,`$2'.x,`$2'.y) # This uses a right-hand set of
32 mktriple((`$1')*3+1, 0,`$3'.x,`$3'.y) # coords with depth 1st value
33 mktriple((`$1')*3+2,`$4',`$3'.x,`$3'.y)
34 mktriple(0,facetnormal(`$1'))
35 if dot3D(triple(0),View3D) < 0 then {
36 mktriple((`$1')*3,`$4',`$3'.x,`$3'.y)
37 mktriple((`$1')*3+2, 0,`$2'.x,`$2'.y) }
38 ')
39
40 # View angles azimuth, elevation, rotation (degrees),
41 # Implicitly increments m4x
42 define(`mkthreeplanes',`
43 #mkthreeplanes( wd2h param, ht param, dpth param )
44 # Size parameters
45 define(`m4a',`ifelse(`$1',,1.5,(`$1'))')
46 define(`m4b',`ifelse(`$1',,0.4,(`$2'))')
47 define(`m4d',`ifelse(`$1',,0.5,(`$3'))')
48 # Define intersecting lines in the plane
49 A0: -m4a,-m4b; A1: m4a,-m4b
50 B0: Rot_(A0,120); B1: Rot_(A1,120)
51 C0: Rot_(A0,240); C1: Rot_(A1,240)
52 AB: intersect_(A0,A1,B0,B1)
53 BC: intersect_(B0,B1,C0,C1)
54 CA: intersect_(C0,C1,A0,A1)
55 # Define the 9 visible facets
56 mkpfacet(m4inx,A0,CA,-m4d)
57 mkpfacet(m4inx,CA,AB,-m4d)
58 mkpfacet(m4inx,AB,A1,-m4d)
59
60 mkpfacet(m4inx,B0,AB,-m4d)
61 mkpfacet(m4inx,AB,BC,-m4d)
62 mkpfacet(m4inx,BC,B1,-m4d)
63
64 mkpfacet(m4inx,C0,BC,-m4d)
65 mkpfacet(m4inx,BC,CA,-m4d)
66 mkpfacet(m4inx,CA,C1,-m4d)
67 ')
68
69 # Cuboid
70 # Requires centre plus three lengths plus 3 angles or equivalent, e.g. 9 dof
71 # plus, somehow, color information. Implicitly increments m4cux
72 #
73 define(`mkcuboid',`# ( xC,yC,zC, wdh,hgt,depth, xrot,yrot,zrot)
74 pushdef(`m4cubx',`define(`m4cux',ifdef(`m4cux',`incr(m4cux)',1))m4cux')
75 pushdef(`xr',`$7') pushdef(`yr',`$8') pushdef(`zr',`$9') dnl
76 pushdef(`wd2',ifelse(`$4',,boxwd,(`$4'))/2) dnl
77 pushdef(`hg2',ifelse(`$5',,boxht,(`$5'))/2) dnl
78 pushdef(`de2',ifelse(`$6',,boxwd,(`$6'))/2) dnl
79 pushdef(`dx',`ifelse(`$1',,0,`$1')') pushdef(`dy',`ifelse(`$2',,0,`$2')') dnl
80 pushdef(`dz',`ifelse(`$3',,0,`$3')') dnl
81 ixc = m4cubx # Front:
82 placecorner(ixc*3,de2,wd2,-hg2) # FSE
83 placecorner(ixc*3+1,de2,wd2,hg2) # FNE
84 placecorner(ixc*3+2,de2,-wd2,hg2) # FNW
85 mktriple(0,facetnormal(ixc))
86 if dot3D(triple(0),View3D) < 0 then {
87 placecorner(ixc*3,-de2,-wd2,-hg2) # FSE
88 placecorner(ixc*3+1,-de2,-wd2,hg2) # FNE
89 placecorner(ixc*3+2,-de2,wd2,hg2)} # FNW
90 ixc = m4cubx # Right:
91 placecorner(ixc*3,-de2,wd2,-hg2) # RSE
92 placecorner(ixc*3+1,-de2,wd2,hg2) # RNE
93 placecorner(ixc*3+2,de2,wd2,hg2) # RNW
94 mktriple(0,facetnormal(ixc))
95 if dot3D(triple(0),View3D) < 0 then {
96 placecorner(ixc*3,de2,-wd2,-hg2) # LSE
97 placecorner(ixc*3+1,de2,-wd2,hg2) # LNE
98 placecorner(ixc*3+2,-de2,-wd2,hg2)}# LNW
99 ixc = m4cubx # Top:
100 placecorner(ixc*3,de2,wd2,hg2) # TSE
101 placecorner(ixc*3+1,-de2,wd2,hg2) # TNE
102 placecorner(ixc*3+2,-de2,-wd2,hg2) # TNW
103 mktriple(0,facetnormal(ixc))
104 if dot3D(triple(0),View3D) < 0 then {
105 placecorner(ixc*3,-de2,wd2,-hg2) # USE U=underside
106 placecorner(ixc*3+1,de2,wd2,-hg2) # UNE
107 placecorner(ixc*3+2,de2,-wd2,-hg2)}# UNW
108 popdef(`m4cubx',`xr',`yr',`zr',`wd2',`hg2',`de2',`dx',`dy',`dz')
109 ')
110 define(`rots',`rot3Dz(ifelse(zr,,0,(zr)*dtor_),rot3Dy(ifelse(yr,,0,(yr)*dtor_),
111 rot3Dx(ifelse(xr,,0,(xr)*dtor_),`$1',`$2',`$3')))')
112 define(`placecorner',`mktriple(`$1',sum3D(dx,dy,dz,rots(`$2',`$3',`$4')))')
113
114 # Recover the 4th (SW) corner and draw
115 # `drawfacet(index,r,g,b)'
116 # `drawfacet(index,line attributes)'
117 define(`drawfacet',`
118 dnl print "`$0'($@)"
119 SE[`$1']: project(triple((`$1')*3))
120 NE[`$1']: project(triple((`$1')*3+1))
121 NW[`$1']: project(triple((`$1')*3+2))
122 SW[`$1']: NW[`$1']+SE[`$1']-NE[`$1']
123 N[`$1']: 0.5 between NW[`$1'] and NE[`$1']
124 C[`$1']: 0.5 between NW[`$1'] and SE[`$1']
125 Line[`$1']: line from N[`$1'] to NE[`$1'] then to SE[`$1'] \
126 then to SW[`$1'] then to NW[`$1'] then to N[`$1'] invis `$2'
127 ')
128
129 # Shortcut `processfacets(nfacets)'
130 define(`processfacets',
131 `indexfacets(`$1',nvisible)
132 drawfacets(nvisible) ')
133
134 # Create nvisible, arrays dircos[1..nvisible],
135 # dist[1..nvisible], and index
136 # sorted[1..nvisible] of facets; then sort.
137 # Uses macros facetnormal(i) and facetcenter(i)
138 define(`indexfacets',`nvis = 0
139 for i=1 to `$1' do {
140 mktriple(0,facetnormal(i))
141 dx = dot3D(triple(0),View3D)
142 if dx > 0 then { nvis +=1
143 dircos[nvis] = abs(dx/length3D(triple(0))) # dir cosine normal wrt View3D
144 dist[nvis] = dot3D(facetcenter(i),View3D) # distance along View3D
145 sorted[nvis] = i }
146 }; `$2' = nvis
147 if nvis > 1 then { dpquicksort(dist,1,nvis,sorted) } ')
148
149 # Compute posefactor and color, then draw.
150 define(`drawfacets',
151 `for i=1 to `$1' do {
152 posefactor=sqrt(dircos[i]*i/(`$1'))
153 ifdef(`facetcolor', facetcolor,
154 mktriple(1,(2+posefactor)/3,(2+posefactor)/3,(2+posefactor)/3) )
155 drawfacet(sorted[i],shaded rgbstring(triple(1)))
156 }
157 ifdef(`facetcolor',`popdef(`facetcolor')')
158 ')
159 #####################################################################
160 divert(0)dnl
161
162 # Threeplanes
163 [
164 setview( 10, 40 )
165 define(`m4x',0)
166 mkthreeplanes(3/2,0.4,1); nfacets = m4x
167 pushdef(`facetcolor',`mktriple(1,max(0,1-2*dircos[sorted[i]]),
168 dircos[sorted[i]],dircos[sorted[i]])')
169 processfacets(nfacets)
170 ]
171
172 define setfacetcolor { dnl This reduces color saturation depending on pose
173 mktriple(1,
174 (2*($1)+posefactor)/3,(2*($2)+posefactor)/3,(2*($3)+posefactor)/3) }
175
176 # Transistor
177 [
178 hsvtorgb(220,0.75,1, r1,g1,b1) # blueish
179 hsvtorgb(60,0.75,1, r2,g2,b2) # greenish
180 setview(-40, 20 )
181 skale = 1/2
182 footw = 5*skale
183 footh = 0.5*skale
184 footd = 3.5*skale
185 cstripd = footd*0.3
186 bludp = (footd-cstripd)/2
187 twd = cstripd
188 srch = 0.35*skale
189 twh = 7.5*srch
190 define(`footcolor',`0.45,0.45,0.45')
191 define(`m4cux',0)
192 # ( xC,yC,zC, wd2h,hg2t,depth, xrot,yrot,zrot)
193 mkcuboid(0,0,footh/2,footw,footh,footd)
194 mkcuboid(0,0,footh+bludp/2,footw,bludp,cstripd)
195 mkcuboid( footd/2-bludp/2,0,footh+bludp/2,footw,bludp,bludp)
196 mkcuboid(-footd/2+bludp/2,0,footh+bludp/2,footw,bludp,bludp)
197 mkcuboid(0,0,footh+bludp+twh/2,twd,twh,footd)
198 shelfw = (footw-twd)/2
199 for_(0,2,1,
200 `mkcuboid(0,-footw/2+shelfw/2,footh+bludp+srch*(3/2+2*m4x),
201 shelfw,srch,cstripd)
202 mkcuboid(0, footw/2-shelfw/2,footh+bludp+srch*(3/2+2*m4x),
203 shelfw,srch,cstripd) ')
204 nfacets = m4cux
205 pushdef(`facetcolor',
206 `if sorted[i]<=6 then { setfacetcolor(footcolor) } \# first two blocks
207 else { if sorted[i] <=12 then { setfacetcolor(r1,g1,b1) } \# blue blocks
208 else { if sorted[i] <=15 then {setfacetcolor(r2,g2,b2) } \
209 else { setfacetcolor(footcolor) }}}')
210 indexfacets(nfacets,nvisible) # Tweak the sort:
211 t = sorted[17]; sorted[17] = sorted[18]; sorted[18] = t
212 t = sorted[10]; sorted[10] = sorted[6]; sorted[6] = t
213 drawfacets(nvisible)
214 ] with .sw at last [].se+(0.2,0)
215
216 .PE