Debian Codegraph @

src/libmpg123/synth_x86_64_s32.S

raw
1 /*
2 synth_x86_64_s32: SSE optimized synth for x86-64 (s32 output version)
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* short *window; */
14 #define ARG0 %r10
15 /* short *b0; */
16 #define ARG1 %rdx
17 /* short *samples; */
18 #define ARG2 %r8
19 /* int bo1; */
20 #define ARG3 %r9
21 #else
22 /* real *window; */
23 #define ARG0 %rdi
24 /* real *b0; */
25 #define ARG1 %rsi
26 /* real *samples; */
27 #define ARG2 %rdx
28 /* int bo1; */
29 #define ARG3 %rcx
30 #endif
31
32 #define XMMREG_SCALE %xmm15 /* {65536.0, 65536.0, 65536.0, 65536.0} */
33 #define XMMREG_MAX %xmm14 /* {32767.999, 32767.999, 32767.999, 32767.999} */
34 #define XMMREG_MIN %xmm13 /* {-32768.0, -32768.0, -32768.0, -32768.0} */
35 #define XMMREG_CLIP %xmm12
36
37 /*
38 int synth_1to1_s32_x86_64_asm(real *window, real *b0, int32_t *samples, int bo1);
39 return value: number of clipped samples
40 */
41
42 RODATA
43 ALIGN32
44 ASM_NAME(INT123_scale_s32):
45 .long 1199570944
46 .long 1199570944
47 .long 1199570944
48 .long 1199570944
49 ALIGN16
50 ASM_NAME(INT123_maxmin_s32):
51 .long 1191182335
52 .long 1191182335
53 .long 1191182335
54 .long 1191182335
55 .long -956301312
56 .long -956301312
57 .long -956301312
58 .long -956301312
59 .text
60 ALIGN16
61 .globl ASM_NAME(INT123_synth_1to1_s32_x86_64_asm)
62 ASM_NAME(INT123_synth_1to1_s32_x86_64_asm):
63 #ifdef IS_MSABI /* should save xmm6-15 */
64 movq %rcx, ARG0
65 subq $168, %rsp /* stack alignment + 10 xmm registers */
66 movaps %xmm6, (%rsp)
67 movaps %xmm7, 16(%rsp)
68 movaps %xmm8, 32(%rsp)
69 movaps %xmm9, 48(%rsp)
70 movaps %xmm10, 64(%rsp)
71 movaps %xmm11, 80(%rsp)
72 movaps %xmm12, 96(%rsp)
73 movaps %xmm13, 112(%rsp)
74 movaps %xmm14, 128(%rsp)
75 movaps %xmm15, 144(%rsp)
76 #endif
77
78 leaq ASM_NAME(INT123_scale_s32)(%rip), %rax
79 movaps (%rax), XMMREG_SCALE
80 leaq ASM_NAME(INT123_maxmin_s32)(%rip), %rax
81 movaps (%rax), XMMREG_MAX
82 movaps 16(%rax), XMMREG_MIN
83
84 xorps XMMREG_CLIP, XMMREG_CLIP
85
86 andq $0xf, ARG3
87 shlq $2, ARG3
88 leaq 64(ARG0), ARG0
89 subq ARG3, ARG0
90
91 movl $4, %ecx
92
93 ALIGN16
94 1:
95 movups (ARG0), %xmm8
96 movups 16(ARG0), %xmm1
97 movups 32(ARG0), %xmm2
98 movups 48(ARG0), %xmm3
99 movups 128(ARG0), %xmm9
100 movups 144(ARG0), %xmm5
101 movups 160(ARG0), %xmm6
102 movups 176(ARG0), %xmm7
103 mulps (ARG1), %xmm8
104 mulps 16(ARG1), %xmm1
105 mulps 32(ARG1), %xmm2
106 mulps 48(ARG1), %xmm3
107 mulps 64(ARG1), %xmm9
108 mulps 80(ARG1), %xmm5
109 mulps 96(ARG1), %xmm6
110 mulps 112(ARG1), %xmm7
111
112 addps %xmm1, %xmm8
113 addps %xmm2, %xmm3
114 addps %xmm5, %xmm9
115 addps %xmm7, %xmm6
116 addps %xmm3, %xmm8
117 addps %xmm6, %xmm9
118 leaq 256(ARG0), ARG0
119 leaq 128(ARG1), ARG1
120
121 movups (ARG0), %xmm10
122 movups 16(ARG0), %xmm1
123 movups 32(ARG0), %xmm2
124 movups 48(ARG0), %xmm3
125 movups 128(ARG0), %xmm11
126 movups 144(ARG0), %xmm5
127 movups 160(ARG0), %xmm6
128 movups 176(ARG0), %xmm7
129 mulps (ARG1), %xmm10
130 mulps 16(ARG1), %xmm1
131 mulps 32(ARG1), %xmm2
132 mulps 48(ARG1), %xmm3
133 mulps 64(ARG1), %xmm11
134 mulps 80(ARG1), %xmm5
135 mulps 96(ARG1), %xmm6
136 mulps 112(ARG1), %xmm7
137
138 addps %xmm1, %xmm10
139 addps %xmm2, %xmm3
140 addps %xmm5, %xmm11
141 addps %xmm7, %xmm6
142 addps %xmm3, %xmm10
143 addps %xmm6, %xmm11
144 leaq 256(ARG0), ARG0
145 leaq 128(ARG1), ARG1
146
147 movaps %xmm8, %xmm0
148 movaps %xmm10, %xmm1
149 unpcklps %xmm9, %xmm8
150 unpcklps %xmm11, %xmm10
151 unpckhps %xmm9, %xmm0
152 unpckhps %xmm11, %xmm1
153 movaps %xmm8, %xmm2
154 movaps %xmm0, %xmm3
155 movlhps %xmm10, %xmm8
156 movhlps %xmm2, %xmm10
157 movlhps %xmm1, %xmm0
158 movhlps %xmm3, %xmm1
159 subps %xmm10, %xmm8
160 subps %xmm1, %xmm0
161 addps %xmm8, %xmm0
162
163 movups (ARG2), %xmm1
164 movups 16(ARG2), %xmm2
165 movaps %xmm0, %xmm3
166 movaps %xmm0, %xmm4
167 mulps XMMREG_SCALE, %xmm0
168 cmpnleps XMMREG_MAX, %xmm3
169 cmpltps XMMREG_MIN, %xmm4
170 cvtps2dq %xmm0, %xmm0
171 xorps %xmm3, %xmm0
172 shufps $0xdd, %xmm2, %xmm1
173 movaps %xmm0, %xmm2
174 unpcklps %xmm1, %xmm0
175 unpckhps %xmm1, %xmm2
176 movups %xmm0, (ARG2)
177 movups %xmm2, 16(ARG2)
178
179 psrld $31, %xmm3
180 psrld $31, %xmm4
181 paddd %xmm4, %xmm3
182 paddd %xmm3, XMMREG_CLIP
183
184 leaq 32(ARG2), ARG2
185 decl %ecx
186 jnz 1b
187
188 movl $4, %ecx
189
190 ALIGN16
191 1:
192 movups (ARG0), %xmm8
193 movups 16(ARG0), %xmm1
194 movups 32(ARG0), %xmm2
195 movups 48(ARG0), %xmm3
196 movups 128(ARG0), %xmm9
197 movups 144(ARG0), %xmm5
198 movups 160(ARG0), %xmm6
199 movups 176(ARG0), %xmm7
200 mulps (ARG1), %xmm8
201 mulps 16(ARG1), %xmm1
202 mulps 32(ARG1), %xmm2
203 mulps 48(ARG1), %xmm3
204 mulps -64(ARG1), %xmm9
205 mulps -48(ARG1), %xmm5
206 mulps -32(ARG1), %xmm6
207 mulps -16(ARG1), %xmm7
208
209 addps %xmm1, %xmm8
210 addps %xmm2, %xmm3
211 addps %xmm5, %xmm9
212 addps %xmm7, %xmm6
213 addps %xmm3, %xmm8
214 addps %xmm6, %xmm9
215 leaq 256(ARG0), ARG0
216 leaq -128(ARG1), ARG1
217
218 movups (ARG0), %xmm10
219 movups 16(ARG0), %xmm1
220 movups 32(ARG0), %xmm2
221 movups 48(ARG0), %xmm3
222 movups 128(ARG0), %xmm11
223 movups 144(ARG0), %xmm5
224 movups 160(ARG0), %xmm6
225 movups 176(ARG0), %xmm7
226 mulps (ARG1), %xmm10
227 mulps 16(ARG1), %xmm1
228 mulps 32(ARG1), %xmm2
229 mulps 48(ARG1), %xmm3
230 mulps -64(ARG1), %xmm11
231 mulps -48(ARG1), %xmm5
232 mulps -32(ARG1), %xmm6
233 mulps -16(ARG1), %xmm7
234
235 addps %xmm1, %xmm10
236 addps %xmm2, %xmm3
237 addps %xmm5, %xmm11
238 addps %xmm7, %xmm6
239 addps %xmm3, %xmm10
240 addps %xmm6, %xmm11
241 leaq 256(ARG0), ARG0
242 leaq -128(ARG1), ARG1
243
244 movaps %xmm8, %xmm0
245 movaps %xmm10, %xmm1
246 unpcklps %xmm9, %xmm8
247 unpcklps %xmm11, %xmm10
248 unpckhps %xmm9, %xmm0
249 unpckhps %xmm11, %xmm1
250 movaps %xmm8, %xmm2
251 movaps %xmm0, %xmm3
252 movlhps %xmm10, %xmm8
253 movhlps %xmm2, %xmm10
254 movlhps %xmm1, %xmm0
255 movhlps %xmm3, %xmm1
256 addps %xmm10, %xmm8
257 addps %xmm1, %xmm0
258 addps %xmm8, %xmm0
259
260 movups (ARG2), %xmm1
261 movups 16(ARG2), %xmm2
262 movaps %xmm0, %xmm3
263 movaps %xmm0, %xmm4
264 mulps XMMREG_SCALE, %xmm0
265 cmpnleps XMMREG_MAX, %xmm3
266 cmpltps XMMREG_MIN, %xmm4
267 cvtps2dq %xmm0, %xmm0
268 xorps %xmm3, %xmm0
269 shufps $0xdd, %xmm2, %xmm1
270 movaps %xmm0, %xmm2
271 unpcklps %xmm1, %xmm0
272 unpckhps %xmm1, %xmm2
273 movups %xmm0, (ARG2)
274 movups %xmm2, 16(ARG2)
275
276 psrld $31, %xmm3
277 psrld $31, %xmm4
278 paddd %xmm4, %xmm3
279 paddd %xmm3, XMMREG_CLIP
280
281 leaq 32(ARG2), ARG2
282 decl %ecx
283 jnz 1b
284
285 pshuflw $0xee, XMMREG_CLIP, %xmm0
286 movhlps XMMREG_CLIP, %xmm1
287 pshuflw $0xee, %xmm1, %xmm2
288 paddd %xmm0, XMMREG_CLIP
289 paddd %xmm1, XMMREG_CLIP
290 paddd %xmm2, XMMREG_CLIP
291
292 movd XMMREG_CLIP, %eax
293
294 #ifdef IS_MSABI
295 movaps (%rsp), %xmm6
296 movaps 16(%rsp), %xmm7
297 movaps 32(%rsp), %xmm8
298 movaps 48(%rsp), %xmm9
299 movaps 64(%rsp), %xmm10
300 movaps 80(%rsp), %xmm11
301 movaps 96(%rsp), %xmm12
302 movaps 112(%rsp), %xmm13
303 movaps 128(%rsp), %xmm14
304 movaps 144(%rsp), %xmm15
305 addq $168, %rsp
306 #endif
307 ret
308
309 NONEXEC_STACK