Debian Codegraph @

src/libmpg123/synth_stereo_avx_float.S

raw
1 /*
2 synth_stereo_avx_float: AVX optimized synth for x86-64 (stereo specific, float output version)
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* real *window; */
14 #define WINDOW %r10
15 /* real *b0l; */
16 #define B0L %rdx
17 /* real *b0r; */
18 #define B0R %r8
19 /* real *samples; */
20 #define SAMPLES %r9
21 #else
22 /* real *window; */
23 #define WINDOW %rdi
24 /* real *b0l; */
25 #define B0L %rsi
26 /* real *b0r; */
27 #define B0R %rdx
28 /* real *samples; */
29 #define SAMPLES %r9
30 #endif
31
32 /*
33 int synth_1to1_real_s_avx_asm(real *window, real *b0l, real *b0r, real *samples, int bo1);
34 return value: number of clipped samples (0)
35 */
36
37 RODATA
38 ALIGN16
39 scale_avx:
40 .long 939524096
41 .text
42 ALIGN16
43 .globl ASM_NAME(INT123_synth_1to1_real_s_avx_asm)
44 ASM_NAME(INT123_synth_1to1_real_s_avx_asm):
45 #ifdef IS_MSABI /* should save xmm6-15 */
46 push %rbp
47 mov %rsp, %rbp
48 sub $144, %rsp
49 movaps %xmm6, (%rsp)
50 movaps %xmm7, 16(%rsp)
51 movaps %xmm8, 32(%rsp)
52 movaps %xmm9, 48(%rsp)
53 movaps %xmm10, 64(%rsp)
54 movaps %xmm11, 80(%rsp)
55 movaps %xmm12, 96(%rsp)
56 movaps %xmm13, 112(%rsp)
57 movaps %xmm14, 128(%rsp)
58 movl 48(%rbp), %eax /* 5th argument; placed after 32-byte shadow space */
59 #endif
60
61 vbroadcastss scale_avx(%rip), %ymm14
62
63 #ifdef IS_MSABI
64 shl $2, %eax
65 mov %rcx, WINDOW
66 #else
67 mov %r8d, %eax
68 shl $2, %eax
69 mov %rcx, SAMPLES
70 #endif
71 add $64, WINDOW
72 sub %rax, WINDOW
73
74 mov $128, %rax
75 mov $4, %ecx
76
77 ALIGN16
78 1:
79 vmovups (WINDOW), %ymm8
80 vmovups 32(WINDOW), %ymm9
81 vmovups (WINDOW,%rax), %ymm10
82 vmovups 32(WINDOW,%rax), %ymm11
83 vmulps (B0L), %ymm8, %ymm0
84 vmulps 32(B0L), %ymm9, %ymm1
85 vmulps (B0R), %ymm8, %ymm2
86 vmulps 32(B0R), %ymm9, %ymm3
87 vmulps 64(B0L), %ymm10, %ymm4
88 vmulps 96(B0L), %ymm11, %ymm5
89 vmulps 64(B0R), %ymm10, %ymm6
90 vmulps 96(B0R), %ymm11, %ymm7
91 vaddps %ymm1, %ymm0, %ymm8
92 vaddps %ymm3, %ymm2, %ymm0
93 vaddps %ymm5, %ymm4, %ymm9
94 vaddps %ymm7, %ymm6, %ymm1
95 lea (WINDOW,%rax,2), WINDOW
96 add %rax, B0L
97 add %rax, B0R
98
99 vmovups (WINDOW), %ymm10
100 vmovups 32(WINDOW), %ymm11
101 vmovups (WINDOW,%rax), %ymm12
102 vmovups 32(WINDOW,%rax), %ymm13
103 vmulps (B0L), %ymm10, %ymm2
104 vmulps 32(B0L), %ymm11, %ymm3
105 vmulps (B0R), %ymm10, %ymm4
106 vmulps 32(B0R), %ymm11, %ymm5
107 vmulps 64(B0L), %ymm12, %ymm6
108 vmulps 96(B0L), %ymm13, %ymm10
109 vmulps 64(B0R), %ymm12, %ymm7
110 vmulps 96(B0R), %ymm13, %ymm11
111 vaddps %ymm3, %ymm2, %ymm2
112 vaddps %ymm5, %ymm4, %ymm3
113 vaddps %ymm6, %ymm10, %ymm4
114 vaddps %ymm7, %ymm11, %ymm5
115 lea (WINDOW,%rax,2), WINDOW
116 add %rax, B0L
117 add %rax, B0R
118
119 vunpcklps %ymm0, %ymm8, %ymm6
120 vunpckhps %ymm0, %ymm8, %ymm0
121 vunpcklps %ymm1, %ymm9, %ymm7
122 vunpckhps %ymm1, %ymm9, %ymm1
123 vaddps %ymm6, %ymm0, %ymm0
124 vaddps %ymm7, %ymm1, %ymm1
125 vunpcklps %ymm3, %ymm2, %ymm6
126 vunpckhps %ymm3, %ymm2, %ymm2
127 vunpcklps %ymm5, %ymm4, %ymm7
128 vunpckhps %ymm5, %ymm4, %ymm3
129 vaddps %ymm6, %ymm2, %ymm2
130 vaddps %ymm7, %ymm3, %ymm3
131
132 vunpcklpd %ymm1, %ymm0, %ymm4
133 vunpckhpd %ymm1, %ymm0, %ymm0
134 vunpcklpd %ymm3, %ymm2, %ymm5
135 vunpckhpd %ymm3, %ymm2, %ymm1
136 vsubps %ymm0, %ymm4, %ymm0
137 vsubps %ymm1, %ymm5, %ymm1
138 vperm2f128 $0x20, %ymm1, %ymm0, %ymm2
139 vperm2f128 $0x31, %ymm1, %ymm0, %ymm3
140 vaddps %ymm3, %ymm2, %ymm0
141 vmulps %ymm14, %ymm0, %ymm0
142
143 vmovups %ymm0, (SAMPLES)
144 add $32, SAMPLES
145 dec %ecx
146 jnz 1b
147
148 mov $4, %ecx
149
150 ALIGN16
151 1:
152 vmovups (WINDOW), %ymm8
153 vmovups 32(WINDOW), %ymm9
154 vmovups (WINDOW,%rax), %ymm10
155 vmovups 32(WINDOW,%rax), %ymm11
156 vmulps (B0L), %ymm8, %ymm0
157 vmulps 32(B0L), %ymm9, %ymm1
158 vmulps (B0R), %ymm8, %ymm2
159 vmulps 32(B0R), %ymm9, %ymm3
160 vmulps -64(B0L), %ymm10, %ymm4
161 vmulps -32(B0L), %ymm11, %ymm5
162 vmulps -64(B0R), %ymm10, %ymm6
163 vmulps -32(B0R), %ymm11, %ymm7
164 vaddps %ymm1, %ymm0, %ymm8
165 vaddps %ymm3, %ymm2, %ymm0
166 vaddps %ymm5, %ymm4, %ymm9
167 vaddps %ymm7, %ymm6, %ymm1
168 lea (WINDOW,%rax,2), WINDOW
169 sub %rax, B0L
170 sub %rax, B0R
171
172 vmovups (WINDOW), %ymm10
173 vmovups 32(WINDOW), %ymm11
174 vmovups (WINDOW,%rax), %ymm12
175 vmovups 32(WINDOW,%rax), %ymm13
176 vmulps (B0L), %ymm10, %ymm2
177 vmulps 32(B0L), %ymm11, %ymm3
178 vmulps (B0R), %ymm10, %ymm4
179 vmulps 32(B0R), %ymm11, %ymm5
180 vmulps -64(B0L), %ymm12, %ymm6
181 vmulps -32(B0L), %ymm13, %ymm10
182 vmulps -64(B0R), %ymm12, %ymm7
183 vmulps -32(B0R), %ymm13, %ymm11
184 vaddps %ymm3, %ymm2, %ymm2
185 vaddps %ymm5, %ymm4, %ymm3
186 vaddps %ymm6, %ymm10, %ymm4
187 vaddps %ymm7, %ymm11, %ymm5
188 lea (WINDOW,%rax,2), WINDOW
189 sub %rax, B0L
190 sub %rax, B0R
191
192 vunpcklps %ymm0, %ymm8, %ymm6
193 vunpckhps %ymm0, %ymm8, %ymm0
194 vunpcklps %ymm1, %ymm9, %ymm7
195 vunpckhps %ymm1, %ymm9, %ymm1
196 vaddps %ymm6, %ymm0, %ymm0
197 vaddps %ymm7, %ymm1, %ymm1
198 vunpcklps %ymm3, %ymm2, %ymm6
199 vunpckhps %ymm3, %ymm2, %ymm2
200 vunpcklps %ymm5, %ymm4, %ymm7
201 vunpckhps %ymm5, %ymm4, %ymm3
202 vaddps %ymm6, %ymm2, %ymm2
203 vaddps %ymm7, %ymm3, %ymm3
204
205 vunpcklpd %ymm1, %ymm0, %ymm4
206 vunpckhpd %ymm1, %ymm0, %ymm0
207 vunpcklpd %ymm3, %ymm2, %ymm5
208 vunpckhpd %ymm3, %ymm2, %ymm1
209 vaddps %ymm0, %ymm4, %ymm0
210 vaddps %ymm1, %ymm5, %ymm1
211 vperm2f128 $0x20, %ymm1, %ymm0, %ymm2
212 vperm2f128 $0x31, %ymm1, %ymm0, %ymm3
213 vaddps %ymm3, %ymm2, %ymm0
214 vmulps %ymm14, %ymm0, %ymm0
215
216 vmovups %ymm0, (SAMPLES)
217 add $32, SAMPLES
218 dec %ecx
219 jnz 1b
220
221 vzeroupper
222
223 xor %eax, %eax
224
225 #ifdef IS_MSABI
226 movaps (%rsp), %xmm6
227 movaps 16(%rsp), %xmm7
228 movaps 32(%rsp), %xmm8
229 movaps 48(%rsp), %xmm9
230 movaps 64(%rsp), %xmm10
231 movaps 80(%rsp), %xmm11
232 movaps 96(%rsp), %xmm12
233 movaps 112(%rsp), %xmm13
234 movaps 128(%rsp), %xmm14
235 mov %rbp, %rsp
236 pop %rbp
237 #endif
238 ret
239
240 NONEXEC_STACK