| 1 |
/* |
| 2 |
synth_stereo_x86_64_float: SSE optimized synth for x86-64 (stereo specific, float output version) |
| 3 |
|
| 4 |
copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1 |
| 5 |
see COPYING and AUTHORS files in distribution or http://mpg123.org |
| 6 |
initially written by Taihei Monma |
| 7 |
*/ |
| 8 |
|
| 9 |
#include "x86_64_defs.h" |
| 10 |
#include "mangle.h" |
| 11 |
|
| 12 |
#ifdef IS_MSABI |
| 13 |
/* short *window; */ |
| 14 |
#define WINDOW %r10 |
| 15 |
/* short *b0l; */ |
| 16 |
#define B0L %rdx |
| 17 |
/* short *b0r; */ |
| 18 |
#define B0R %r8 |
| 19 |
/* short *samples; */ |
| 20 |
#define SAMPLES %r9 |
| 21 |
#else |
| 22 |
/* real *window; */ |
| 23 |
#define WINDOW %rdi |
| 24 |
/* real *b0l; */ |
| 25 |
#define B0L %rsi |
| 26 |
/* real *b0r; */ |
| 27 |
#define B0R %rdx |
| 28 |
/* real *samples; */ |
| 29 |
#define SAMPLES %r9 |
| 30 |
#endif |
| 31 |
|
| 32 |
#define XMMREG_SCALE (%r11) /* {1/32768.0, 1/32768.0, 1/32768.0, 1/32768.0} */ |
| 33 |
|
| 34 |
/* |
| 35 |
int synth_1to1_real_s_x86_64_asm(real *window, real *b0l, real *b0r, real *samples, int bo1); |
| 36 |
return value: number of clipped samples (0) |
| 37 |
*/ |
| 38 |
|
| 39 |
RODATA |
| 40 |
ALIGN32 |
| 41 |
ASM_NAME(INT123_scale_x86_64): |
| 42 |
.long 939524096 |
| 43 |
.long 939524096 |
| 44 |
.long 939524096 |
| 45 |
.long 939524096 |
| 46 |
.text |
| 47 |
ALIGN16 |
| 48 |
.globl ASM_NAME(INT123_synth_1to1_real_s_x86_64_asm) |
| 49 |
ASM_NAME(INT123_synth_1to1_real_s_x86_64_asm): |
| 50 |
#ifdef IS_MSABI /* should save xmm6-15 */ |
| 51 |
movl 40(%rsp), %eax /* 5th argument; placed after 32-byte shadow space */ |
| 52 |
subq $168, %rsp /* stack alignment + 10 xmm registers */ |
| 53 |
movaps %xmm6, (%rsp) |
| 54 |
movaps %xmm7, 16(%rsp) |
| 55 |
movaps %xmm8, 32(%rsp) |
| 56 |
movaps %xmm9, 48(%rsp) |
| 57 |
movaps %xmm10, 64(%rsp) |
| 58 |
movaps %xmm11, 80(%rsp) |
| 59 |
movaps %xmm12, 96(%rsp) |
| 60 |
movaps %xmm13, 112(%rsp) |
| 61 |
movaps %xmm14, 128(%rsp) |
| 62 |
movaps %xmm15, 144(%rsp) |
| 63 |
#endif |
| 64 |
|
| 65 |
leaq ASM_NAME(INT123_scale_x86_64)(%rip), %r11 |
| 66 |
|
| 67 |
#ifdef IS_MSABI |
| 68 |
shlq $32, %rax |
| 69 |
shrq $30, %rax |
| 70 |
movq %rcx, %r10 |
| 71 |
#else |
| 72 |
movq %r8, %rax |
| 73 |
shlq $32, %rax |
| 74 |
shrq $30, %rax |
| 75 |
movq %rcx, %r9 |
| 76 |
#endif |
| 77 |
leaq 64(WINDOW), WINDOW |
| 78 |
subq %rax, WINDOW |
| 79 |
|
| 80 |
movl $4, %ecx |
| 81 |
|
| 82 |
ALIGN16 |
| 83 |
1: |
| 84 |
movups (WINDOW), %xmm8 |
| 85 |
movups 16(WINDOW), %xmm1 |
| 86 |
movups 32(WINDOW), %xmm2 |
| 87 |
movups 48(WINDOW), %xmm3 |
| 88 |
movups 128(WINDOW), %xmm9 |
| 89 |
movups 144(WINDOW), %xmm5 |
| 90 |
movups 160(WINDOW), %xmm6 |
| 91 |
movups 176(WINDOW), %xmm7 |
| 92 |
movaps %xmm8, %xmm0 |
| 93 |
movaps %xmm1, %xmm4 |
| 94 |
movaps %xmm2, %xmm10 |
| 95 |
movaps %xmm3, %xmm11 |
| 96 |
movaps %xmm9, %xmm12 |
| 97 |
movaps %xmm5, %xmm13 |
| 98 |
movaps %xmm6, %xmm14 |
| 99 |
movaps %xmm7, %xmm15 |
| 100 |
mulps (B0L), %xmm8 |
| 101 |
mulps 16(B0L), %xmm1 |
| 102 |
mulps 32(B0L), %xmm2 |
| 103 |
mulps 48(B0L), %xmm3 |
| 104 |
mulps 64(B0L), %xmm9 |
| 105 |
mulps 80(B0L), %xmm5 |
| 106 |
mulps 96(B0L), %xmm6 |
| 107 |
mulps 112(B0L), %xmm7 |
| 108 |
mulps (B0R), %xmm0 |
| 109 |
mulps 16(B0R), %xmm4 |
| 110 |
mulps 32(B0R), %xmm10 |
| 111 |
mulps 48(B0R), %xmm11 |
| 112 |
mulps 64(B0R), %xmm12 |
| 113 |
mulps 80(B0R), %xmm13 |
| 114 |
mulps 96(B0R), %xmm14 |
| 115 |
mulps 112(B0R), %xmm15 |
| 116 |
|
| 117 |
addps %xmm1, %xmm8 |
| 118 |
addps %xmm2, %xmm3 |
| 119 |
addps %xmm4, %xmm0 |
| 120 |
addps %xmm11, %xmm10 |
| 121 |
addps %xmm5, %xmm9 |
| 122 |
addps %xmm7, %xmm6 |
| 123 |
addps %xmm13, %xmm12 |
| 124 |
addps %xmm15, %xmm14 |
| 125 |
addps %xmm3, %xmm8 |
| 126 |
addps %xmm6, %xmm9 |
| 127 |
addps %xmm10, %xmm0 |
| 128 |
addps %xmm12, %xmm14 |
| 129 |
movaps %xmm0, %xmm12 |
| 130 |
movaps %xmm14, %xmm13 |
| 131 |
leaq 256(WINDOW), WINDOW |
| 132 |
leaq 128(B0L), B0L |
| 133 |
leaq 128(B0R), B0R |
| 134 |
|
| 135 |
movups (WINDOW), %xmm10 |
| 136 |
movups 16(WINDOW), %xmm1 |
| 137 |
movups 32(WINDOW), %xmm2 |
| 138 |
movups 48(WINDOW), %xmm3 |
| 139 |
movups 128(WINDOW), %xmm11 |
| 140 |
movups 144(WINDOW), %xmm5 |
| 141 |
movups 160(WINDOW), %xmm6 |
| 142 |
movups 176(WINDOW), %xmm7 |
| 143 |
movaps %xmm10, %xmm0 |
| 144 |
movaps %xmm1, %xmm4 |
| 145 |
movaps %xmm2, %xmm14 |
| 146 |
movaps %xmm3, %xmm15 |
| 147 |
mulps (B0L), %xmm10 |
| 148 |
mulps 16(B0L), %xmm1 |
| 149 |
mulps 32(B0L), %xmm2 |
| 150 |
mulps 48(B0L), %xmm3 |
| 151 |
mulps (B0R), %xmm0 |
| 152 |
mulps 16(B0R), %xmm4 |
| 153 |
mulps 32(B0R), %xmm14 |
| 154 |
mulps 48(B0R), %xmm15 |
| 155 |
addps %xmm1, %xmm10 |
| 156 |
addps %xmm2, %xmm3 |
| 157 |
addps %xmm4, %xmm0 |
| 158 |
addps %xmm15, %xmm14 |
| 159 |
movaps %xmm11, %xmm1 |
| 160 |
movaps %xmm5, %xmm2 |
| 161 |
movaps %xmm6, %xmm4 |
| 162 |
movaps %xmm7, %xmm15 |
| 163 |
mulps 64(B0L), %xmm11 |
| 164 |
mulps 80(B0L), %xmm5 |
| 165 |
mulps 96(B0L), %xmm6 |
| 166 |
mulps 112(B0L), %xmm7 |
| 167 |
mulps 64(B0R), %xmm1 |
| 168 |
mulps 80(B0R), %xmm2 |
| 169 |
mulps 96(B0R), %xmm4 |
| 170 |
mulps 112(B0R), %xmm15 |
| 171 |
addps %xmm5, %xmm11 |
| 172 |
addps %xmm7, %xmm6 |
| 173 |
addps %xmm2, %xmm1 |
| 174 |
addps %xmm15, %xmm4 |
| 175 |
|
| 176 |
addps %xmm3, %xmm10 |
| 177 |
addps %xmm6, %xmm11 |
| 178 |
addps %xmm0, %xmm14 |
| 179 |
addps %xmm4, %xmm1 |
| 180 |
movaps %xmm1, %xmm15 |
| 181 |
leaq 256(WINDOW), WINDOW |
| 182 |
leaq 128(B0L), B0L |
| 183 |
leaq 128(B0R), B0R |
| 184 |
|
| 185 |
movaps %xmm8, %xmm0 |
| 186 |
movaps %xmm10, %xmm1 |
| 187 |
movaps %xmm12, %xmm4 |
| 188 |
movaps %xmm14, %xmm5 |
| 189 |
unpcklps %xmm9, %xmm8 |
| 190 |
unpcklps %xmm11, %xmm10 |
| 191 |
unpckhps %xmm9, %xmm0 |
| 192 |
unpckhps %xmm11, %xmm1 |
| 193 |
unpcklps %xmm13, %xmm12 |
| 194 |
unpcklps %xmm15, %xmm14 |
| 195 |
unpckhps %xmm13, %xmm4 |
| 196 |
unpckhps %xmm15, %xmm5 |
| 197 |
movaps %xmm8, %xmm2 |
| 198 |
movaps %xmm0, %xmm3 |
| 199 |
movaps %xmm12, %xmm6 |
| 200 |
movaps %xmm4, %xmm7 |
| 201 |
movlhps %xmm10, %xmm8 |
| 202 |
movhlps %xmm2, %xmm10 |
| 203 |
movlhps %xmm1, %xmm0 |
| 204 |
movhlps %xmm3, %xmm1 |
| 205 |
movlhps %xmm14, %xmm12 |
| 206 |
movhlps %xmm6, %xmm14 |
| 207 |
movlhps %xmm5, %xmm4 |
| 208 |
movhlps %xmm7, %xmm5 |
| 209 |
subps %xmm10, %xmm8 |
| 210 |
subps %xmm1, %xmm0 |
| 211 |
subps %xmm14, %xmm12 |
| 212 |
subps %xmm5, %xmm4 |
| 213 |
addps %xmm8, %xmm0 |
| 214 |
addps %xmm12, %xmm4 |
| 215 |
|
| 216 |
mulps XMMREG_SCALE, %xmm0 |
| 217 |
mulps XMMREG_SCALE, %xmm4 |
| 218 |
movaps %xmm0, %xmm1 |
| 219 |
unpcklps %xmm4, %xmm0 |
| 220 |
unpckhps %xmm4, %xmm1 |
| 221 |
movups %xmm0, (SAMPLES) |
| 222 |
movups %xmm1, 16(SAMPLES) |
| 223 |
|
| 224 |
leaq 32(SAMPLES), SAMPLES |
| 225 |
decl %ecx |
| 226 |
jnz 1b |
| 227 |
|
| 228 |
movl $4, %ecx |
| 229 |
|
| 230 |
ALIGN16 |
| 231 |
1: |
| 232 |
movups (WINDOW), %xmm8 |
| 233 |
movups 16(WINDOW), %xmm1 |
| 234 |
movups 32(WINDOW), %xmm2 |
| 235 |
movups 48(WINDOW), %xmm3 |
| 236 |
movups 128(WINDOW), %xmm9 |
| 237 |
movups 144(WINDOW), %xmm5 |
| 238 |
movups 160(WINDOW), %xmm6 |
| 239 |
movups 176(WINDOW), %xmm7 |
| 240 |
movaps %xmm8, %xmm0 |
| 241 |
movaps %xmm1, %xmm4 |
| 242 |
movaps %xmm2, %xmm10 |
| 243 |
movaps %xmm3, %xmm11 |
| 244 |
movaps %xmm9, %xmm12 |
| 245 |
movaps %xmm5, %xmm13 |
| 246 |
movaps %xmm6, %xmm14 |
| 247 |
movaps %xmm7, %xmm15 |
| 248 |
mulps (B0L), %xmm8 |
| 249 |
mulps 16(B0L), %xmm1 |
| 250 |
mulps 32(B0L), %xmm2 |
| 251 |
mulps 48(B0L), %xmm3 |
| 252 |
mulps -64(B0L), %xmm9 |
| 253 |
mulps -48(B0L), %xmm5 |
| 254 |
mulps -32(B0L), %xmm6 |
| 255 |
mulps -16(B0L), %xmm7 |
| 256 |
mulps (B0R), %xmm0 |
| 257 |
mulps 16(B0R), %xmm4 |
| 258 |
mulps 32(B0R), %xmm10 |
| 259 |
mulps 48(B0R), %xmm11 |
| 260 |
mulps -64(B0R), %xmm12 |
| 261 |
mulps -48(B0R), %xmm13 |
| 262 |
mulps -32(B0R), %xmm14 |
| 263 |
mulps -16(B0R), %xmm15 |
| 264 |
|
| 265 |
addps %xmm1, %xmm8 |
| 266 |
addps %xmm2, %xmm3 |
| 267 |
addps %xmm4, %xmm0 |
| 268 |
addps %xmm11, %xmm10 |
| 269 |
addps %xmm5, %xmm9 |
| 270 |
addps %xmm7, %xmm6 |
| 271 |
addps %xmm13, %xmm12 |
| 272 |
addps %xmm15, %xmm14 |
| 273 |
addps %xmm3, %xmm8 |
| 274 |
addps %xmm6, %xmm9 |
| 275 |
addps %xmm10, %xmm0 |
| 276 |
addps %xmm12, %xmm14 |
| 277 |
movaps %xmm0, %xmm12 |
| 278 |
movaps %xmm14, %xmm13 |
| 279 |
leaq 256(WINDOW), WINDOW |
| 280 |
leaq -128(B0L), B0L |
| 281 |
leaq -128(B0R), B0R |
| 282 |
|
| 283 |
movups (WINDOW), %xmm10 |
| 284 |
movups 16(WINDOW), %xmm1 |
| 285 |
movups 32(WINDOW), %xmm2 |
| 286 |
movups 48(WINDOW), %xmm3 |
| 287 |
movups 128(WINDOW), %xmm11 |
| 288 |
movups 144(WINDOW), %xmm5 |
| 289 |
movups 160(WINDOW), %xmm6 |
| 290 |
movups 176(WINDOW), %xmm7 |
| 291 |
movaps %xmm10, %xmm0 |
| 292 |
movaps %xmm1, %xmm4 |
| 293 |
movaps %xmm2, %xmm14 |
| 294 |
movaps %xmm3, %xmm15 |
| 295 |
mulps (B0L), %xmm10 |
| 296 |
mulps 16(B0L), %xmm1 |
| 297 |
mulps 32(B0L), %xmm2 |
| 298 |
mulps 48(B0L), %xmm3 |
| 299 |
mulps (B0R), %xmm0 |
| 300 |
mulps 16(B0R), %xmm4 |
| 301 |
mulps 32(B0R), %xmm14 |
| 302 |
mulps 48(B0R), %xmm15 |
| 303 |
addps %xmm1, %xmm10 |
| 304 |
addps %xmm2, %xmm3 |
| 305 |
addps %xmm4, %xmm0 |
| 306 |
addps %xmm15, %xmm14 |
| 307 |
movaps %xmm11, %xmm1 |
| 308 |
movaps %xmm5, %xmm2 |
| 309 |
movaps %xmm6, %xmm4 |
| 310 |
movaps %xmm7, %xmm15 |
| 311 |
mulps -64(B0L), %xmm11 |
| 312 |
mulps -48(B0L), %xmm5 |
| 313 |
mulps -32(B0L), %xmm6 |
| 314 |
mulps -16(B0L), %xmm7 |
| 315 |
mulps -64(B0R), %xmm1 |
| 316 |
mulps -48(B0R), %xmm2 |
| 317 |
mulps -32(B0R), %xmm4 |
| 318 |
mulps -16(B0R), %xmm15 |
| 319 |
addps %xmm5, %xmm11 |
| 320 |
addps %xmm7, %xmm6 |
| 321 |
addps %xmm2, %xmm1 |
| 322 |
addps %xmm15, %xmm4 |
| 323 |
|
| 324 |
addps %xmm3, %xmm10 |
| 325 |
addps %xmm6, %xmm11 |
| 326 |
addps %xmm0, %xmm14 |
| 327 |
addps %xmm4, %xmm1 |
| 328 |
movaps %xmm1, %xmm15 |
| 329 |
leaq 256(WINDOW), WINDOW |
| 330 |
leaq -128(B0L), B0L |
| 331 |
leaq -128(B0R), B0R |
| 332 |
|
| 333 |
movaps %xmm8, %xmm0 |
| 334 |
movaps %xmm10, %xmm1 |
| 335 |
movaps %xmm12, %xmm4 |
| 336 |
movaps %xmm14, %xmm5 |
| 337 |
unpcklps %xmm9, %xmm8 |
| 338 |
unpcklps %xmm11, %xmm10 |
| 339 |
unpckhps %xmm9, %xmm0 |
| 340 |
unpckhps %xmm11, %xmm1 |
| 341 |
unpcklps %xmm13, %xmm12 |
| 342 |
unpcklps %xmm15, %xmm14 |
| 343 |
unpckhps %xmm13, %xmm4 |
| 344 |
unpckhps %xmm15, %xmm5 |
| 345 |
movaps %xmm8, %xmm2 |
| 346 |
movaps %xmm0, %xmm3 |
| 347 |
movaps %xmm12, %xmm6 |
| 348 |
movaps %xmm4, %xmm7 |
| 349 |
movlhps %xmm10, %xmm8 |
| 350 |
movhlps %xmm2, %xmm10 |
| 351 |
movlhps %xmm1, %xmm0 |
| 352 |
movhlps %xmm3, %xmm1 |
| 353 |
movlhps %xmm14, %xmm12 |
| 354 |
movhlps %xmm6, %xmm14 |
| 355 |
movlhps %xmm5, %xmm4 |
| 356 |
movhlps %xmm7, %xmm5 |
| 357 |
addps %xmm10, %xmm8 |
| 358 |
addps %xmm1, %xmm0 |
| 359 |
addps %xmm14, %xmm12 |
| 360 |
addps %xmm5, %xmm4 |
| 361 |
addps %xmm8, %xmm0 |
| 362 |
addps %xmm12, %xmm4 |
| 363 |
|
| 364 |
mulps XMMREG_SCALE, %xmm0 |
| 365 |
mulps XMMREG_SCALE, %xmm4 |
| 366 |
movaps %xmm0, %xmm1 |
| 367 |
unpcklps %xmm4, %xmm0 |
| 368 |
unpckhps %xmm4, %xmm1 |
| 369 |
movups %xmm0, (SAMPLES) |
| 370 |
movups %xmm1, 16(SAMPLES) |
| 371 |
|
| 372 |
leaq 32(SAMPLES), SAMPLES |
| 373 |
decl %ecx |
| 374 |
jnz 1b |
| 375 |
|
| 376 |
xorl %eax, %eax |
| 377 |
|
| 378 |
#ifdef IS_MSABI |
| 379 |
movaps (%rsp), %xmm6 |
| 380 |
movaps 16(%rsp), %xmm7 |
| 381 |
movaps 32(%rsp), %xmm8 |
| 382 |
movaps 48(%rsp), %xmm9 |
| 383 |
movaps 64(%rsp), %xmm10 |
| 384 |
movaps 80(%rsp), %xmm11 |
| 385 |
movaps 96(%rsp), %xmm12 |
| 386 |
movaps 112(%rsp), %xmm13 |
| 387 |
movaps 128(%rsp), %xmm14 |
| 388 |
movaps 144(%rsp), %xmm15 |
| 389 |
addq $168, %rsp |
| 390 |
#endif |
| 391 |
ret |
| 392 |
|
| 393 |
NONEXEC_STACK |