Debian Codegraph @

src/libmpg123/dct64_sse_float.S

raw
1 /*
2 dct64_sse_float: SSE optimized dct64 (float output version)
3
4 copyright 1995-2009 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "mangle.h"
10
11 #define ARG(n) (8+n*4)(%ebp)
12 #define TEMP(n) (4+n*16)(%esp)
13 #define TEMP_BYTE(n) (4+n)(%esp)
14
15 /*
16 void dct64_real_sse(real *out0, real *out1, real *samples);
17 */
18
19 RODATA
20 ALIGN16
21 pnpn:
22 .long 0
23 .long -2147483648
24 .long 0
25 .long -2147483648
26 ALIGN16
27 mask:
28 .long -1
29 .long -1
30 .long -1
31 .long 0
32
33 .text
34 ALIGN16
35 .globl ASM_NAME(INT123_dct64_real_sse)
36 ASM_NAME(INT123_dct64_real_sse):
37 pushl %ebp
38 movl %esp, %ebp
39
40 andl $-16, %esp /* align the stack at 16 bytes */
41 subl $128, %esp /* reserve space for temporal store */
42 pushl %ebx
43
44 GET_GOT
45
46 movl ARG(2), %eax
47
48 MOVUAPS (%eax), %xmm7
49 MOVUAPS 16(%eax), %xmm6
50 MOVUAPS 112(%eax), %xmm0
51 MOVUAPS 96(%eax), %xmm1
52 shufps $0x1b, %xmm0, %xmm0
53 shufps $0x1b, %xmm1, %xmm1
54 movaps %xmm7, %xmm4
55 movaps %xmm6, %xmm5
56 addps %xmm0, %xmm4
57 addps %xmm1, %xmm5
58 subps %xmm0, %xmm7
59 subps %xmm1, %xmm6
60 movaps %xmm4, TEMP(0)
61 movaps %xmm5, TEMP(1)
62
63 MOVUAPS 32(%eax), %xmm2
64 MOVUAPS 48(%eax), %xmm3
65 MOVUAPS 80(%eax), %xmm0
66 MOVUAPS 64(%eax), %xmm1
67 shufps $0x1b, %xmm0, %xmm0
68 shufps $0x1b, %xmm1, %xmm1
69 movaps %xmm2, %xmm5
70 movaps %xmm3, %xmm4
71 addps %xmm0, %xmm2
72 addps %xmm1, %xmm3
73 subps %xmm0, %xmm5
74 subps %xmm1, %xmm4
75
76 #ifdef PIC_GLOBAL_PTR
77 mov GLOBAL_VAR_PTR(INT123_costab_mmxsse), %eax
78 #else
79 lea GLOBAL_VAR(INT123_costab_mmxsse), %eax
80 #endif
81 mulps (%eax), %xmm7
82 mulps 16(%eax), %xmm6
83 mulps 32(%eax), %xmm5
84 mulps 48(%eax), %xmm4
85
86 shufps $0x1b, %xmm2, %xmm2
87 shufps $0x1b, %xmm3, %xmm3
88 shufps $0x1b, %xmm4, %xmm4
89 shufps $0x1b, %xmm5, %xmm5
90 movaps TEMP(0), %xmm0
91 movaps TEMP(1), %xmm1
92 subps %xmm3, %xmm0
93 subps %xmm2, %xmm1
94 addps TEMP(0), %xmm3
95 addps TEMP(1), %xmm2
96 movaps %xmm3, TEMP(0)
97 movaps %xmm2, TEMP(1)
98 movaps %xmm6, %xmm2
99 movaps %xmm7, %xmm3
100 subps %xmm5, %xmm6
101 subps %xmm4, %xmm7
102 addps %xmm3, %xmm4
103 addps %xmm2, %xmm5
104 mulps 64(%eax), %xmm0
105 mulps 80(%eax), %xmm1
106 mulps 80(%eax), %xmm6
107 mulps 64(%eax), %xmm7
108
109 movaps TEMP(0), %xmm2
110 movaps TEMP(1), %xmm3
111 shufps $0x1b, %xmm3, %xmm3
112 shufps $0x1b, %xmm5, %xmm5
113 shufps $0x1b, %xmm1, %xmm1
114 shufps $0x1b, %xmm6, %xmm6
115 movaps %xmm0, TEMP(1)
116 subps %xmm3, %xmm2
117 subps %xmm1, %xmm0
118 addps TEMP(0), %xmm3
119 addps TEMP(1), %xmm1
120 movaps %xmm3, TEMP(0)
121 movaps %xmm1, TEMP(2)
122 movaps %xmm5, %xmm1
123 movaps %xmm4, %xmm5
124 movaps %xmm7, %xmm3
125 subps %xmm1, %xmm5
126 subps %xmm6, %xmm7
127 addps %xmm1, %xmm4
128 addps %xmm3, %xmm6
129 mulps 96(%eax), %xmm2
130 mulps 96(%eax), %xmm0
131 mulps 96(%eax), %xmm5
132 mulps 96(%eax), %xmm7
133 movaps %xmm2, TEMP(1)
134 movaps %xmm0, TEMP(3)
135
136 movaps %xmm4, %xmm2
137 movaps %xmm5, %xmm3
138 shufps $0x44, %xmm6, %xmm2
139 shufps $0xbb, %xmm7, %xmm5
140 shufps $0xbb, %xmm6, %xmm4
141 shufps $0x44, %xmm7, %xmm3
142 movaps %xmm2, %xmm6
143 movaps %xmm3, %xmm7
144 subps %xmm4, %xmm2
145 subps %xmm5, %xmm3
146 addps %xmm6, %xmm4
147 addps %xmm7, %xmm5
148 movaps 112(%eax), %xmm0
149 movlhps %xmm0, %xmm0
150 mulps %xmm0, %xmm2
151 mulps %xmm0, %xmm3
152 movaps %xmm0, TEMP(4)
153 movaps %xmm4, %xmm6
154 movaps %xmm5, %xmm7
155 shufps $0x14, %xmm2, %xmm4
156 shufps $0xbe, %xmm2, %xmm6
157 shufps $0x14, %xmm3, %xmm5
158 shufps $0xbe, %xmm3, %xmm7
159 movaps %xmm5, TEMP(5)
160 movaps %xmm7, TEMP(7)
161
162 movaps TEMP(0), %xmm0
163 movaps TEMP(1), %xmm1
164 movaps %xmm0, %xmm2
165 movaps %xmm1, %xmm3
166 shufps $0x44, TEMP(2), %xmm2
167 shufps $0xbb, TEMP(3), %xmm1
168 shufps $0xbb, TEMP(2), %xmm0
169 shufps $0x44, TEMP(3), %xmm3
170 movaps %xmm2, %xmm5
171 movaps %xmm3, %xmm7
172 subps %xmm0, %xmm2
173 subps %xmm1, %xmm3
174 addps %xmm5, %xmm0
175 addps %xmm7, %xmm1
176 mulps TEMP(4), %xmm2
177 mulps TEMP(4), %xmm3
178 movaps %xmm0, %xmm5
179 movaps %xmm1, %xmm7
180 shufps $0x14, %xmm2, %xmm0
181 shufps $0xbe, %xmm2, %xmm5
182 shufps $0x14, %xmm3, %xmm1
183 shufps $0xbe, %xmm3, %xmm7
184
185 movaps %xmm0, TEMP(0)
186 movaps %xmm1, TEMP(1)
187 movaps %xmm5, TEMP(2)
188 movaps %xmm7, TEMP(3)
189
190 movss 120(%eax), %xmm5
191 shufps $0x00, %xmm5, %xmm5
192 xorps LOCAL_VAR(pnpn), %xmm5
193
194 movaps %xmm4, %xmm0
195 movaps %xmm6, %xmm1
196 unpcklps TEMP(5), %xmm4
197 unpckhps TEMP(5), %xmm0
198 unpcklps TEMP(7), %xmm6
199 unpckhps TEMP(7), %xmm1
200 movaps %xmm4, %xmm2
201 movaps %xmm6, %xmm3
202 unpcklps %xmm0, %xmm4
203 unpckhps %xmm0, %xmm2
204 unpcklps %xmm1, %xmm6
205 unpckhps %xmm1, %xmm3
206 movaps %xmm4, %xmm0
207 movaps %xmm6, %xmm1
208 subps %xmm2, %xmm0
209 subps %xmm3, %xmm1
210 addps %xmm2, %xmm4
211 addps %xmm3, %xmm6
212 mulps %xmm5, %xmm0
213 mulps %xmm5, %xmm1
214 movaps %xmm5, TEMP(5)
215 movaps %xmm4, %xmm5
216 movaps %xmm6, %xmm7
217 unpcklps %xmm0, %xmm4
218 unpckhps %xmm0, %xmm5
219 unpcklps %xmm1, %xmm6
220 unpckhps %xmm1, %xmm7
221
222 movaps TEMP(0), %xmm0
223 movaps TEMP(2), %xmm2
224 movaps %xmm4, TEMP(4)
225 movaps %xmm6, TEMP(6)
226
227 movaps %xmm0, %xmm4
228 movaps %xmm2, %xmm6
229 unpcklps TEMP(1), %xmm0
230 unpckhps TEMP(1), %xmm4
231 unpcklps TEMP(3), %xmm2
232 unpckhps TEMP(3), %xmm6
233 movaps %xmm0, %xmm1
234 movaps %xmm2, %xmm3
235 unpcklps %xmm4, %xmm0
236 unpckhps %xmm4, %xmm1
237 unpcklps %xmm6, %xmm2
238 unpckhps %xmm6, %xmm3
239 movaps %xmm0, %xmm4
240 movaps %xmm2, %xmm6
241 subps %xmm1, %xmm4
242 subps %xmm3, %xmm6
243 addps %xmm1, %xmm0
244 addps %xmm3, %xmm2
245 mulps TEMP(5), %xmm4
246 mulps TEMP(5), %xmm6
247 movaps %xmm0, %xmm1
248 movaps %xmm2, %xmm3
249 unpcklps %xmm4, %xmm0
250 unpckhps %xmm4, %xmm1
251 unpcklps %xmm6, %xmm2
252 unpckhps %xmm6, %xmm3
253
254 movaps %xmm0, TEMP(0)
255 movaps %xmm1, TEMP(1)
256 movaps %xmm2, TEMP(2)
257 movaps %xmm3, TEMP(3)
258 movaps %xmm5, TEMP(5)
259 movaps %xmm7, TEMP(7)
260
261 movss TEMP_BYTE(12), %xmm0
262 movss TEMP_BYTE(28), %xmm1
263 movss TEMP_BYTE(44), %xmm2
264 movss TEMP_BYTE(60), %xmm3
265 addss TEMP_BYTE(8), %xmm0
266 addss TEMP_BYTE(24), %xmm1
267 addss TEMP_BYTE(40), %xmm2
268 addss TEMP_BYTE(56), %xmm3
269 movss %xmm0, TEMP_BYTE(8)
270 movss %xmm1, TEMP_BYTE(24)
271 movss %xmm2, TEMP_BYTE(40)
272 movss %xmm3, TEMP_BYTE(56)
273 movss TEMP_BYTE(76), %xmm0
274 movss TEMP_BYTE(92), %xmm1
275 movss TEMP_BYTE(108), %xmm2
276 movss TEMP_BYTE(124), %xmm3
277 addss TEMP_BYTE(72), %xmm0
278 addss TEMP_BYTE(88), %xmm1
279 addss TEMP_BYTE(104), %xmm2
280 addss TEMP_BYTE(120), %xmm3
281 movss %xmm0, TEMP_BYTE(72)
282 movss %xmm1, TEMP_BYTE(88)
283 movss %xmm2, TEMP_BYTE(104)
284 movss %xmm3, TEMP_BYTE(120)
285
286 movaps TEMP_BYTE(16), %xmm1
287 movaps TEMP_BYTE(48), %xmm3
288 movaps TEMP_BYTE(80), %xmm5
289 movaps TEMP_BYTE(112), %xmm7
290 movaps %xmm1, %xmm0
291 movaps %xmm3, %xmm2
292 movaps %xmm5, %xmm4
293 movaps %xmm7, %xmm6
294 shufps $0x1e, %xmm0, %xmm0
295 shufps $0x1e, %xmm2, %xmm2
296 shufps $0x1e, %xmm4, %xmm4
297 shufps $0x1e, %xmm6, %xmm6
298 lea LOCAL_VAR(mask), %eax
299 andps (%eax), %xmm0
300 andps (%eax), %xmm2
301 andps (%eax), %xmm4
302 andps (%eax), %xmm6
303 addps %xmm0, %xmm1
304 addps %xmm2, %xmm3
305 addps %xmm4, %xmm5
306 addps %xmm6, %xmm7
307
308 movaps TEMP_BYTE(32), %xmm2
309 movaps TEMP_BYTE(96), %xmm6
310 movaps %xmm2, %xmm0
311 movaps %xmm6, %xmm4
312 shufps $0x1e, %xmm0, %xmm0
313 shufps $0x1e, %xmm4, %xmm4
314 andps (%eax), %xmm0
315 andps (%eax), %xmm4
316 addps %xmm3, %xmm2
317 addps %xmm0, %xmm3
318 addps %xmm7, %xmm6
319 addps %xmm4, %xmm7
320
321 movaps TEMP_BYTE(0), %xmm0
322 movaps TEMP_BYTE(64), %xmm4
323
324 movl ARG(0), %ecx
325 movl ARG(1), %ebx
326
327 movss %xmm0, 1024(%ecx)
328 movss %xmm2, 896(%ecx)
329 movss %xmm1, 768(%ecx)
330 movss %xmm3, 640(%ecx)
331
332 shufps $0xe1, %xmm0, %xmm0
333 shufps $0xe1, %xmm2, %xmm2
334 shufps $0xe1, %xmm1, %xmm1
335 shufps $0xe1, %xmm3, %xmm3
336 movss %xmm0, (%ecx)
337 movss %xmm0, (%ebx)
338 movss %xmm2, 128(%ebx)
339 movss %xmm1, 256(%ebx)
340 movss %xmm3, 384(%ebx)
341
342 movhlps %xmm0, %xmm0
343 movhlps %xmm2, %xmm2
344 movhlps %xmm1, %xmm1
345 movhlps %xmm3, %xmm3
346 movss %xmm0, 512(%ecx)
347 movss %xmm2, 384(%ecx)
348 movss %xmm1, 256(%ecx)
349 movss %xmm3, 128(%ecx)
350
351 shufps $0xe1, %xmm0, %xmm0
352 shufps $0xe1, %xmm2, %xmm2
353 shufps $0xe1, %xmm1, %xmm1
354 shufps $0xe1, %xmm3, %xmm3
355 movss %xmm0, 512(%ebx)
356 movss %xmm2, 640(%ebx)
357 movss %xmm1, 768(%ebx)
358 movss %xmm3, 896(%ebx)
359
360 movaps %xmm4, %xmm0
361 shufps $0x1e, %xmm0, %xmm0
362 movaps %xmm5, %xmm1
363 andps (%eax), %xmm0
364
365 addps %xmm6, %xmm4
366 addps %xmm7, %xmm5
367 addps %xmm1, %xmm6
368 addps %xmm0, %xmm7
369
370 movss %xmm4, 960(%ecx)
371 movss %xmm6, 832(%ecx)
372 movss %xmm5, 704(%ecx)
373 movss %xmm7, 576(%ecx)
374 movhlps %xmm4, %xmm0
375 movhlps %xmm6, %xmm1
376 movhlps %xmm5, %xmm2
377 movhlps %xmm7, %xmm3
378 movss %xmm0, 448(%ecx)
379 movss %xmm1, 320(%ecx)
380 movss %xmm2, 192(%ecx)
381 movss %xmm3, 64(%ecx)
382
383 shufps $0xe1, %xmm4, %xmm4
384 shufps $0xe1, %xmm6, %xmm6
385 shufps $0xe1, %xmm5, %xmm5
386 shufps $0xe1, %xmm7, %xmm7
387 movss %xmm4, 64(%ebx)
388 movss %xmm6, 192(%ebx)
389 movss %xmm5, 320(%ebx)
390 movss %xmm7, 448(%ebx)
391
392 shufps $0xe1, %xmm0, %xmm0
393 shufps $0xe1, %xmm1, %xmm1
394 shufps $0xe1, %xmm2, %xmm2
395 shufps $0xe1, %xmm3, %xmm3
396 movss %xmm0, 576(%ebx)
397 movss %xmm1, 704(%ebx)
398 movss %xmm2, 832(%ebx)
399 movss %xmm3, 960(%ebx)
400
401 popl %ebx
402 movl %ebp, %esp
403 popl %ebp
404 ret
405
406 #if defined(PIC) && defined(__APPLE__)
407 .section __IMPORT,__pointers,non_lazy_symbol_pointers
408 L_INT123_costab_mmxsse:
409 .indirect_symbol ASM_NAME(INT123_costab_mmxsse)
410 .long 0
411 #endif
412
413 NONEXEC_STACK