Debian Codegraph @

src/libmpg123/synth_stereo_x86_64_s32.S

raw
1 /*
2 synth_stereo_x86_64_s32: SSE optimized synth for x86-64 (stereo specific, s32 output version)
3
4 copyright 1995-2026 by the mpg123 project - free software under the terms of the LGPL 2.1
5 see COPYING and AUTHORS files in distribution or http://mpg123.org
6 initially written by Taihei Monma
7 */
8
9 #include "x86_64_defs.h"
10 #include "mangle.h"
11
12 #ifdef IS_MSABI
13 /* short *window; */
14 #define WINDOW %rsi
15 /* short *b0l; */
16 #define B0L %rdx
17 /* short *b0r; */
18 #define B0R %r8
19 /* short *samples; */
20 #define SAMPLES %rdi
21 #else
22 /* real *window; */
23 #define WINDOW %rdi
24 /* real *b0l; */
25 #define B0L %rsi
26 /* real *b0r; */
27 #define B0R %rdx
28 /* real *samples; */
29 #define SAMPLES %r8
30 #endif
31
32 #define XMMREG_SCALE (%r9) /* {65536.0, 65536.0, 65536.0, 65536.0} */
33 #define XMMREG_MAX (%r10) /* {32767.999, 32767.999, 32767.999, 32767.999} */
34 #define XMMREG_MIN (%r11) /* {-32768.0, -32768.0, -32768.0, -32768.0} */
35 #define TEMP_CLIP (%rsp)
36
37 /*
38 int synth_1to1_s32_s_x86_64_asm(real *window, real *b0l, real *b0r, int32_t *samples, int bo1);
39 return value: number of clipped samples
40 */
41
42 RODATA
43 ALIGN32
44 ASM_NAME(INT123_scale_s32):
45 .long 1199570944
46 .long 1199570944
47 .long 1199570944
48 .long 1199570944
49 ALIGN16
50 ASM_NAME(INT123_maxmin_s32):
51 .long 1191182335
52 .long 1191182335
53 .long 1191182335
54 .long 1191182335
55 .long -956301312
56 .long -956301312
57 .long -956301312
58 .long -956301312
59 .text
60 ALIGN16
61 .globl ASM_NAME(INT123_synth_1to1_s32_s_x86_64_asm)
62 ASM_NAME(INT123_synth_1to1_s32_s_x86_64_asm):
63 #ifdef IS_MSABI /* should save xmm6-15 */
64 movl 40(%rsp), %eax /* 5th argument; placed after 32-byte shadow space */
65 pushq %rsi
66 pushq %rdi
67 subq $184, %rsp /* stack alignment + 10 xmm registers + temp */
68 movaps %xmm6, 16(%rsp)
69 movaps %xmm7, 32(%rsp)
70 movaps %xmm8, 48(%rsp)
71 movaps %xmm9, 64(%rsp)
72 movaps %xmm10, 80(%rsp)
73 movaps %xmm11, 96(%rsp)
74 movaps %xmm12, 112(%rsp)
75 movaps %xmm13, 128(%rsp)
76 movaps %xmm14, 144(%rsp)
77 movaps %xmm15, 160(%rsp)
78 #else
79 subq $24, %rsp /* stack alignment + temp */
80 #endif
81
82 #ifdef IS_MSABI
83 shlq $32, %rax
84 shrq $30, %rax
85 movq %rcx, %rsi
86 movq %r9, %rdi
87 #else
88 movq %r8, %rax
89 shlq $32, %rax
90 shrq $30, %rax
91 movq %rcx, %r8
92 #endif
93 leaq 64(WINDOW), WINDOW
94 subq %rax, WINDOW
95
96 leaq ASM_NAME(INT123_scale_s32)(%rip), %r9
97 leaq ASM_NAME(INT123_maxmin_s32)(%rip), %r10
98 leaq 16(%r10), %r11
99 xorps %xmm0, %xmm0
100 movaps %xmm0, TEMP_CLIP
101
102 movl $4, %ecx
103
104 ALIGN16
105 1:
106 movups (WINDOW), %xmm8
107 movups 16(WINDOW), %xmm1
108 movups 32(WINDOW), %xmm2
109 movups 48(WINDOW), %xmm3
110 movups 128(WINDOW), %xmm9
111 movups 144(WINDOW), %xmm5
112 movups 160(WINDOW), %xmm6
113 movups 176(WINDOW), %xmm7
114 movaps %xmm8, %xmm0
115 movaps %xmm1, %xmm4
116 movaps %xmm2, %xmm10
117 movaps %xmm3, %xmm11
118 movaps %xmm9, %xmm12
119 movaps %xmm5, %xmm13
120 movaps %xmm6, %xmm14
121 movaps %xmm7, %xmm15
122 mulps (B0L), %xmm8
123 mulps 16(B0L), %xmm1
124 mulps 32(B0L), %xmm2
125 mulps 48(B0L), %xmm3
126 mulps 64(B0L), %xmm9
127 mulps 80(B0L), %xmm5
128 mulps 96(B0L), %xmm6
129 mulps 112(B0L), %xmm7
130 mulps (B0R), %xmm0
131 mulps 16(B0R), %xmm4
132 mulps 32(B0R), %xmm10
133 mulps 48(B0R), %xmm11
134 mulps 64(B0R), %xmm12
135 mulps 80(B0R), %xmm13
136 mulps 96(B0R), %xmm14
137 mulps 112(B0R), %xmm15
138
139 addps %xmm1, %xmm8
140 addps %xmm2, %xmm3
141 addps %xmm4, %xmm0
142 addps %xmm11, %xmm10
143 addps %xmm5, %xmm9
144 addps %xmm7, %xmm6
145 addps %xmm13, %xmm12
146 addps %xmm15, %xmm14
147 addps %xmm3, %xmm8
148 addps %xmm6, %xmm9
149 addps %xmm10, %xmm0
150 addps %xmm12, %xmm14
151 movaps %xmm0, %xmm12
152 movaps %xmm14, %xmm13
153 leaq 256(WINDOW), WINDOW
154 leaq 128(B0L), B0L
155 leaq 128(B0R), B0R
156
157 movups (WINDOW), %xmm10
158 movups 16(WINDOW), %xmm1
159 movups 32(WINDOW), %xmm2
160 movups 48(WINDOW), %xmm3
161 movups 128(WINDOW), %xmm11
162 movups 144(WINDOW), %xmm5
163 movups 160(WINDOW), %xmm6
164 movups 176(WINDOW), %xmm7
165 movaps %xmm10, %xmm0
166 movaps %xmm1, %xmm4
167 movaps %xmm2, %xmm14
168 movaps %xmm3, %xmm15
169 mulps (B0L), %xmm10
170 mulps 16(B0L), %xmm1
171 mulps 32(B0L), %xmm2
172 mulps 48(B0L), %xmm3
173 mulps (B0R), %xmm0
174 mulps 16(B0R), %xmm4
175 mulps 32(B0R), %xmm14
176 mulps 48(B0R), %xmm15
177 addps %xmm1, %xmm10
178 addps %xmm2, %xmm3
179 addps %xmm4, %xmm0
180 addps %xmm15, %xmm14
181 movaps %xmm11, %xmm1
182 movaps %xmm5, %xmm2
183 movaps %xmm6, %xmm4
184 movaps %xmm7, %xmm15
185 mulps 64(B0L), %xmm11
186 mulps 80(B0L), %xmm5
187 mulps 96(B0L), %xmm6
188 mulps 112(B0L), %xmm7
189 mulps 64(B0R), %xmm1
190 mulps 80(B0R), %xmm2
191 mulps 96(B0R), %xmm4
192 mulps 112(B0R), %xmm15
193 addps %xmm5, %xmm11
194 addps %xmm7, %xmm6
195 addps %xmm2, %xmm1
196 addps %xmm15, %xmm4
197
198 addps %xmm3, %xmm10
199 addps %xmm6, %xmm11
200 addps %xmm0, %xmm14
201 addps %xmm4, %xmm1
202 movaps %xmm1, %xmm15
203 leaq 256(WINDOW), WINDOW
204 leaq 128(B0L), B0L
205 leaq 128(B0R), B0R
206
207 movaps %xmm8, %xmm0
208 movaps %xmm10, %xmm1
209 movaps %xmm12, %xmm4
210 movaps %xmm14, %xmm5
211 unpcklps %xmm9, %xmm8
212 unpcklps %xmm11, %xmm10
213 unpckhps %xmm9, %xmm0
214 unpckhps %xmm11, %xmm1
215 unpcklps %xmm13, %xmm12
216 unpcklps %xmm15, %xmm14
217 unpckhps %xmm13, %xmm4
218 unpckhps %xmm15, %xmm5
219 movaps %xmm8, %xmm2
220 movaps %xmm0, %xmm3
221 movaps %xmm12, %xmm6
222 movaps %xmm4, %xmm7
223 movlhps %xmm10, %xmm8
224 movhlps %xmm2, %xmm10
225 movlhps %xmm1, %xmm0
226 movhlps %xmm3, %xmm1
227 movlhps %xmm14, %xmm12
228 movhlps %xmm6, %xmm14
229 movlhps %xmm5, %xmm4
230 movhlps %xmm7, %xmm5
231 subps %xmm10, %xmm8
232 subps %xmm1, %xmm0
233 subps %xmm14, %xmm12
234 subps %xmm5, %xmm4
235 addps %xmm8, %xmm0
236 addps %xmm12, %xmm4
237
238 movaps %xmm0, %xmm2
239 movaps %xmm0, %xmm3
240 movaps %xmm4, %xmm5
241 movaps %xmm4, %xmm6
242 mulps XMMREG_SCALE, %xmm0
243 mulps XMMREG_SCALE, %xmm4
244 cmpnleps XMMREG_MAX, %xmm2
245 cmpltps XMMREG_MIN, %xmm3
246 cmpnleps XMMREG_MAX, %xmm5
247 cmpltps XMMREG_MIN, %xmm6
248 cvtps2dq %xmm0, %xmm0
249 cvtps2dq %xmm4, %xmm4
250 xorps %xmm2, %xmm0
251 xorps %xmm5, %xmm4
252 movaps %xmm0, %xmm1
253 unpcklps %xmm4, %xmm0
254 unpckhps %xmm4, %xmm1
255 movups %xmm0, (SAMPLES)
256 movups %xmm1, 16(SAMPLES)
257
258 packssdw %xmm5, %xmm2
259 packssdw %xmm6, %xmm3
260 psrlw $15, %xmm2
261 psrlw $15, %xmm3
262 paddw %xmm3, %xmm2
263 paddw TEMP_CLIP, %xmm2
264 movaps %xmm2, TEMP_CLIP
265
266 leaq 32(SAMPLES), SAMPLES
267 decl %ecx
268 jnz 1b
269
270 movl $4, %ecx
271
272 ALIGN16
273 1:
274 movups (WINDOW), %xmm8
275 movups 16(WINDOW), %xmm1
276 movups 32(WINDOW), %xmm2
277 movups 48(WINDOW), %xmm3
278 movups 128(WINDOW), %xmm9
279 movups 144(WINDOW), %xmm5
280 movups 160(WINDOW), %xmm6
281 movups 176(WINDOW), %xmm7
282 movaps %xmm8, %xmm0
283 movaps %xmm1, %xmm4
284 movaps %xmm2, %xmm10
285 movaps %xmm3, %xmm11
286 movaps %xmm9, %xmm12
287 movaps %xmm5, %xmm13
288 movaps %xmm6, %xmm14
289 movaps %xmm7, %xmm15
290 mulps (B0L), %xmm8
291 mulps 16(B0L), %xmm1
292 mulps 32(B0L), %xmm2
293 mulps 48(B0L), %xmm3
294 mulps -64(B0L), %xmm9
295 mulps -48(B0L), %xmm5
296 mulps -32(B0L), %xmm6
297 mulps -16(B0L), %xmm7
298 mulps (B0R), %xmm0
299 mulps 16(B0R), %xmm4
300 mulps 32(B0R), %xmm10
301 mulps 48(B0R), %xmm11
302 mulps -64(B0R), %xmm12
303 mulps -48(B0R), %xmm13
304 mulps -32(B0R), %xmm14
305 mulps -16(B0R), %xmm15
306
307 addps %xmm1, %xmm8
308 addps %xmm2, %xmm3
309 addps %xmm4, %xmm0
310 addps %xmm11, %xmm10
311 addps %xmm5, %xmm9
312 addps %xmm7, %xmm6
313 addps %xmm13, %xmm12
314 addps %xmm15, %xmm14
315 addps %xmm3, %xmm8
316 addps %xmm6, %xmm9
317 addps %xmm10, %xmm0
318 addps %xmm12, %xmm14
319 movaps %xmm0, %xmm12
320 movaps %xmm14, %xmm13
321 leaq 256(WINDOW), WINDOW
322 leaq -128(B0L), B0L
323 leaq -128(B0R), B0R
324
325 movups (WINDOW), %xmm10
326 movups 16(WINDOW), %xmm1
327 movups 32(WINDOW), %xmm2
328 movups 48(WINDOW), %xmm3
329 movups 128(WINDOW), %xmm11
330 movups 144(WINDOW), %xmm5
331 movups 160(WINDOW), %xmm6
332 movups 176(WINDOW), %xmm7
333 movaps %xmm10, %xmm0
334 movaps %xmm1, %xmm4
335 movaps %xmm2, %xmm14
336 movaps %xmm3, %xmm15
337 mulps (B0L), %xmm10
338 mulps 16(B0L), %xmm1
339 mulps 32(B0L), %xmm2
340 mulps 48(B0L), %xmm3
341 mulps (B0R), %xmm0
342 mulps 16(B0R), %xmm4
343 mulps 32(B0R), %xmm14
344 mulps 48(B0R), %xmm15
345 addps %xmm1, %xmm10
346 addps %xmm2, %xmm3
347 addps %xmm4, %xmm0
348 addps %xmm15, %xmm14
349 movaps %xmm11, %xmm1
350 movaps %xmm5, %xmm2
351 movaps %xmm6, %xmm4
352 movaps %xmm7, %xmm15
353 mulps -64(B0L), %xmm11
354 mulps -48(B0L), %xmm5
355 mulps -32(B0L), %xmm6
356 mulps -16(B0L), %xmm7
357 mulps -64(B0R), %xmm1
358 mulps -48(B0R), %xmm2
359 mulps -32(B0R), %xmm4
360 mulps -16(B0R), %xmm15
361 addps %xmm5, %xmm11
362 addps %xmm7, %xmm6
363 addps %xmm2, %xmm1
364 addps %xmm15, %xmm4
365
366 addps %xmm3, %xmm10
367 addps %xmm6, %xmm11
368 addps %xmm0, %xmm14
369 addps %xmm4, %xmm1
370 movaps %xmm1, %xmm15
371 leaq 256(WINDOW), WINDOW
372 leaq -128(B0L), B0L
373 leaq -128(B0R), B0R
374
375 movaps %xmm8, %xmm0
376 movaps %xmm10, %xmm1
377 movaps %xmm12, %xmm4
378 movaps %xmm14, %xmm5
379 unpcklps %xmm9, %xmm8
380 unpcklps %xmm11, %xmm10
381 unpckhps %xmm9, %xmm0
382 unpckhps %xmm11, %xmm1
383 unpcklps %xmm13, %xmm12
384 unpcklps %xmm15, %xmm14
385 unpckhps %xmm13, %xmm4
386 unpckhps %xmm15, %xmm5
387 movaps %xmm8, %xmm2
388 movaps %xmm0, %xmm3
389 movaps %xmm12, %xmm6
390 movaps %xmm4, %xmm7
391 movlhps %xmm10, %xmm8
392 movhlps %xmm2, %xmm10
393 movlhps %xmm1, %xmm0
394 movhlps %xmm3, %xmm1
395 movlhps %xmm14, %xmm12
396 movhlps %xmm6, %xmm14
397 movlhps %xmm5, %xmm4
398 movhlps %xmm7, %xmm5
399 addps %xmm10, %xmm8
400 addps %xmm1, %xmm0
401 addps %xmm14, %xmm12
402 addps %xmm5, %xmm4
403 addps %xmm8, %xmm0
404 addps %xmm12, %xmm4
405
406 movaps %xmm0, %xmm2
407 movaps %xmm0, %xmm3
408 movaps %xmm4, %xmm5
409 movaps %xmm4, %xmm6
410 mulps XMMREG_SCALE, %xmm0
411 mulps XMMREG_SCALE, %xmm4
412 cmpnleps XMMREG_MAX, %xmm2
413 cmpltps XMMREG_MIN, %xmm3
414 cmpnleps XMMREG_MAX, %xmm5
415 cmpltps XMMREG_MIN, %xmm6
416 cvtps2dq %xmm0, %xmm0
417 cvtps2dq %xmm4, %xmm4
418 xorps %xmm2, %xmm0
419 xorps %xmm5, %xmm4
420 movaps %xmm0, %xmm1
421 unpcklps %xmm4, %xmm0
422 unpckhps %xmm4, %xmm1
423 movups %xmm0, (SAMPLES)
424 movups %xmm1, 16(SAMPLES)
425
426 packssdw %xmm5, %xmm2
427 packssdw %xmm6, %xmm3
428 psrlw $15, %xmm2
429 psrlw $15, %xmm3
430 paddw %xmm3, %xmm2
431 paddw TEMP_CLIP, %xmm2
432 movaps %xmm2, TEMP_CLIP
433
434 leaq 32(SAMPLES), SAMPLES
435 decl %ecx
436 jnz 1b
437
438 movaps TEMP_CLIP, %xmm4
439 movhlps %xmm4, %xmm0
440 paddw %xmm4, %xmm0
441 pshuflw $0x55, %xmm0, %xmm1
442 pshuflw $0xaa, %xmm0, %xmm2
443 pshuflw $0xff, %xmm0, %xmm3
444 paddw %xmm1, %xmm0
445 paddw %xmm2, %xmm0
446 paddw %xmm3, %xmm0
447
448 movd %xmm0, %eax
449 andl $0xffff, %eax
450
451 #ifdef IS_MSABI
452 movaps 16(%rsp), %xmm6
453 movaps 32(%rsp), %xmm7
454 movaps 48(%rsp), %xmm8
455 movaps 64(%rsp), %xmm9
456 movaps 80(%rsp), %xmm10
457 movaps 96(%rsp), %xmm11
458 movaps 112(%rsp), %xmm12
459 movaps 128(%rsp), %xmm13
460 movaps 144(%rsp), %xmm14
461 movaps 160(%rsp), %xmm15
462 addq $184, %rsp
463 popq %rdi
464 popq %rsi
465 #else
466 addq $24, %rsp
467 #endif
468 ret
469
470 NONEXEC_STACK